Justfile

set positional-arguments

# default recipe to display help information
default:
  @just --list

# Install required dependencies
deps:
    cargo install mdbook mdbook-katex mdbook-linkcheck mdbook-mermaid
    pnpm i --frozen-lockfile

# Lint the workspace for all available targets
lint: lint-specs-md-check lint-specs-toc-check lint-filenames lint-links lint-specs-spelling

# Updates all files to fix linting issues
lint-fix: lint-specs-md-fix lint-specs-toc

# Validates markdown file formatting
lint-specs-md-check:
    npx markdownlint-cli2 "./specs/**/*.md"

# Updates markdown files formatting to satisfy lints
lint-specs-md-fix:
    npx markdownlint-cli2 --fix "./specs/**/*.md"

# Validates Table of Content Sections with doctoc
lint-specs-toc-check:
    npx doctoc '--title=**Table of Contents**' ./specs && git diff --exit-code ./specs

# Updates Table of Content Sections with doctoc
lint-specs-toc:
    npx doctoc '--title=**Table of Contents**' ./specs

# Validates all hyperlinks respond with status 200
lint-links:
    docker run --init -it -v `pwd`:/input lycheeverse/lychee --verbose --no-progress --exclude-loopback \
    		--exclude twitter.com --exclude explorer.optimism.io --exclude linux-mips.org --exclude vitalik.eth.limo \
    		--exclude-mail /input/README.md "/input/specs/**/*.md"

# Validates spelling using cspell
lint-specs-spelling:
    npx cspell "./**/*.md"

# Updates cspell words file with new words
lint-specs-spelling-fix:
    npx cspell --words-only --unique "./**/*.md" | sort --ignore-case | uniq > words.txt

lint-filenames:
    #!/usr/bin/env bash
    for file in $(find ./specs -type f); do
      if [[ "$file" == *_* ]]; then
        echo "File with underscore found: $file"
        exit 1
      fi
    done
    echo "Filename linting complete"

build:
    mdbook build

# Serves the mdbook locally
serve *args='':
    mdbook serve $@