Implement more suffix classes, esp. for lisp variables/options

[tarsius]

No description provided.

[vifon]

A suffix class for minor-mode toggles with the current state indicator would be very welcome too.

[tarsius]

A suffix class for minor-mode toggles with the current state indicator would be very welcome too.

A simple implementation of that:

(defun demo-minor-mode-description (obj)
  (let* ((mode (oref obj command))
         (lighter (cadr (assq mode minor-mode-alist))))
    (when (and lighter (symbolp lighter))
      (setq lighter (symbol-value lighter)))
    (format
     ;; Personally I would just use the mode name, even if there is a lighter.
     ;; Other users might want to see the mode docstring instead/also.
     (if lighter "%s %s (%s)" "%s %s")
     (or lighter mode)
     (cond ((symbol-value mode)
            (format
             (propertize "[%s|%s]" 'face 'transient-delimiter)
             (propertize "on"  'face 'transient-value)
             (propertize "off" 'face 'transient-infix-value)))
           ((format
             (propertize "[%s|%s]" 'face 'transient-delimiter)
             (propertize "on"  'face 'transient-infix-value)
             (propertize "off" 'face '((:foreground "red") transient-value)))))
     mode)))

(transient-define-prefix demo ()
  :transient-suffix 'transient--do-stay
  [("a" outline-minor-mode :description demo-minor-mode-description)])

;; (demo)

It seems to me that the main complication is having to decide how to present the information. And that different users will have different opinions on what would be best, which makes it unappealing to add this to Transient itself.

One problem with the above is that one has to add :description demo-minor-mode-description explicitly for each mode command, but adding a class does not actually help:

(defclass transient-minor-mode-command (transient-suffix)
  ())

(cl-defmethod transient-format-description ((obj transient-minor-mode-command))
  (with-current-buffer transient--current-buffer
    ... as above...))

(transient-define-prefix demo ()
  :transient-suffix 'transient--do-stay
  ;; Hurray! We don't have to specify :description. Oh no! We have to specify :class.
  [("a" outline-minor-mode :class transient-minor-mode-command)])

[tarsius]

An idea that might be worth considering, is adding a :suffix-class slot to transient-prefix:

(transient-define-prefix demo ()
  :transient-suffix 'transient--do-stay
  :suffix-class 'transient-minor-mode-command
  [("a" outline-minor-mode)
   ("b" another-minor-mode)])

Then again, we might want to generate the list of minor-mode suffixes, instead of hardcoding them, at which point having to specify the :class or :description slot for each suffix doesn't matter anymore.

I might something like this to my minions package eventually. It already dynamically generates a drop-down menu, and might as well support generating a transient menu too.

[tarsius]

When tackling this issue, also consider whether adding something like transient-defvar would make sense, as suggested in #262.