automake-ized

COPYING

@@ -291,7 +291,7 @@ convey the exclusion of warranty; and each file should have at least
 the "copyright" line and a pointer to where the full notice is found.
 
     <one line to give the program's name and a brief idea of what it does.>
-    Copyright (C) 19yy  <name of author>
+    Copyright (C) <year>  <name of author>
 
     This program is free software; you can redistribute it and/or modify
     it under the terms of the GNU General Public License as published by
@@ -313,7 +313,7 @@ Also add information on how to contact you by electronic and paper mail.
 If the program is interactive, make it output a short notice like this
 when it starts in an interactive mode:
 
-    Gnomovision version 69, Copyright (C) 19yy name of author
+    Gnomovision version 69, Copyright (C) year  name of author
     Gnomovision comes with ABSOLUTELY NO WARRANTY; for details type `show w'.
     This is free software, and you are welcome to redistribute it
     under certain conditions; type `show c' for details.

ChangeLog

@@ -0,0 +1,80 @@
+2002-03-28  Steven G. Johnson  <stevenj@ab-initio>
+
+	* sines.c: add noise option -N
+
+2002-03-18  Steven G. Johnson  <stevenj@ab-initio>
+
+	* harminv-main.c: bug fix in -f parsing
+
+2001-10-28  Steven G. Johnson  <stevenj@ab-initio>
+
+	* configure.in: slightly updated complex tests
+
+2000-06-06  Steven G. Johnson  <stevenj@ab-initio>
+
+	* sines.c:
+	bug fix: default # timesteps should be NPERIODS periods, not 1.
+
+	* README: added README
+
+2000-06-05  Steven G. Johnson  <stevenj@ab-initio>
+
+	* harminv.1: note that inputs are whitespace-separated
+
+	* harminv.1: many improvements
+
+	* configure.in: cray has CGEEV, not ZGEEV
+
+	* configure.in, harminv.c: more cray fixes (sigh)
+
+	* harminv.h, configure.in: Cray doesn't have carg
+
+	* sines.c: don't divide by zero, not all machines support 1/0 = inf
+
+	* configure.in: check for I constant
+
+	* harminv.c: make F77_FUNC slightly more general
+
+	* harminv.c: whoops, ref was correct
+
+	* harminv.c: fixed reference
+
+	* harminv.c:
+	disable LAPACK "optimal workspace" computation, as LAPACK seems to be buggy sometimes.
+
+	* Makefile.in: 'make dist' needs to run autoheader.
+
+	* configure.in, harminv-main.c, harminv.c: cleaned up warnings
+
+	* sines.c: fixed compilation error under C
+
+2000-06-04  Steven G. Johnson  <stevenj@ab-initio>
+
+	* sines.c: explained meaning of Im[freq]
+
+	* Makefile.in, sines.c: added sines test program
+
+	* harminv.1: weakened description of error output.
+
+	* harminv-main.c: match column ordering in man page
+
+	* harminv.1, harminv-main.c: added man page
+
+	* configure.in, harminv-main.c, harminv.c, harminv.h, Makefile.in:
+	added C++ complex<double> support
+
+	* harminv-main.c: sign-related bugfixes
+
+	* harminv-main.c: bug fix
+
+	* harminv.h, COPYING, COPYRIGHT, check.h, copyright.h, harminv-main.c, harminv.c:
+	added copyright info
+
+	* configure.in, harminv-main.c, harminv.h, install-sh, Makefile, Makefile.in, config.guess, config.sub:
+	autoconfiscated
+
+	* Makefile, check.h, harminv-main.c, harminv.c, harminv.h: New file.
+
+	* Makefile, check.h, harminv-main.c, harminv.c, harminv.h:
+	created repository
+

Makefile.am

@@ -0,0 +1,7 @@
+bin_PROGRAMS = harminv
+dist_man_MANS = harminv.1
+noinst_PROGRAMS = sines
+
+harminv_SOURCES = harminv-main.c harminv.c check.h config.h	\
+		  copyright.h harminv.h
+sines_SOURCES = sines.c harminv.c

NEWS

@@ -0,0 +1 @@
+harminv will be released someday.

acx_blas.m4

@@ -0,0 +1,149 @@
+dnl @synopsis ACX_BLAS([ACTION-IF-FOUND[, ACTION-IF-NOT-FOUND]])
+dnl
+dnl This macro looks for a library that implements the BLAS
+dnl linear-algebra interface (see http://www.netlib.org/blas/).
+dnl On success, it sets the BLAS_LIBS output variable to
+dnl hold the requisite library linkages.
+dnl
+dnl To link with BLAS, you should link with:
+dnl 	$BLAS_LIBS $LIBS $FLIBS
+dnl in that order.  FLIBS is the output variable of the
+dnl AC_F77_LIBRARY_LDFLAGS macro (called if necessary by ACX_BLAS),
+dnl and is sometimes necessary in order to link with F77 libraries.
+dnl Users will also need to use AC_F77_DUMMY_MAIN (see the autoconf
+dnl manual), for the same reason.
+dnl
+dnl Many libraries are searched for, from ATLAS to CXML to ESSL.
+dnl The user may also use --with-blas=<lib> in order to use some
+dnl specific BLAS library <lib>.  In order to link successfully,
+dnl however, be aware that you will probably need to use the same
+dnl Fortran compiler (which can be set via the F77 env. var.) as
+dnl was used to compile the BLAS library.
+dnl
+dnl ACTION-IF-FOUND is a list of shell commands to run if a BLAS
+dnl library is found, and ACTION-IF-NOT-FOUND is a list of commands
+dnl to run it if it is not found.  If ACTION-IF-FOUND is not specified,
+dnl the default action will define HAVE_BLAS.
+dnl
+dnl This macro requires autoconf 2.50 or later.
+dnl
+dnl @version $Id: acx_blas.m4,v 1.1 2002/11/04 04:54:49 stevenj Exp $
+dnl @author Steven G. Johnson <[email protected]>
+
+AC_DEFUN([ACX_BLAS], [
+AC_PREREQ(2.50)
+AC_REQUIRE([AC_F77_LIBRARY_LDFLAGS])
+acx_blas_ok=no
+
+AC_ARG_WITH(blas,
+	[AC_HELP_STRING([--with-blas=<lib>], [use BLAS library <lib>])])
+case $with_blas in
+	yes | "") ;;
+	no) acx_blas_ok=disable ;;
+	-* | */* | *.a | *.so | *.so.* | *.o) BLAS_LIBS="$with_blas" ;;
+	*) BLAS_LIBS="-l$with_blas" ;;
+esac
+
+# Get fortran linker names of BLAS functions to check for.
+AC_F77_FUNC(sgemm)
+AC_F77_FUNC(dgemm)
+
+acx_blas_save_LIBS="$LIBS"
+LIBS="$LIBS $FLIBS"
+
+# First, check BLAS_LIBS environment variable
+if test $acx_blas_ok = no; then
+if test "x$BLAS_LIBS" != x; then
+	save_LIBS="$LIBS"; LIBS="$BLAS_LIBS $LIBS"
+	AC_MSG_CHECKING([for $sgemm in $BLAS_LIBS])
+	AC_TRY_LINK_FUNC($sgemm, [acx_blas_ok=yes], [BLAS_LIBS=""])
+	AC_MSG_RESULT($acx_blas_ok)
+	LIBS="$save_LIBS"
+fi
+fi
+
+# BLAS linked to by default?  (happens on some supercomputers)
+if test $acx_blas_ok = no; then
+	save_LIBS="$LIBS"; LIBS="$LIBS"
+	AC_CHECK_FUNC($sgemm, [acx_blas_ok=yes])
+	LIBS="$save_LIBS"
+fi
+
+# BLAS in ATLAS library? (http://math-atlas.sourceforge.net/)
+if test $acx_blas_ok = no; then
+	AC_CHECK_LIB(atlas, ATL_xerbla,
+		[AC_CHECK_LIB(f77blas, $sgemm,
+		[AC_CHECK_LIB(cblas, cblas_dgemm,
+			[acx_blas_ok=yes
+			 BLAS_LIBS="-lcblas -lf77blas -latlas"],
+			[], [-lf77blas -latlas])],
+			[], [-latlas])])
+fi
+
+# BLAS in PhiPACK libraries? (requires generic BLAS lib, too)
+if test $acx_blas_ok = no; then
+	AC_CHECK_LIB(blas, $sgemm,
+		[AC_CHECK_LIB(dgemm, $dgemm,
+		[AC_CHECK_LIB(sgemm, $sgemm,
+			[acx_blas_ok=yes; BLAS_LIBS="-lsgemm -ldgemm -lblas"],
+			[], [-lblas])],
+			[], [-lblas])])
+fi
+
+# BLAS in Alpha CXML library?
+if test $acx_blas_ok = no; then
+	AC_CHECK_LIB(cxml, $sgemm, [acx_blas_ok=yes;BLAS_LIBS="-lcxml"])
+fi
+
+# BLAS in Alpha DXML library? (now called CXML, see above)
+if test $acx_blas_ok = no; then
+	AC_CHECK_LIB(dxml, $sgemm, [acx_blas_ok=yes;BLAS_LIBS="-ldxml"])
+fi
+
+# BLAS in Sun Performance library?
+if test $acx_blas_ok = no; then
+	if test "x$GCC" != xyes; then # only works with Sun CC
+		AC_CHECK_LIB(sunmath, acosp,
+			[AC_CHECK_LIB(sunperf, $sgemm,
+        			[BLAS_LIBS="-xlic_lib=sunperf -lsunmath"
+                                 acx_blas_ok=yes],[],[-lsunmath])])
+	fi
+fi
+
+# BLAS in SCSL library?  (SGI/Cray Scientific Library)
+if test $acx_blas_ok = no; then
+	AC_CHECK_LIB(scs, $sgemm, [acx_blas_ok=yes; BLAS_LIBS="-lscs"])
+fi
+
+# BLAS in SGIMATH library?
+if test $acx_blas_ok = no; then
+	AC_CHECK_LIB(complib.sgimath, $sgemm,
+		     [acx_blas_ok=yes; BLAS_LIBS="-lcomplib.sgimath"])
+fi
+
+# BLAS in IBM ESSL library? (requires generic BLAS lib, too)
+if test $acx_blas_ok = no; then
+	AC_CHECK_LIB(blas, $sgemm,
+		[AC_CHECK_LIB(essl, $sgemm,
+			[acx_blas_ok=yes; BLAS_LIBS="-lessl -lblas"],
+			[], [-lblas $FLIBS])])
+fi
+
+# Generic BLAS library?
+if test $acx_blas_ok = no; then
+	AC_CHECK_LIB(blas, $sgemm, [acx_blas_ok=yes; BLAS_LIBS="-lblas"])
+fi
+
+AC_SUBST(BLAS_LIBS)
+
+LIBS="$acx_blas_save_LIBS"
+
+# Finally, execute ACTION-IF-FOUND/ACTION-IF-NOT-FOUND:
+if test x"$acx_blas_ok" = xyes; then
+        ifelse([$1],,AC_DEFINE(HAVE_BLAS,1,[Define if you have a BLAS library.]),[$1])
+        :
+else
+        acx_blas_ok=no
+        $2
+fi
+])dnl ACX_BLAS