ejemplo con dos opiniones

.github/workflows/ci.yml

@@ -0,0 +1,14 @@
+name: build
+
+on: [push, pull_request]
+jobs:
+  wollok-ts:
+    runs-on: ubuntu-latest
+
+    steps:
+      - uses: actions/checkout@v4
+      - run: |
+          wget -O wollok-ts-cli https://github.com/uqbar-project/wollok-ts-cli/releases/latest/download/wollok-ts-cli-linux-x64
+          chmod a+x ./wollok-ts-cli
+          ./wollok-ts-cli test --skipValidations -p ./
+        shell: bash

.gitignore

@@ -0,0 +1,6 @@
+
+# Local history
+.history
+
+# Wollok Log
+*.log

README.md

@@ -0,0 +1,6 @@
+
+
+## example
+
+TODO
+

encuesta.wpgm

@@ -0,0 +1,19 @@
+import grafico.*
+import grupo1.*
+import grupo2.*
+import opiniones.*
+
+program graficadorEncuestas {
+	const encuesta = new Encuesta()
+	encuesta.opiniones().add(grupo1)
+	encuesta.opiniones().add(grupo2)
+
+	game.boardGround("fondoClaro.jpg")
+	game.height(14)
+	game.width(16)	new GraficoBarrasIconos(
+		valores = encuesta.resultados(),
+		etiquetas = encuesta.descripciones(),
+		position = game.at(3, 3)
+	).dibujar()
+	game.start()
+}

grafico.wlk

@@ -0,0 +1,101 @@
+import wollok.game.*
+
+class BarraVertical {
+	const valor
+	var position
+
+	method dibujar() {
+		if (valor > 0) valor.times(
+				{ i =>
+					new Item(position = position).dibujar()
+					position = position.up(1)
+				}
+			)
+	}
+}
+
+class GraficoBarras {
+	const valores
+	const etiquetas
+	const maximo = 10
+	var property position
+
+	method dibujar() {
+		self.dibujarBarras()
+		self.dibujarEtiquetasHorizontales()
+		self.dibujarEtiquetasVerticales()
+	}
+
+	method dibujarBarras() {
+		var pos = position
+
+		valores.forEach(
+			{ valor =>
+				new BarraVertical(valor = valor, position = pos).dibujar()
+				pos = pos.right(2)
+			}
+		)
+	}
+
+	method dibujarEtiquetasHorizontales() {
+		var pos = position.down(2)
+		etiquetas.forEach(
+			{ etiqueta =>
+				self.nuevaEtiquetaHorizontal(etiqueta, pos).dibujar()
+				pos = pos.right(2)
+			}
+		)
+	}
+
+	method dibujarEtiquetasVerticales() {
+		var pos = position.left(2)
+		maximo.times(
+			{ nro =>
+				self.nuevaEtiquetaVertical(nro.toString(), pos).dibujar()
+				pos = pos.up(1)
+			}
+		)
+	}
+
+	method nuevaEtiquetaHorizontal(etiqueta, pos) = new Etiqueta(
+		text = etiqueta,
+		position = pos
+	)
+
+	method nuevaEtiquetaVertical(etiqueta, pos) = self.nuevaEtiquetaHorizontal(
+		etiqueta,
+		pos
+	)
+}
+
+class GraficoBarrasIconos inherits GraficoBarras {
+	override method nuevaEtiquetaHorizontal(etiqueta, pos) = new Icono(
+		image = etiqueta,
+		position = pos
+	)
+
+	override method nuevaEtiquetaVertical(etiqueta, pos) = new Icono(
+		image = ("number-" + etiqueta) + ".png",
+		position = pos
+	)
+}
+
+class Visual {
+	const property position
+
+	method dibujar() {
+		game.addVisual(self)
+	}
+}
+
+class Icono inherits Visual {
+	const property image
+}
+
+class Etiqueta inherits Visual {
+	const property text
+}
+
+class Item inherits Visual {
+	method image() = "cuadradoliso.jpg"
+}

grupo1.wlk

@@ -0,0 +1,7 @@
+import opiniones.*
+
+const grupo1 = new Opinion(
+   objetos = 9,
+   funcional = 7,
+   logico = 3
+)

grupo2.wlk

@@ -0,0 +1,7 @@
+import opiniones.*
+
+const grupo2 = new Opinion(
+   objetos = 6,
+   funcional = 10,
+   logico = 4
+)

opiniones.wlk

@@ -0,0 +1,18 @@
+class Opinion {
+
+    var property objetos
+
+    var property funcional
+
+    var property logico
+
+}
+
+
+class Encuesta {
+    const property opiniones = []
+    const property descripciones = ["wollok.png", "haskell.png", "prolog.png"]
+    const property criterios = [{o=>o.objetos()},{o=>o.funcional()},{o=>o.logico()} ]
+
+    method resultados() = criterios.map({c=>opiniones.sum(c)/opiniones.size()})
+}

package.json

@@ -0,0 +1,7 @@
+{
+  "name": "encuesta",
+  "version": "1.0.0",
+  "wollokVersion": "4.0.0",
+  "author": "lucas",
+  "license": "ISC"
+}

testExample.wtest

@@ -0,0 +1,9 @@
+import grafico.*
+
+describe "group of tests for grafico" {
+
+  test "valoracion promedio" {
+    //assert.equals(100, pepita.energy())
+  }
+
+}