Add a test task

README.md

@@ -29,3 +29,4 @@ Tasks
 Tasks added to your project when applying this plugin:
 
 - *scalafmt* - formats your scala and sbt source code based on the provided configuration
+- *scalafmtTest* - tests whether all files are correctly formatted, if not, the task fails

src/main/groovy/cz/alenkacz/gradle/scalafmt/ScalafmtFormatBase.groovy

@@ -5,20 +5,30 @@ import org.gradle.api.plugins.JavaBasePlugin
 import org.scalafmt.Scalafmt
 
 class ScalafmtFormatBase extends DefaultTask {
-    def runScalafmt() {
+    def runScalafmt(boolean testOnly = false) {
         if (project.plugins.withType(JavaBasePlugin).empty) {
             logger.info("Java or Scala gradle plugin not available in this project, nothing to format")
             return
         }
-
+        def misformattedFiles = new ArrayList<String>()
         project.sourceSets.all { sourceSet ->
             sourceSet.allSource.filter { File f -> canBeFormatted(f) }.each { File f ->
                 String contents = f.text
                 logger.debug("Formatting '$f'")
                 def formattedContents = Scalafmt.format(contents, ConfigFactory.load(logger, project, project.scalafmt.configFilePath), Scalafmt.format$default$3())
-                f.write(formattedContents.get())
+                if (testOnly) {
+                    if (contents != formattedContents.get()) {
+                        misformattedFiles.add(f.absolutePath)
+                    }
+                } else {
+                    f.write(formattedContents.get())
+                }
             }
         }
+
+        if (testOnly && !misformattedFiles.empty) {
+            throw new ScalafmtFormatException(misformattedFiles)
+        }
     }
 
     def boolean canBeFormatted(File file) {

src/main/groovy/cz/alenkacz/gradle/scalafmt/ScalafmtFormatException.groovy

@@ -0,0 +1,7 @@
+package cz.alenkacz.gradle.scalafmt
+
+class ScalafmtFormatException extends Exception {
+    public ScalafmtFormatException(List<String> filePaths) {
+        super("Files incorrectly formatted: " + filePaths.join(","))
+    }
+}

src/main/groovy/cz/alenkacz/gradle/scalafmt/ScalafmtPlugin.groovy

@@ -6,7 +6,8 @@ import org.gradle.api.Project
 class ScalafmtPlugin implements Plugin<Project> {
     @Override
     void apply(Project project) {
-        ScalafmtTask scalafmtTask = project.task('scalafmt', type: ScalafmtTask)
-        PluginExtension extension = project.extensions.create('scalafmt', PluginExtension)
+        project.task('scalafmt', type: ScalafmtTask)
+        project.task('scalafmtTest', type: ScalafmtTestTask)
+        project.extensions.create('scalafmt', PluginExtension)
     }
 }

src/main/groovy/cz/alenkacz/gradle/scalafmt/ScalafmtTestTask.groovy

@@ -0,0 +1,10 @@
+package cz.alenkacz.gradle.scalafmt
+
+import org.gradle.api.tasks.TaskAction
+
+class ScalafmtTestTask extends ScalafmtFormatBase {
+    @TaskAction
+    def format() {
+        runScalafmt(true)
+    }
+}

src/test/groovy/cz/alenkacz/gradle/scalafmt/ProjectMother.groovy

@@ -4,6 +4,24 @@ import java.nio.file.Files
 import java.nio.file.Paths
 
 class ProjectMother {
+    static def basicProjectWithCorrectlyFormattedFile() {
+        TestProject testProject = null
+        File.createTempDir().with {
+            deleteOnExit()
+            def srcFolder = new File(absoluteFile, sourceFilePath)
+            srcFolder.mkdirs()
+            def srcFile = Files.createFile(Paths.get(srcFolder.absolutePath, "Test.scala"))
+            srcFile.write """import java.nio.file.{Paths, Files}
+                     |object Test {
+                     |  foo(a, // comment
+                     |      b)
+                     |}
+                     |""".stripMargin()
+            testProject = new TestProject(absoluteFile, srcFile.toFile())
+        }
+        return testProject
+    }
+
     static def basicProject() {
         TestProject testProject = null
         File.createTempDir().with {

src/test/groovy/cz/alenkacz/gradle/scalafmt/ScalafmtTestTaskTest.groovy

@@ -0,0 +1,34 @@
+package cz.alenkacz.gradle.scalafmt
+
+import org.gradle.testfixtures.ProjectBuilder
+import spock.lang.Specification
+
+class ScalafmtTestTaskTest extends Specification {
+    def "fail for badly formatted code"() {
+        given:
+        def testProject = ProjectMother.basicProject()
+        def project = ProjectBuilder.builder().withProjectDir(testProject.projectRoot).build()
+        project.plugins.apply 'scala'
+        project.plugins.apply 'scalafmt'
+
+        when:
+        project.tasks.scalafmtTest.format()
+
+        then:
+        thrown ScalafmtFormatException
+    }
+
+    def "not fail for correctly formatted code"() {
+        given:
+        def testProject = ProjectMother.basicProjectWithCorrectlyFormattedFile()
+        def project = ProjectBuilder.builder().withProjectDir(testProject.projectRoot).build()
+        project.plugins.apply 'scala'
+        project.plugins.apply 'scalafmt'
+
+        when:
+        project.tasks.scalafmtTest.format()
+
+        then:
+        noExceptionThrown()
+    }
+}