-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathhsp2vlmetsmods.xsl
195 lines (180 loc) · 8.8 KB
/
hsp2vlmetsmods.xsl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:TEI="http://www.tei-c.org/ns/1.0"
xmlns:mods="http://www.loc.gov/mods/v3" xmlns:dc="http://purl.org/dc/elements/1.1/"
xmlns:dcterms="http://purl.org/dc/terms/" xmlns:mets="http://www.loc.gov/METS/"
xmlns:xlink="http://www.w3.org/1999/xlink"
xmlns:xs="http://www.w3.org/2001/XMLSchema"
exclude-result-prefixes="xs"
version="2.0">
<xsl:output encoding="UTF-8" method="xml" indent="yes" omit-xml-declaration="no"/>
<xsl:template match="/">
<mets:mets>
<mets:metsHdr>
<mets:agent ROLE="CREATOR">
<mets:name>hsp2vlmetsmods-Skript Knepper 10/2024</mets:name>
</mets:agent>
</mets:metsHdr>
<xsl:message>
<xsl:text>Processing </xsl:text>
<xsl:value-of select="base-uri()"/>
</xsl:message>
<xsl:apply-templates mode="mods"/>
<mets:structMap TYPE="logical">
<xsl:apply-templates mode="map"/>
</mets:structMap>
</mets:mets>
</xsl:template>
<xsl:template match="TEI:msDesc" mode="mods">
<xsl:message>
<xsl:text>MODS: </xsl:text>
<xsl:value-of select="@xml:id"/>
</xsl:message>
<xsl:if test="not(TEI:msIdentifier/TEI:idno/text())">
<xsl:message>
<xsl:text>Warnung: keine Signatur</xsl:text>
</xsl:message>
</xsl:if>
<mets:dmdSec ID="{concat('md-',@xml:id)}">
<mets:mdWrap MIMETYPE="text/xml" MDTYPE="MODS">
<mets:xmlData>
<mods:mods>
<mods:recordInfo>
<mods:recordIdentifier>
<xsl:value-of select="@xml:id"/>
</mods:recordIdentifier>
</mods:recordInfo>
<xsl:choose>
<xsl:when test="@type='hsp:object'">
<mods:identifier type="HSP">
<xsl:value-of select="@xml:id"/>
</mods:identifier>
</xsl:when>
<xsl:when test="@type='hsp:description'">
<mods:location>
<mods:url displayLabel="Ausführliche Beschreibung">
<xsl:value-of select="concat('https://handschriftenportal.de/search?hspobjectid=',@xml:id)"/>
</mods:url>
</mods:location>
</xsl:when>
</xsl:choose>
<mods:genre authority="marcgt">script</mods:genre>
<mods:genre authority="lcgft">script</mods:genre>
<mods:typeOfResource>text</mods:typeOfResource>
<mods:accessCondition type="use and reproduction" xlink:href="https://creativecommons.org/publicdomain/mark/1.0/" displayLabel="Public Domain Mark 1.0">pdm</mods:accessCondition>
<mods:originInfo>
<mods:issuance>monographic</mods:issuance>
<xsl:apply-templates mode="mods-origininfo"/>
</mods:originInfo>
<mods:physicalDescription>
<mods:extent>
<xsl:value-of select="string-join((.//TEI:index[@indexName='norm_measure']/TEI:term[@type='measure']/text(),
.//TEI:index[@indexName='norm_material']/TEI:term[@type='material']/text(),
.//TEI:index[@indexName='norm_dimensions']/TEI:term[@type='dimensions']/text()),' ; ')"/>
</mods:extent>
</mods:physicalDescription>
<xsl:apply-templates mode="mods"/>
<xsl:if test="not(.//TEI:index[@indexName='norm_textLang'])">
<mods:language>
<mods:languageTerm type="code" authority="iso639-2b">
<xsl:text>lat</xsl:text>
</mods:languageTerm>
</mods:language>
</xsl:if>
</mods:mods>
</mets:xmlData>
</mets:mdWrap>
</mets:dmdSec>
</xsl:template>
<xsl:template match="TEI:altIdentifier[@type='hsp-ID']/TEI:idno" mode="mods">
<mods:identifier type="HSP">
<xsl:value-of select="."/>
</mods:identifier>
</xsl:template>
<xsl:template match="TEI:altIdentifier[not(@type='hsp-ID')]" mode="mods"/>
<xsl:template match="TEI:idno" mode="mods">
<mods:location>
<mods:physicalLocation authorityURI="http://d-nb.info/gnd/" valueURI="http://d-nb.info/gnd/{../TEI:repository/@ref}">
<xsl:value-of select="../TEI:repository"/>
</mods:physicalLocation>
<mods:shelfLocator>
<xsl:value-of select="string-join((../TEI:repository,.),' : ')"/>
</mods:shelfLocator>
</mods:location>
</xsl:template>
<xsl:template match="TEI:msPart" mode="#all"/>
<xsl:template match="TEI:index[@indexName='norm_title']" mode="mods">
<mods:titleInfo>
<mods:title>
<xsl:value-of select="string-join((../../TEI:msIdentifier/TEI:idno,TEI:term[@type='title']),' - ')"/>
</mods:title>
</mods:titleInfo>
</xsl:template>
<xsl:template match="TEI:listBibl/TEI:bibl/TEI:ref" mode="mods">
<mods:location>
<mods:url displayLabel="Ausführliche Beschreibung">
<xsl:value-of select="concat('https://handschriftenportal.de/search?hspobjectid=',@target)"/>
</mods:url>
</mods:location>
</xsl:template>
<xsl:template match="TEI:index[@indexName='norm_origDate']" mode="mods-origininfo">
<mods:dateIssued>
<xsl:value-of select="TEI:term[@type='origDate']"/>
</mods:dateIssued>
<mods:dateIssued encoding="w3cdtf" point="start" keyDate="yes">
<xsl:value-of select="TEI:term[@type='origDate_notBefore']"/>
</mods:dateIssued>
<mods:dateIssued encoding="w3cdtf" point="end">
<xsl:value-of select="TEI:term[@type='origDate_notAfter']"/>
</mods:dateIssued>
</xsl:template>
<xsl:template match="TEI:index[@indexName='norm_origPlace']" mode="mods-origininfo">
<xsl:for-each select="TEI:term[@type='origPlace']">
<mods:place>
<mods:placeTerm type="text">
<xsl:value-of select="."/>
</mods:placeTerm>
</mods:place>
</xsl:for-each>
<xsl:for-each select="TEI:term[@type='origPlace_norm'][starts-with(@ref,'http://d-nb.info/gnd/')]">
<mods:place>
<mods:placeTerm authorityURI="http://d-nb.info/gnd/" valueURI="{@ref}"/>
<mods:placeTerm type="text">
<xsl:value-of select="."/>
</mods:placeTerm>
</mods:place>
</xsl:for-each>
</xsl:template>
<xsl:template match="TEI:index[@indexName='norm_textLang']/TEI:term[@type='textLang-ID']" mode="mods">
<xsl:variable name="iso639_1" select="('de','la','it','fr','ca')"/>
<xsl:variable name="iso639_2b" select="('ger','lat','ita','fre','cat')"/>
<xsl:variable name="i" select="index-of($iso639_1,.)"/>
<xsl:if test="$i>0">
<mods:language>
<mods:languageTerm type="code" authority="iso639-2b">
<xsl:value-of select="$iso639_2b[$i]"/>
</mods:languageTerm>
</mods:language>
</xsl:if>
</xsl:template>
<!--
<xsl:template match="TEI:index[indexName='Autorschaft']/TEI:term[@type='textLang-ID']" mode="mods">
<name type="personal" authorityURI="http://d-nb.info/gnd/" valueURI="http://d-nb.info/gnd/118522213">
<displayForm>Cornelius, Peter</displayForm>
<namePart>Cornelius, Peter</namePart>
<role>
<roleTerm type="code" authority="marcrelator">aut</roleTerm>
<roleTerm>author</roleTerm>
</role>
</name>
</xsl:template>
-->
<xsl:template match="TEI:msDesc" mode="map">
<xsl:message>
<xsl:text>Map: </xsl:text>
<xsl:value-of select="@xml:id"/>
</xsl:message>
<mets:div TYPE="document" DMDID="{concat('md-',@xml:id)}" LABEL="Handschrift"/>
</xsl:template>
<xsl:template match="text()" mode="#all"/>
</xsl:stylesheet>