kiloparsec

#!/usr/bin/env perl

# MP4: https://youtu.be/vstdXn_ufVY

use strict;
use warnings;

# Prefer my local library
use lib '/Users/gene/sandbox/MIDI-Util/lib';

use MIDI::Util qw(setup_score set_chan_patch);
use Music::Scales qw/ get_scale_notes /;
use Music::Voss qw/ powers /;

my $max = shift || 64;
my $bpm = shift || 200;

my $scale_note          = 'C';
my $alto_scale_name     = 'minor';
my $tenor_scale_name    = 'pminor';
my $baritone_scale_name = 'pminor';

my $alto_patch     = 69;
my $tenor_patch    = 70;
my $baritone_patch = 42;

my $quarter = 'qn';
my $half    = 'hn';
my $whole   = 'wn';

my $score = setup_score( lead_in => 0, bpm => $bpm );

$score->synch(
    \&alto,
    \&tenor,
    \&baritone,
);

$score->write_score("$0.mid");

sub alto {
    set_chan_patch( $score, 0, $alto_patch );

    my ( $scale, $genf ) = get_genf( $scale_note, 5, $alto_scale_name );

    my $i = 0;

    for my $n ( 0 .. $max - 1 ) {
        if ( $n % 4 == 0 ) {
            for ( 1 .. 4 ) {
                $score->n( $quarter, $scale->[ $genf->($n) ] );
            }

            if ( $i % 3 == 0 ) {
                $score->n( $quarter, $scale->[ $genf->($n) ] );
            }
        }
        else {
            $score->r($whole);
        }

        $i++;
    }

    $score->r($whole);
}

sub tenor {
    set_chan_patch( $score, 1, $tenor_patch );

    my ( $scale, $genf ) = get_genf( $scale_note, 4, $tenor_scale_name );

    for my $n ( 0 .. $max - 1 ) {
        if ( $n < 8 ) {
            $score->r($whole);
        }
        else {
            if ( $n % 2 == 0 ) {
                $score->n( $half, $scale->[ $genf->($n) ] );
            }
            else {
                $score->r($half);
            }

            if ( $n % 3 == 0 ) {
                $score->n( $half, $scale->[ $genf->($n) ] );
            }
            else {
                $score->r($half);
            }
        }
    }

    $score->n( $whole, $scale->[0] );
}

sub baritone {
    set_chan_patch( $score, 2, $baritone_patch );

    my ( $scale, $genf ) = get_genf( $scale_note, 3, $baritone_scale_name );

    for my $n ( 0 .. $max - 1 ) {
        if ( $n < 8 ) {
            $score->r($whole);
        }
        else {
            $score->n( $whole, $scale->[ $genf->($n) ] );
        }
    }

    $score->n( $whole, $scale->[0] );
}

sub get_genf {
    my ( $note, $octave, $name ) = @_;

    my @scale = map { $_ . $octave } get_scale_notes( $note, $name );
    for ( @scale ) {
        s/#/s/;
        s/b/f/;
    }

    my $seed = [ map { sub { int rand 2 } } @scale ];
    my $genf = powers( calls => $seed );

    return \@scale, $genf;
}