[opentitan] Integrate OpenTitan Peripherals

CMakeLists.txt

@@ -16,9 +16,6 @@ set(CMAKE_C_COMPILER_WORKS 1)
 set(CMAKE_EXPORT_COMPILE_COMMANDS TRUE)
 set(CMAKE_VERBOSE_MAKEFILE TRUE)
 
-# SCHEREMO: Help most IDE's LSPs find definitions
-set(CMAKE_EXPORT_COMPILE_COMMANDS 1)
-
 # SCHEREMO: This toolchain file is only used for test compilation!
 set(CMAKE_TOOLCHAIN_FILE cmake/toolchain_llvm.cmake)
 

cmake/opentitan.cmake

@@ -0,0 +1,146 @@
+# Copyright 2024 ETH Zurich and University of Bologna.
+# Licensed under the Apache License, Version 2.0, see LICENSE for details.
+# SPDX-License-Identifier: Apache-2.0
+#
+# Viviane Potocnik <[email protected]>
+
+include(ExternalProject)
+
+set(OPENTITAN_DIR ${CMAKE_SOURCE_DIR}/drivers/opentitan)
+set(SPARSE_CHECKOUT_FILE ${CMAKE_CURRENT_BINARY_DIR}/sparse-checkout)
+
+if(NOT DEFINED OPENTITAN_COMMIT_HASH)
+  message(FATAL_ERROR "Please set a commit hash in your target.")
+endif()
+
+message(STATUS "[OT Drivers] Using OpenTitan commit hash: ${OPENTITAN_COMMIT_HASH}")
+
+set(SPARSE_PATTERNS
+  "util/design/*"
+  "util/reggen/*"
+  "util/regtool.py"
+  "util/version_file.py"
+  "hw/ip/uart/data/uart.hjson"
+  "sw/device/lib/base/abs_mmio.c"
+  "sw/device/lib/base/abs_mmio.h"
+  "sw/device/lib/base/bitfield.c"
+  "sw/device/lib/base/bitfield.h"
+  "sw/device/lib/base/macros.h"
+  "sw/device/lib/base/math.c"
+  "sw/device/lib/base/math.h"
+  "sw/device/lib/base/math_builtins.c"
+  "sw/device/lib/base/memory.c"
+  "sw/device/lib/base/memory.h"
+)
+
+file(WRITE ${SPARSE_CHECKOUT_FILE} "")
+foreach(PATTERN ${SPARSE_PATTERNS})
+  file(APPEND ${SPARSE_CHECKOUT_FILE} "${PATTERN}\n")
+endforeach()
+
+# Clone and set up the OpenTitan repository during configuration
+if(NOT EXISTS ${OPENTITAN_DIR}/.git)
+  execute_process(
+    COMMAND git clone --no-checkout https://github.com/lowRISC/opentitan.git ${OPENTITAN_DIR}
+    RESULT_VARIABLE GIT_CLONE_RESULT
+    OUTPUT_VARIABLE GIT_CLONE_OUTPUT
+    ERROR_VARIABLE GIT_CLONE_ERROR
+  )
+  if(NOT GIT_CLONE_RESULT EQUAL 0)
+    message(FATAL_ERROR "Failed to clone OpenTitan repository: ${GIT_CLONE_ERROR}")
+  endif()
+else()
+  message(STATUS "[OT Drivers] OpenTitan repository already exists.")
+endif()
+
+# Configure sparse checkout
+execute_process(
+  COMMAND git -C ${OPENTITAN_DIR} config core.sparseCheckout true
+  RESULT_VARIABLE GIT_CONFIG_RESULT
+  OUTPUT_VARIABLE GIT_CONFIG_OUTPUT
+  ERROR_VARIABLE GIT_CONFIG_ERROR
+)
+if(NOT GIT_CONFIG_RESULT EQUAL 0)
+  message(FATAL_ERROR "Failed to configure sparse checkout: ${GIT_CONFIG_ERROR}")
+endif()
+
+file(COPY ${SPARSE_CHECKOUT_FILE} DESTINATION ${OPENTITAN_DIR}/.git/info/)
+
+# Apply sparse checkout
+execute_process(
+  COMMAND git -C ${OPENTITAN_DIR} read-tree -mu HEAD
+  RESULT_VARIABLE GIT_READ_TREE_RESULT
+  OUTPUT_VARIABLE GIT_READ_TREE_OUTPUT
+  ERROR_VARIABLE GIT_READ_TREE_ERROR
+)
+if(NOT GIT_READ_TREE_RESULT EQUAL 0)
+  message(FATAL_ERROR "Failed to apply sparse checkout: ${GIT_READ_TREE_ERROR}")
+endif()
+
+# Checkout the desired branch (e.g., master)
+execute_process(
+  COMMAND git -C ${OPENTITAN_DIR} checkout ${OPENTITAN_COMMIT_HASH}
+  RESULT_VARIABLE GIT_CHECKOUT_RESULT
+  OUTPUT_VARIABLE GIT_CHECKOUT_OUTPUT
+  ERROR_VARIABLE GIT_CHECKOUT_ERROR
+)
+if(NOT GIT_CHECKOUT_RESULT EQUAL 0)
+  message(FATAL_ERROR "Failed to checkout commit ${OPENTITAN_COMMIT_HASH}: ${GIT_CHECKOUT_ERROR}")
+endif()
+
+# Now proceed with adding the external project to manage build steps
+ExternalProject_Add(
+  opentitan_build
+  SOURCE_DIR ${OPENTITAN_DIR}
+  CONFIGURE_COMMAND ""    # No configure step needed
+  BUILD_COMMAND ""        # No build step needed (unless you have specific build steps)
+  INSTALL_COMMAND ""      # No install step needed
+  BUILD_BYPRODUCTS ${OPENTITAN_DIR}/.git/config
+)
+
+# Define directories for OpenTitan sources
+set(OPENTITAN_SW_DIR ${OPENTITAN_DIR}/sw)
+set(OPENTITAN_HW_IP_DIR ${OPENTITAN_DIR}/hw/ip)
+set(OPENTITAN_UTIL_DIR ${OPENTITAN_DIR}/util)
+
+# Paths for regtool and UART headers
+set(REGTOOL_PY ${OPENTITAN_UTIL_DIR}/regtool.py)
+set(UART_HJSON ${OPENTITAN_HW_IP_DIR}/uart/data/uart.hjson)
+set(UART_REGS_H ${OPENTITAN_SW_DIR}/device/lib/dif/autogen/uart_regs.h)
+
+# Define the output directory
+get_filename_component(UART_REGS_DIR ${UART_REGS_H} DIRECTORY)
+
+# Custom command to generate UART registers header
+add_custom_command(
+  OUTPUT ${UART_REGS_H}
+  COMMAND ${CMAKE_COMMAND} -E make_directory ${UART_REGS_DIR}
+  COMMAND ${Python3_EXECUTABLE} ${REGTOOL_PY} ${UART_HJSON} -D > ${UART_REGS_H}
+  DEPENDS ${REGTOOL_PY} ${UART_HJSON}
+  COMMENT "Generating ${UART_REGS_H} with COMMAND ${Python3_EXECUTABLE} ${REGTOOL_PY} ${UART_HJSON} -D > ${UART_REGS_H}"
+)
+
+add_custom_target(
+  generate_uart_regs ALL
+  DEPENDS ${UART_REGS_H}
+)
+
+add_dependencies(generate_uart_regs opentitan_build)
+
+file(GLOB_RECURSE OPENTITAN_SOURCES
+  LIST_DIRECTORIES false
+  ${OPENTITAN_SW_DIR}/device/lib/base/*.c
+)
+
+# Create OpenTitan library
+add_library(opentitan_lib STATIC ${OPENTITAN_SOURCES})
+
+# Ensure the library depends on the external project build
+add_dependencies(opentitan_lib opentitan_build generate_uart_regs)
+
+# Include directories for OpenTitan library
+target_include_directories(opentitan_lib
+    PUBLIC
+    ${OPENTITAN_DIR}
+)
+

cmake/toolchain_llvm.cmake

@@ -20,4 +20,4 @@ set(CMAKE_OBJDUMP ${TOOLCHAIN_DIR}/${LLVM_TAG}-objdump)
 set(CMAKE_AR ${TOOLCHAIN_DIR}/${LLVM_TAG}-ar)
 
 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} --target=riscv32-unknown-elf")
-set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} --target=riscv32-unknown-elf")
+set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} --target=riscv32-unknown-elf")

drivers/CMakeLists.txt

@@ -2,6 +2,7 @@
 # Licensed under the Apache License, Version 2.0, see LICENSE for details.
 # SPDX-License-Identifier: Apache-2.0
 #
+# Viviane Potocnik <[email protected]>
 # Philip Wiese <[email protected]>
 
 # Define mappings for drivers
@@ -17,3 +18,9 @@ add_chimera_subdirectories(${TARGET_PLATFORM} "Driver" "${DRIVER_MAPPINGS}")
 
 # WIESEP: Export this directory as root include directory for the drivers
 target_include_directories(runtime_host PUBLIC ${CMAKE_CURRENT_LIST_DIR})
+
+# VIVIANEP: Link to the opentitan library
+target_link_libraries(runtime_host
+    PUBLIC
+    opentitan_lib
+)

targets/chimera-open/CMakeLists.txt

@@ -9,8 +9,18 @@
 ################################################################################
 # Host Runtime Library                                                         #
 ################################################################################
+
+# VIVIANEP: Select target-specific commit hash of the OT lib
+set(TARGET_OPENTITAN_COMMIT_HASH 22168a3d42febfca725b36dd0d1554b68cf5783e)
+
+set(OPENTITAN_COMMIT_HASH ${TARGET_OPENTITAN_COMMIT_HASH})
+
+# VIVIANEP: Add OpenTitan as an external project
+include(${CMAKE_SOURCE_DIR}/cmake/opentitan.cmake)
+
 add_library(runtime_host STATIC)
 
+
 file(GLOB_RECURSE ASM_SOURCES
   "src/crt0.S"
 )