chore: Release preparation kitchen sink

.github/workflows/linters-win32.yml

@@ -46,4 +46,4 @@ jobs:
 
     - name: Run mypy
       run: |
-        uv run make lint-win32
+        uv run just win32-lint-mypy

.github/workflows/linters.yml

@@ -44,18 +44,18 @@ jobs:
       run: |
         uv sync --all-extras --dev
 
-    - name: Run ruff
+    - name: Run reuse lint
       run: |
-        uv run ruff check src tests
+        uv run just lint-reuse
 
-    - name: Run mypy
+    - name: Run ruff format
       run: |
-        uv run mypy src tests
+        uv run just lint-ruff-format
 
-    - name: Run ruff format
+    - name: Run ruff check
       run: |
-        uv run ruff format --check src tests
+        uv run just lint-ruff-check
 
-    - name: Run reuse lint
+    - name: Run mypy
       run: |
-        uv run reuse lint
+        uv run just lint-mypy

.github/workflows/tests.yml

@@ -44,7 +44,7 @@ jobs:
 
     - name: Run pytest
       run: |
-        uv run make pytest
+        uv run just run-test-pytest
 
   bats:
     strategy:
@@ -78,4 +78,4 @@ jobs:
 
     - name: Run bats
       run: |
-        uv run make bats
+        uv run just run-test-bats

CONTRIBUTING.md

@@ -18,8 +18,6 @@ Several linters and unit tests are used to catch programming errors and regressi
 The relevant tools and their versions are specified in the `pyproject.toml`.
 [Github Actions](https://docs.github.com/en/actions) are configured to run against all merge requests.
 
-To run these checks locally, use `make lint` and `make test`.
-
 ## Commit Messages
 
 We use [Conventional Commits](https://www.conventionalcommits.org/en/v1.0.0/) for structured commit messages.

justfile

@@ -0,0 +1,63 @@
+# SPDX-FileCopyrightText: AISEC Pentesting Team
+#
+# SPDX-License-Identifier: CC0-1.0
+
+default:
+    @just --list
+
+[private]
+lint-mypy:
+    mypy --pretty src tests
+
+[private]
+lint-ruff-check:
+    ruff check
+
+[private]
+lint-ruff-format:
+    ruff format --check
+
+[private]
+lint-shellcheck:
+    find tests/bats \( -iname "*.bash" -or -iname "*.bats" -or -iname "*.sh" \) | xargs shellcheck
+
+[private]
+lint-reuse:
+    reuse lint
+
+lint: lint-mypy lint-ruff-check lint-ruff-format lint-ruff-format lint-shellcheck lint-reuse
+
+win32-lint-mypy:
+    mypy --platform win32 --exclude "gallia\/log\.py" --exclude "hr" src tests
+
+fmt:
+    ruff check --fix-only
+    ruff format
+    find tests/bats \( -iname "*.bash" -or -iname "*.bats" -or -iname "*.sh" \) | xargs shfmt -w
+
+run-tests: run-test-pytest run-test-bats
+
+run-test-pytest:
+    python -m pytest -v --cov={{justfile_directory()}} --cov-report html tests/pytest
+
+run-test-bats:
+    ./tests/bats/run_bats.sh
+
+gen-constants: && fmt
+    ./scripts/gen_constants.py > src/gallia/transports/_can_constants.py
+
+release increment:
+    cz bump --increment {{increment}}
+    git push --follow-tags
+    gh release create "v$(cz version -p)"
+
+pre-release increment premode:
+    cz bump --increment {{increment}} --prerelease {{premode}}
+    git push --follow-tags
+    gh release create --prerelease "v$(cz version -p)"
+
+make-docs:
+    make -C docs html
+
+clean:
+    make -C docs clean

pyproject.toml

@@ -52,6 +52,7 @@ dependencies = [
 [project.optional-dependencies]
 dev = [
     "Sphinx >=8.0",
+    "commitizen>=4.1.0",
     "construct-typing >=0.5.2,<0.7.0",
     "mypy >=1.0,<2.0",
     "myst-parser >=3.0.1,<4.1",
@@ -63,6 +64,7 @@ dev = [
     "python-lsp-server >=1.5,<2.0",
     "reuse >=4.0,<5.0",
     "ruff >=0.8.0",
+    "rust-just>=1.38.0",
     "sphinx-rtd-theme >=3",
     "types-tabulate >=0.9,<0.10",
 ]
@@ -129,3 +131,10 @@ asyncio_default_fixture_loop_scope = "function"
 filterwarnings = [
     "error::UserWarning",
 ]
+
+[tool.commitizen]
+name = "cz_conventional_commits"
+tag_format = "v$version"
+version_scheme = "pep440"
+version_provider = "pep621"
+annotated_tag = true

scripts/gen_constants.py

@@ -6,7 +6,6 @@
 
 import socket
 
-
 TEMPLATE = f"""# This file has been autogenerated by `make constants`.
 # !! DO NOT CHANGE MANUALLY !!