NAME

Udev::FFI - Perl bindings for libudev using ffi.

SYNOPSIS

use Udev::FFI;
use Udev::FFI::Devnum qw(:all); # <- import major, minor and makedev

# get udev library version
my $udev_version = Udev::FFI::udev_version() or
    die("Can't get udev library version: $@");


# create Udev::FFI object
my $udev = Udev::FFI->new() or
    die("Can't create Udev::FFI object: $@");


# create udev monitor
my $monitor = $udev->new_monitor() or
    die("Can't create udev monitor: $@");

# add filter to monitor
unless ($monitor->filter_by_subsystem_devtype('block')) {
    warn("Ouch!");
}

# start monitor
if ($monitor->start()) {
    for (;;) {
        # poll devices, now insert or remove your block device
        my $device = $monitor->poll(); # blocking read
        my $action = $device->get_action();

        print("ACTION: $action\n");
        print('SYSNAME: '.$device->get_sysname()."\n");
        print('DEVNODE: '.$device->get_devnode()."\n");

        last; # for example
    }

    for (;;) {
        # poll devices, now insert or remove your block device
        if (defined(my $device = $monitor->poll(0))) { # non-blocking read like can_read in IO::Select
            my $action = $device->get_action();

            print("ACTION: $action\n");
            print('SYSNAME: '.$device->get_sysname()."\n");
            print('DEVNODE: '.$device->get_devnode()."\n");
        }

        sleep(1);

        last; # for example
    }
}


# enumerate devices
my $enumerate = $udev->new_enumerate() or
    die("Can't create enumerate context: $@");

$enumerate->add_match_subsystem('block');
$enumerate->scan_devices();

use Data::Dumper; # for dump values in $href and @a

# scalar context
my $href = $enumerate->get_list_entries();
print(Dumper($href)."\n");

# list context
my @a = $enumerate->get_list_entries();
print(Dumper(@a)."\n");

if (@a) { # we got devices
    my $device = $udev->new_device_from_syspath($a[0]);

    if (defined($device)) {
        print('Device: '.$device->get_sysname()."\n");

        my $devnum = $device->get_devnum();

        # major, minor and makedev from Udev::FFI::Devnum
        my ($ma, $mi) = (major($devnum), minor($devnum));

        print("Major: $ma\n");
        print("Minor: $mi\n");

        $devnum = makedev($ma, $mi);
        print("Devnum: $devnum\n");


        # scalar context
        $href = $device->get_properties_list_entries();
        print(Dumper($href)."\n");

        # list context
        @a = $device->get_properties_list_entries();
        print(Dumper(@a)."\n");
    }
}

DESCRIPTION

Udev::FFI exposes OO interface to libudev.

CONSTRUCTOR

new()

This is the constructor for a new Udev::FFI object.

If the constructor fails undef will be returned and an error message will be in $@.
```
  my $udev = Udev::FFI->new() or
      die("Can't create Udev::FFI object: $@");
```

METHODS

new_monitor( [SOURCE] )

Create new udev monitor and connect to a specified event source. Valid sources identifiers are 'udev' and 'kernel'. This argument is optional and defaults to 'udev'.

Return new Udev::FFI::Monitor object on success, undef with the error in $@ on failure.

my $monitor = $udev->new_monitor() or
    die("Can't create udev monitor: $@");

new_enumerate()

Create an enumeration context to scan /sys.

Return new Udev::FFI::Enumerate object on success, undef with the error in $@ on failure.

my $enumerate = $udev->new_enumerate() or
    die("Can't create enumerate context: $@");

new_device_from_syspath( SYSPATH )

Create new udev device, and fill in information from the sys device and the udev database entry. The syspath is the absolute path to the device, including the sys mount point.