feat: add propagate_common_{,test_,binary_}rule_attributes to lib/utils.

lib/private/utils.bzl

@@ -247,6 +247,97 @@ def _maybe_http_archive(**kwargs):
     """
     maybe(_http_archive, **kwargs)
 
+_COMMON_RULE_ATTRIBUTES = [
+    "compatible_with",
+    "deprecation",
+    "distribs",
+    "exec_compatible_with",
+    "exec_properties",
+    "features",
+    "restricted_to",
+    "tags",
+    "target_compatible_with",
+    "testonly",
+    "toolchains",
+    "visibility",
+]
+
+_COMMON_TEST_RULE_ATTRIBUTES = _COMMON_RULE_ATTRIBUTES + [
+    "args",
+    "env",
+    "env_inherit",
+    "size",
+    "timeout",
+    "flaky",
+    "shard_count",
+    "local",
+]
+
+_COMMON_BINARY_RULE_ATTRIBUTES = _COMMON_RULE_ATTRIBUTES + [
+    "args",
+    "env",
+    "output_licenses",
+]
+
+def _propagate_common_rule_attributes(attrs):
+    """Returns a dict of rule parameters filtered from the input dict that only contains the onces that are common to all rules
+
+    These are listed in Bazel's documentation:
+    https://bazel.build/reference/be/common-definitions#common-attributes
+
+    Args:
+        attrs: Dict of parameters to filter
+
+    Returns:
+        The dict of parameters, containing only common attributes
+    """
+
+    return {
+        k: attrs[k]
+        for k in attrs
+        if k in _COMMON_RULE_ATTRIBUTES
+    }
+
+def _propagate_common_test_rule_attributes(attrs):
+    """Returns a dict of rule parameters filtered from the input dict that only contains the onces that are common to all test rules
+
+    These are listed in Bazel's documentation:
+    https://bazel.build/reference/be/common-definitions#common-attributes
+    https://bazel.build/reference/be/common-definitions#common-attributes-tests
+
+    Args:
+        attrs: Dict of parameters to filter
+
+    Returns:
+        The dict of parameters, containing only common test attributes
+    """
+
+    return {
+        k: attrs[k]
+        for k in attrs
+        if k in _COMMON_TEST_RULE_ATTRIBUTES
+    }
+
+def _propagate_common_binary_rule_attributes(attrs):
+    """Returns a dict of rule parameters filtered from the input dict that only contains the onces that are common to all binary rules
+
+    These are listed in Bazel's documentation:
+    https://bazel.build/reference/be/common-definitions#common-attributes
+    https://bazel.build/reference/be/common-definitions#common-attributes-binary
+
+    Args:
+        attrs: Dict of parameters to filter
+
+    Returns:
+        The dict of parameters, containing only common binary attributes
+    """
+
+    return {
+        k: attrs[k]
+        for k in attrs
+        if k in _COMMON_RULE_ATTRIBUTES or k in _COMMON_BINARY_RULE_ATTRIBUTES
+    }
+
 utils = struct(
     default_timeout = _default_timeout,
     file_exists = _file_exists,
@@ -257,6 +348,9 @@ utils = struct(
     maybe_http_archive = _maybe_http_archive,
     path_to_workspace_root = _path_to_workspace_root,
     propagate_well_known_tags = _propagate_well_known_tags,
+    propagate_common_rule_attributes = _propagate_common_rule_attributes,
+    propagate_common_test_rule_attributes = _propagate_common_test_rule_attributes,
+    propagate_common_binary_rule_attributes = _propagate_common_binary_rule_attributes,
     to_label = _to_label,
     consistent_label_str = _consistent_label_str,
 )

lib/tests/utils_test.bzl

@@ -71,6 +71,63 @@ def _propagate_well_known_tags_test_impl(ctx):
 
     return unittest.end(env)
 
+def _propagate_common_rule_attributes_test_impl(ctx):
+    env = unittest.begin(ctx)
+
+    asserts.equals(env, {
+        "features": ["dbg"],
+        "testonly": True,
+        "visibility": ["//visibility:private"],
+    }, utils.propagate_common_rule_attributes({
+        "features": ["dbg"],
+        "testonly": True,
+        "visibility": ["//visibility:private"],
+        "platform": ["//:myplatform"],
+        "env": {"PATH": "/usr/bin:/bin"},
+        "size": "small",
+    }))
+
+    return unittest.end(env)
+
+def _propagate_common_test_rule_attributes_test_impl(ctx):
+    env = unittest.begin(ctx)
+
+    asserts.equals(env, {
+        "features": ["dbg"],
+        "testonly": True,
+        "visibility": ["//visibility:private"],
+        "env": {"PATH": "/usr/bin:/bin"},
+        "size": "small",
+    }, utils.propagate_common_test_rule_attributes({
+        "features": ["dbg"],
+        "testonly": True,
+        "visibility": ["//visibility:private"],
+        "platform": ["//:myplatform"],
+        "env": {"PATH": "/usr/bin:/bin"},
+        "size": "small",
+    }))
+
+    return unittest.end(env)
+
+def _propagate_common_binary_rule_attributes_test_impl(ctx):
+    env = unittest.begin(ctx)
+
+    asserts.equals(env, {
+        "features": ["dbg"],
+        "testonly": True,
+        "visibility": ["//visibility:private"],
+        "env": {"PATH": "/usr/bin:/bin"},
+    }, utils.propagate_common_binary_rule_attributes({
+        "features": ["dbg"],
+        "testonly": True,
+        "visibility": ["//visibility:private"],
+        "platform": ["//:myplatform"],
+        "env": {"PATH": "/usr/bin:/bin"},
+        "size": "small",
+    }))
+
+    return unittest.end(env)
+
 def _consistent_label_str_impl(ctx):
     env = unittest.begin(ctx)
 
@@ -104,6 +161,9 @@ is_external_label_test = unittest.make(
 )
 
 propagate_well_known_tags_test = unittest.make(_propagate_well_known_tags_test_impl)
+propagate_common_rule_attributes_test = unittest.make(_propagate_common_rule_attributes_test_impl)
+propagate_common_test_rule_attributes_test = unittest.make(_propagate_common_test_rule_attributes_test_impl)
+propagate_common_binary_rule_attributes_test = unittest.make(_propagate_common_binary_rule_attributes_test_impl)
 consistent_label_str_test = unittest.make(_consistent_label_str_impl)
 
 # buildifier: disable=function-docstring
@@ -134,6 +194,21 @@ def utils_test_suite():
         timeout = "short",
     )
 
+    propagate_common_rule_attributes_test(
+        name = "propagate_common_rule_attribute_tests",
+        timeout = "short",
+    )
+
+    propagate_common_test_rule_attributes_test(
+        name = "propagate_common_test_rule_attribute_tests",
+        timeout = "short",
+    )
+
+    propagate_common_binary_rule_attributes_test(
+        name = "propagate_common_binary_rule_attribute_tests",
+        timeout = "short",
+    )
+
     consistent_label_str_test(
         name = "consistent_label_str_tests",
         timeout = "short",

lib/utils.bzl

@@ -11,5 +11,8 @@ is_external_label = utils.is_external_label
 maybe_http_archive = utils.maybe_http_archive
 path_to_workspace_root = utils.path_to_workspace_root
 propagate_well_known_tags = utils.propagate_well_known_tags
+propagate_common_rule_attributes = utils.propagate_common_rule_attributes
+propagate_common_test_rule_attributes = utils.propagate_common_test_rule_attributes
+propagate_common_binary_rule_attributes = utils.propagate_common_binary_rule_attributes
 to_label = utils.to_label
 consistent_label_str = utils.consistent_label_str