vrjugglua-config-build-tree.cmake.in

# CMake cross-platform build system
# 2009-2010 Ryan Pavlik <rpavlik@iastate.edu>
# http://academic.cleardefinition.com/
# Iowa State University HCI Graduate Program/VRAC

set(VRJUGGLUA_LIBRARIES vrjlua_buildtree_vrjugglua)
set(VRJUGGLUA_FLTK_CONSOLE_LIBRARIES vrjlua_buildtree_vrjugglua-fltk)
set(VRJUGGLUA_QT_CONSOLE_LIBRARIES vrjlua_buildtree_vrjugglua-qt)

set(VRJUGGLUA_BASE_DIR "@CMAKE_CURRENT_BINARY_DIR@")

set(VRJUGGLUA_INCLUDE_DIRS
	"@CMAKE_CURRENT_SOURCE_DIR@/third-party/lua-5.1.4/src"
	"@CMAKE_CURRENT_SOURCE_DIR@/third-party/Fl_Native_File_Chooser-0.86"
	"@CMAKE_CURRENT_SOURCE_DIR@/third-party/luabind"
	"@OSGLUA_INCLUDE_DIRS@"
	"@CMAKE_CURRENT_SOURCE_DIR@"
	"@CMAKE_CURRENT_BINARY_DIR@")

set(VRJUGGLUA_VRJ30 @BUILD_WITH_VRJ30@)

if(			(NOT BOOST_INCLUDEDIR)
		AND (NOT BOOST_LIBRARYDIR)
		AND (NOT BOOST_ROOT)
		AND (NOT BOOSTROOT))

	set(BOOST_LIBRARYDIR @Boost_LIBRARY_DIRS@)
	set(BOOST_INCLUDEDIR @Boost_INCLUDE_DIR@)
endif()

function(install_vrjugglua_lua_files)
	install(DIRECTORY "${VRJUGGLUA_BASE_DIR}/share/vrjugglua/"
		DESTINATION "share/vrjugglua/"
		${ARGN})

	install(DIRECTORY "@CMAKE_CURRENT_SOURCE_DIR@/assets"
		DESTINATION "share/vrjugglua/"
		${ARGN})
endfunction()

include("@CMAKE_CURRENT_BINARY_DIR@/vrjugglua-targets.cmake")

set(_luac_target_file "@CMAKE_CURRENT_BINARY_DIR@/vrjugglua-luac-target.cmake")
if((NOT TARGET luac) AND (EXISTS "${_luac_target_file}"))
	include("${_luac_target_file}")
endif()

set(BUILD_LUA_AS_CPP @BUILD_LUA_AS_CPP@)
if(BUILD_LUA_AS_CPP)
	list(APPEND VRJUGGLUA_DEFINITIONS -DLUABIND_CPLUSPLUS_LUA)
endif()

set(VRJUGGLUA_FOUND ON)