func7.fj

// Calculate the squared distance between each pair of points (between the 3 points)
// Tests a complicated call stack, with many push/pop n, that's repeated 3 times.


stl.startup_and_init_all 100
N = 2
STACK_N = (N+1)/2

hex.set N, p1_x, 9
hex.set N, p1_y, 0-54

hex.set N, p2_x, 0-22
hex.set N, p2_y, 69

hex.set N, p3_x, 87
hex.set N, p3_y, 0-127

calc_dist_squared p1_x, p1_y, p2_x, p2_y, "dist[p1, p2] ** 2 = 0x"
calc_dist_squared p1_x, p1_y, p3_x, p3_y, "dist[p1, p3] ** 2 = 0x"
calc_dist_squared p2_x, p2_y, p3_x, p3_y, "dist[p2, p3] ** 2 = 0x"


stl.loop

p1_x: hex.vec N
p1_y: hex.vec N
p2_x: hex.vec N
p2_y: hex.vec N
p3_x: hex.vec N
p3_y: hex.vec N



def calc_dist_squared x1, y1, x2, y2, prefix_distance_string @ end, res < math.square_distance {
    stl.output 'A'
    pushN x1
    pushN y1
    pushN x2
    pushN y2
    stl.output 'B'

    stl.call math.square_distance, 2*STACK_N
    stl.output 'I'

    pop2N res
    stl.output "J\n"

    stl.output prefix_distance_string
    hex.print_as_digit 2*N, res, 1
    stl.output "\n\n"

    ;end
  res: hex.vec 2*N
  end:
}



ns math {
sub:
ns sub {
    hex.sp_dec
    popN .res
    popN .temp
    stl.output "-1"

    hex.sub N, .res, .temp
    stl.output '2'

    pushN .res
    hex.sp_add STACK_N+1
    stl.output "3-"

    stl.return
res: hex.vec N
temp: hex.vec N
}


add_2N:
ns add_2N {
    hex.sp_dec
    pop2N .res
    pop2N .temp
    stl.output "-1"

    hex.add 2*N, .res, .temp
    stl.output '2'

    push2N .res
    hex.sp_add 2*STACK_N+1
    stl.output "3-"
    stl.return

res: hex.vec 2*N
temp: hex.vec 2*N
}


mul:
ns mul {
    stl.output "-1"
    hex.sp_dec

    stl.output '2'
    popN .temp1
    hex.sign_extend 2*N, N, .temp1
    stl.output '3'
    popN .temp2
    hex.sign_extend 2*N, N, .temp2

    stl.output '4'
    hex.mul 2*N, .res, .temp1, .temp2

    stl.output '5'
    push2N .res
    hex.sp_inc

    stl.output "6-"
    stl.return

temp1: hex.vec 2*N
temp2: hex.vec 2*N
res: hex.vec 2*N
}


square_sub:
ns square_sub {
    hex.sp_dec
    popN .b
    popN .a
    hex.sp_add 2*STACK_N+1
    stl.output 'a'

    pushN .a
    pushN .b
    stl.call ..sub, STACK_N
    popN .res
    stl.output 'b'

    pushN .res
    pushN .res
    stl.call ..mul
    pop2N .res
    stl.output 'c'

    hex.sp_sub 2*STACK_N+1
    push2N .res
    hex.sp_inc
    stl.output "d\n"

    stl.return

a: hex.vec 2*N
b: hex.vec 2*N
res: hex.vec 2*N
}


square_distance:
ns square_distance {
    stl.output 'C'
    hex.sp_dec
    popN .y2
    popN .x2
    popN .y1
    popN .x1
    hex.sp_add 4*STACK_N+1
    stl.output 'D'

    // (x1-x2)**2
    pushN .x1
    pushN .x2
    stl.call ..square_sub
    pop2N .res1
    stl.output 'E'
    // (y1-y2)**2
    pushN .y1
    pushN .y2
    stl.call ..square_sub
    pop2N .res2
    stl.output 'F'

    // (x1-x2)**2 + (y1-y2)**2
    push2N .res1
    push2N .res2
    stl.call ..add_2N, 2*STACK_N
    pop2N .res1
    stl.output 'G'

    hex.sp_sub 4*STACK_N+1
    push2N .res1
    hex.sp_add 2*STACK_N+1
    stl.output 'H'

    stl.return

x1: hex.vec N
y1: hex.vec N
x2: hex.vec N
y2: hex.vec N
res1: hex.vec 2*N
res2: hex.vec 2*N
}
}


// Push+Pop fast-functions

def pushN variable < pushN, stack_variable, pushed_ret {
    hex.mov N, stack_variable, variable
    stl.fcall pushN, pushed_ret
}

def push2N variable < push2N, stack_variable, pushed_ret {
    hex.mov 2*N, stack_variable, variable
    stl.fcall push2N, pushed_ret
}

def popN variable < popN, stack_variable, pushed_ret {
    stl.fcall popN, pushed_ret
    hex.mov N, variable, stack_variable
}

def pop2N variable < pop2N, stack_variable, pushed_ret {
    stl.fcall pop2N, pushed_ret
    hex.mov 2*N, variable, stack_variable
}


stack_variable: hex.vec 2*N
pushed_ret: bit.bit

pushN:
hex.push N, stack_variable
stl.fret pushed_ret

push2N:
hex.push 2*N, stack_variable
stl.fret pushed_ret

popN:
hex.pop N, stack_variable
stl.fret pushed_ret

pop2N:
hex.pop 2*N, stack_variable
stl.fret pushed_ret