forked from emacs-slack/emacs-slack
-
Notifications
You must be signed in to change notification settings - Fork 0
/
slack-message-reaction.el
171 lines (146 loc) · 6.52 KB
/
slack-message-reaction.el
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
;;; slack-message-reaction.el --- adding, removing reaction from message -*- lexical-binding: t; -*-
;; Copyright (C) 2015 yuya.minami
;; Author: yuya.minami <[email protected]>
;; Keywords:
;; This program is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.
;; This program is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
;; GNU General Public License for more details.
;; You should have received a copy of the GNU General Public License
;; along with this program. If not, see <http://www.gnu.org/licenses/>.
;;; Commentary:
;;
;;; Code:
(require 'slack-message)
(require 'slack-reaction)
(require 'slack-room)
(defconst slack-message-reaction-add-url "https://slack.com/api/reactions.add")
(defconst slack-message-reaction-remove-url "https://slack.com/api/reactions.remove")
(defvar slack-current-team-id)
(defvar slack-current-room-id)
(defvar slack-emojify-comp-list)
(defcustom slack-invalid-emojis '("^:flag_" "tone[[:digit:]]:$" "-" "^[^:].*[^:]$" "\\Ca")
"Invalid emoji regex. Slack server treated some emojis as Invalid."
:group 'slack)
(defun slack-message-reaction-load-emojify-comp-list ()
(if (and (bound-and-true-p emojify-emojis)
(not (bound-and-true-p slack-emojify-comp-list)))
(setq slack-emojify-comp-list
(let ((invalid-regex (mapconcat #'identity
slack-invalid-emojis
"\\|")))
(cl-remove-if (lambda (s) (string-match invalid-regex s))
(hash-table-keys emojify-emojis))))))
(defun slack-message-add-reaction ()
(interactive)
(let* ((ts (slack-get-ts))
(reaction (slack-message-reaction-input))
(team (slack-team-find slack-current-team-id))
(room (slack-room-find slack-current-room-id
team)))
(slack-message-reaction-add reaction ts room team)))
(defun slack-message-remove-reaction ()
(interactive)
(let* ((team (slack-team-find slack-current-team-id))
(room (slack-room-find slack-current-room-id
team))
(ts (slack-get-ts))
(msg (slack-room-find-message room ts))
(reactions (slack-message-get-reactions msg))
(reaction (slack-message-reaction-select reactions)))
(slack-message-reaction-remove reaction ts room team)))
(defun slack-message-show-reaction-users ()
(interactive)
(let* ((team (slack-team-find slack-current-team-id))
(reaction (ignore-errors (get-text-property (point) 'reaction))))
(if reaction
(let ((user-names (slack-reaction-user-names reaction team)))
(message "reacted users: %s" (mapconcat #'identity user-names ", ")))
(message "Can't get reaction:"))))
(defun slack-message-reaction-select (reactions)
(let ((list (mapcar #'(lambda (r)
(cons (oref r name)
(oref r name)))
reactions)))
(slack-select-from-list
(list "Select Reaction: ")
selected)))
(defun slack-message-reaction-input ()
(slack-message-reaction-load-emojify-comp-list)
(let ((reaction (if (bound-and-true-p slack-emojify-comp-list)
(completing-read "Select Emoji: " slack-emojify-comp-list)
(read-from-minibuffer "Emoji: "))))
(if (and (string-prefix-p ":" reaction)
(string-suffix-p ":" reaction))
(substring reaction 1 -1)
reaction)))
(defmethod slack-message-get-param-for-reaction ((m slack-message))
(cons "timestamp" (oref m ts)))
(defmethod slack-message-get-param-for-reaction ((m slack-file-share-message))
(cons "file" (oref (oref m file) id)))
(defmethod slack-message-get-param-for-reaction ((m slack-file-comment-message))
(cons "file_comment" (oref (oref m comment) id)))
(defun slack-message-reaction-add (reaction ts room team)
(let ((message (slack-room-find-message room ts)))
(when message
(cl-labels ((on-reaction-add
(&key data &allow-other-keys)
(slack-request-handle-error
(data "slack-message-reaction-add"))))
(slack-request
slack-message-reaction-add-url
team
:type "POST"
:sync nil
:params (list (cons "channel" (oref room id))
(slack-message-get-param-for-reaction message)
(cons "name" reaction))
:success #'on-reaction-add)))))
(defun slack-message-reaction-remove (reaction ts room team)
(let ((message (slack-room-find-message room ts)))
(when message
(cl-labels ((on-reaction-remove
(&key data &allow-other-keys)
(slack-request-handle-error
(data "slack-message-reaction-remove"))))
(slack-request
slack-message-reaction-remove-url
team
:type "POST"
:sync nil
:params (list (cons "channel" (oref room id))
(slack-message-get-param-for-reaction message)
(cons "name" reaction))
:success #'on-reaction-remove)))))
(cl-defmacro slack-message-find-reaction ((m reaction) &body body)
`(let ((same-reaction
(cl-find-if #'(lambda (r) (slack-reaction-equalp r ,reaction))
(slack-message-get-reactions ,m))))
,@body))
(defmethod slack-message-append-reaction ((m slack-message) reaction)
(let ((reactions (slack-message-get-reactions m)))
(slack-message-find-reaction
(m reaction)
(if same-reaction
(slack-reaction-join same-reaction reaction)
(push reaction reactions)
(slack-message-set-reactions m reactions)))))
(defmethod slack-message-pop-reaction ((m slack-message) reaction)
(slack-message-find-reaction
(m reaction)
(if same-reaction
(if (eq 1 (oref same-reaction count))
(progn
(let ((reactions (slack-message-get-reactions m)))
(slack-message-set-reactions
m
(cl-delete-if
#'(lambda (r) (slack-reaction-equalp same-reaction r))
reactions))))
(cl-decf (oref same-reaction count))))))
(provide 'slack-message-reaction)
;;; slack-message-reaction.el ends here