forked from ostat/vacuum-hose-adapter-openscad
-
Notifications
You must be signed in to change notification settings - Fork 0
/
vacuum-hose-adapter-modules.scad
1415 lines (1277 loc) · 48 KB
/
vacuum-hose-adapter-modules.scad
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
// Hose connector modules
// version 2023-02-23
use <dotSCAD/src/ring_extrude.scad>
use <dotSCAD/src/shape_circle.scad>
// https://justinsdk.github.io/dotSCAD/
/* [Hidden] */
fudgeFactor = 0.015;
dysonMinLength = 46;
dysonInnerDiameter = 28.5;
dysonOuterDiameter = 34;
//diameter1: Inner start diameter.
//diameter2: Inner end diameter.
//length: pipe length
//wallThickness1 Thickness of the walls at the start
//wallThickness2 Thickness of the walls at the end
//zPosition: Start Z position.
module Pipe(
diameter1,
diameter2,
length,
wallThickness1,
wallThickness2,
zPosition = 0,
xOffset = 0,
yOffset = 0)
{
difference ()
{
//outer cylinder
translate([0,0,zPosition])
hull()
{
cylinder(fudgeFactor, d=diameter1+2*wallThickness1);
translate([xOffset,yOffset,length-fudgeFactor])
cylinder(fudgeFactor, d=diameter2+2*wallThickness2);
}
//Inner cylinder to remove
translate([0,0,zPosition-fudgeFactor])
hull()
{
cylinder(fudgeFactor, d=diameter1);
translate([xOffset,yOffset,length+2*fudgeFactor])
cylinder(fudgeFactor, d=diameter2);
}
}
}
module StraightPipe(
diameter,
length,
wallThickness,
zPosition = 0)
{
Pipe (
diameter1 = diameter,
diameter2 = diameter,
length = length,
wallThickness1 = wallThickness,
wallThickness2 = wallThickness,
zPosition = zPosition);
}
module HalfConePipe(diameter, length, wallThickness1, wallThickness2, zPosition)
{
Pipe (
diameter1 = diameter,
diameter2 = diameter,
length = length,
wallThickness1 = wallThickness1,
wallThickness2 = wallThickness2,
zPosition = zPosition);
}
module ConeRing(centerDiameter, length, wallThickness1, wallThickness2, zPosition)
{
difference ()
{
//outer cylinder
translate([0, 0, zPosition])
cylinder(
d1=centerDiameter+wallThickness1,
d2=centerDiameter+wallThickness2,
h=length);
//Inner cylinder to remove
translate([0, 0, zPosition-fudgeFactor])
cylinder(
d1=centerDiameter-wallThickness1,
d2=centerDiameter-wallThickness2,
h=length + 2*fudgeFactor);
}
}
module BentPipeHull(
inner1PipeRadius,
inner2PipeRadius,
end1WallThickness,
end2WallThickness,
pipeAngle = 0,
zPosition=0,
end2Count=1,
lengthInHull=0,
lengthOutHull=0,
edgeOffset = 0
)
{
outer1PipeRadius = inner1PipeRadius+ end1WallThickness;
outer2PipeRadius = inner2PipeRadius + end2WallThickness;
//_edgeOffset = outer1PipeRadius - outer2PipeRadius - edgeOffset;
_edgeOffset = edgeOffset;
end1BaseHeight = end1WallThickness;
end2BaseHeight = end2WallThickness;
echo(_edgeOffset = _edgeOffset, lengthInHull = lengthInHull, lengthOutHull=lengthOutHull, outer1PipeRadius=outer1PipeRadius, outer2PipeRadius=outer2PipeRadius, a= (cos(pipeAngle) * outer2PipeRadius*2) );
difference(){
//Outer shape
union(){
hull(){
for (rotation = [0:end2Count-1])
{
rotate([0,0,rotation*(360/end2Count)])
rotate_about_pt(0, -pipeAngle, [-outer1PipeRadius,0,0])
translate([-_edgeOffset, 0, lengthInHull])
cylinder(r=outer2PipeRadius, h=end2WallThickness);
}
cylinder(r=outer1PipeRadius, h=end1BaseHeight+fudgeFactor);
}
for (rotation = [0:end2Count-1])
{
//End 2 extentions
echo("Outer shape", pipeAngle=pipeAngle, outer1PipeRadius=outer1PipeRadius, outer2PipeRadius=outer2PipeRadius, _edgeOffset=_edgeOffset, lengthInHull=lengthInHull, end2WallThickness=end2WallThickness );
rotate([0,0,rotation*(360/end2Count)])
rotate_about_pt(0, -pipeAngle, [-outer1PipeRadius,0,0])
translate([-_edgeOffset, 0, lengthInHull])
cylinder(r=outer2PipeRadius, h=lengthOutHull+fudgeFactor);
}
}
//inner/negative shape
union(){
hull(){
for (rotation = [0:end2Count-1])
{
//End 2
rotate([0,0,rotation*(360/end2Count)])
rotate_about_pt(0, -pipeAngle, [-outer1PipeRadius,0,0])
translate([-_edgeOffset, 0, -end2BaseHeight+fudgeFactor+lengthInHull])
cylinder(r=inner2PipeRadius, h=end2WallThickness+fudgeFactor*2);
}
//End 1
cylinder(r=inner1PipeRadius, h=end1BaseHeight+fudgeFactor*2);
}
for (rotation = [0:end2Count-1])
{
//End 2 extentions
rotate([0,0,rotation*(360/end2Count)])
rotate_about_pt(0, -pipeAngle, [-outer1PipeRadius,0,0])
translate([-_edgeOffset, 0, -end2BaseHeight+fudgeFactor+lengthInHull])
cylinder(r=inner2PipeRadius, h=lengthOutHull+end2WallThickness*2+fudgeFactor*2);
}
}
//Clear start from clipping
rotate([0, 0, pipeAngle])
translate([0, 0, -fudgeFactor])
cylinder(
r=inner1PipeRadius,
h=fudgeFactor*2);
}
}
// rotate as per a, v, but around point pt
module rotate_about_pt(z, y, pt) {
translate(pt)
rotate([0, y, z]) // CHANGE HERE
translate(-pt)
children();
}
module BentPipe(
bendRadius,
innerPipeDiameter,
wallThickness,
pipeAngle,
zPosition = 0,
baseType="none",
baseWidth=0,
baseLength=0,
baseThickness=0,
baseAngle=0,
end2Count=1
)
{
outerPipeDiameter = innerPipeDiameter + wallThickness * 2;
baseSupportThickness = outerPipeDiameter/2 + baseThickness;
baseSupportWidth = baseWidth == 0 ? outerPipeDiameter / 2 : baseWidth;
baseSupportLength = baseLength == 0 ? outerPipeDiameter / 1.5 : baseLength;
baseSupportAngle = baseAngle == 0 ? pipeAngle/2 : baseAngle;
echo("BentPipe", bendRadius=bendRadius, innerPipeDiameter=innerPipeDiameter,wallThickness=wallThickness, pipeAngle=pipeAngle, zPosition=zPosition);
echo("BentPipe", baseSupportWidth=baseSupportWidth, baseSupportLength=baseSupportLength);
difference() {
for (rotation = [0:end2Count-1])
{
rotate([0,0,rotation*(360/end2Count)])
translate([-bendRadius, 0, zPosition])
rotate([90, 0, 0])
union(){
// printing base
if (end2Count <= 1 && baseType != "none"){
rotate([0,0,baseSupportAngle])
translate([bendRadius,0,0])
rotate([0,90,0])
if (baseType == "rectangle")
translate([0,0,baseSupportThickness/2]) cube( [baseSupportWidth,baseSupportLength,baseSupportThickness],center=true);
else if (baseType == "oval")
resize([baseSupportWidth,0,0]) cylinder(h=baseSupportThickness,d=baseSupportLength);
}
rotate_extrude(angle=pipeAngle, convexity=10)
translate([bendRadius, 0, 0])
circle(d=outerPipeDiameter);
}
}
for (rotation = [0:end2Count-1])
{
rotate([0,0,rotation*(360/end2Count)])
translate([-bendRadius, 0, zPosition])
rotate([90, 0, 0])
union(){
rotate([0, 0, -1])
rotate_extrude(angle=pipeAngle+2,convexity=10)
translate([bendRadius, 0, 0])
circle(d=innerPipeDiameter);
//Clear start from clipping
rotate([90, 0, pipeAngle])
translate([bendRadius, 0, -baseSupportThickness])
cylinder(
d=innerPipeDiameter,
h=baseSupportThickness);
//Clear end of the pipe from clipping
rotate([90, 0, 0])
translate([bendRadius, 0, 0])
cylinder(d=innerPipeDiameter, h=baseSupportThickness);
}}
}
}
module TaperedBentPipe(
bendRadius,
end1InnerPipeDiameter,
end2InnerPipeDiameter,
end1WallThickness,
end2WallThickness,
pipeAngle,
zPosition = 0,
baseType="none",
baseWidth=0,
baseLength=0,
baseThickness=0,
baseAngle=0,
end2Count=1
)
{
echo("TaperedBentPipe", bendRadius=bendRadius, end1InnerPipeDiameter=end1InnerPipeDiameter, end2InnerPipeDiameter=end2InnerPipeDiameter, end1WallThickness=end1WallThickness, end2WallThickness=end2WallThickness);
outerPipeDiameter = end1InnerPipeDiameter + end1WallThickness * 2;
sizeStart = end1InnerPipeDiameter / 2 + end1WallThickness ;
sizeEnd = end2InnerPipeDiameter / 2 + end2WallThickness ;
//baseSupportThickness should be between the start and end, but wieghted to the thicker end.
supportBaseValue = (max(sizeStart,sizeEnd)*2 + min(sizeStart,sizeEnd))/3;
baseSupportThickness = supportBaseValue + baseThickness;
baseSupportWidth = baseWidth == 0 ? supportBaseValue *1.5 : baseWidth;
baseSupportLength = baseLength == 0 ? supportBaseValue * 2: baseLength;
baseSupportAngle = baseAngle == 0 ? pipeAngle/2 : baseAngle;
shapeOuter = shape_circle(sizeStart);
shapeInner = shape_circle(sizeStart-end1WallThickness);
echo("TaperedBentPipe", baseSupportThickness=baseSupportThickness, baseSupportAngle=baseSupportAngle, baseSupportWidth=baseSupportWidth, baseSupportLength=baseSupportLength);
translate([0, 0, zPosition])
difference(){
difference(){
for(rotation = [0:end2Count-1])
{
rotate([0, 0, rotation*(360/end2Count)])
translate([-bendRadius, 0, 0])
rotate([90, 0, 0])
union(){
// printing base
if (end2Count <= 1 && baseType != "none"){
rotate([0,0,baseSupportAngle])
translate([bendRadius,0,0])
rotate([0,90,0])
if (baseType == "rectangle")
translate([0,0,baseSupportThickness/2]) cube( [baseSupportWidth,baseSupportLength,baseSupportThickness],center=true);
else if (baseType == "oval")
resize([baseSupportWidth,0,0]) cylinder(h=baseSupportThickness,d=baseSupportLength);
}
ring_extrude(shapeOuter, radius = bendRadius, angle = pipeAngle, scale = (sizeEnd/sizeStart ));
}
}
for(rotation = [0:end2Count-1])
{
rotate([0, 0, rotation*(360/end2Count)])
union(){
translate([-bendRadius, 0, 0])
rotate([90, 0, 0])
ring_extrude(
shapeInner,
radius = bendRadius,
angle = pipeAngle,
scale = ((sizeEnd-end2WallThickness)/(sizeStart-end1WallThickness)));
//Clear start from clipping
translate([0, 0, -fudgeFactor])
cylinder(
d=end1InnerPipeDiameter,
h=2*fudgeFactor);
//Clear end of the pipe from clipping
translate([-bendRadius+fudgeFactor, 0, 0])
rotate([0, -pipeAngle, 0])
translate([bendRadius, 0, 0])
cylinder(
d=end2InnerPipeDiameter,
h=2*fudgeFactor);
}
}
}
}
}
module FlangeConnector(
innerStartDiameter,
innerEndDiameter,
length,
wallThickness,
flangeThickness,
flangeWidth,
screwPosition,
screwBorder,
screwCount,
screwDiameter
)
{
//The fillet around the edge
fillet = flangeThickness;
border = screwBorder == 0 ? flangeWidth/4 : screwBorder;
flangeOuterDiameter = innerStartDiameter + flangeWidth;
screwPositionRadius = screwPosition != 0
? innerStartDiameter/2 + screwPosition/2
: (innerStartDiameter/2 + fillet + (flangeWidth/2-fillet)/2);
echo("FlangeConnector", screwCount=screwCount, screwDiameter=screwDiameter, screwPosition=screwPosition, border=border);
echo("FlangeConnector", screwPositionRadius=screwPositionRadius, fillet=fillet, flangeOuterDiameter=flangeOuterDiameter, innerStartDiameter=innerStartDiameter, flangeWidth=flangeWidth);
difference ()
{
//flange
union() {
Pipe (
diameter1 = innerStartDiameter,
diameter2 = innerEndDiameter,
length = length,
wallThickness1 = wallThickness,
wallThickness2 = wallThickness);
// flange aound the screws
hull () {
cylinder (d = flangeOuterDiameter, flangeThickness);
for (i = [0: screwCount-1]) {
// The rotation should try to avoid the screw being under the bent hose.
rotate ([fudgeFactor, 0, 180/screwCount * (i * 2 - 1 + screwCount)])
translate ([screwPositionRadius, 0, 0])
cylinder (d = screwDiameter + border, h = flangeThickness);
}
}
// taper
intersection()
{
HalfConePipe (
diameter = innerEndDiameter,
length = fillet,
wallThickness1 = fillet - fudgeFactor,
wallThickness2 = 0,
zPosition= flangeThickness - fudgeFactor);
translate([0, 0, 0])
{
// limit fillet to length
cylinder(
d=innerEndDiameter*2,
h=length);
}
}
}
//Screw cut out
for (i = [0: screwCount-1]) {
// The rotation should try to avoid the screw being under the bent hose.
rotate ([fudgeFactor, 0, 180/screwCount * (i * 2 - 1 + screwCount)])
translate ([screwPositionRadius, 0, - fudgeFactor*2])
cylinder (d = screwDiameter, h = flangeThickness + length + fudgeFactor*4);
}
//Flange inner
translate([0, 0, -fudgeFactor])
cylinder (
d1 = innerStartDiameter,
d2 = innerEndDiameter,
h = length + 2 * fudgeFactor*2);
}
}
module MagneticConnector(
innerStartDiameter,
innerEndDiameter,
length,
wallThickness,
magnetDiameter,
magnetThickness,
magnetBorder,
flangeThickness,
magnetCount,
alignmentRing,
alignmentDepth,
alignmentUpperWidth,
alignmentLowerWidth,
alignmentSideClearance,
alignmentDepthClearance
)
{
alignmentBorder = alignmentRing != "no" ? magnetBorder/2 : 0;
magnetPosition = (innerStartDiameter + magnetDiameter) / 2 + magnetBorder +
(alignmentRing != "no" ? alignmentBorder + alignmentUpperWidth : 0);
fillet = flangeThickness;
difference ()
{
//flange
union() {
Pipe (
diameter1 = innerStartDiameter,
diameter2 = innerEndDiameter,
length = length,
wallThickness1 = wallThickness,
wallThickness2 = wallThickness);
// flange aound the magnets
hull () {
for (i = [0: magnetCount-1]) {
rotate ([0, 0, i * (360 / magnetCount)])
translate ([magnetPosition, 0, 0])
cylinder (d = magnetDiameter + magnetBorder * 2, flangeThickness);
}
}
// protuding magent rung
if(alignmentRing == "protruding")
{
AlignmentRing(
centerDiameter = innerStartDiameter + alignmentBorder*2 + alignmentUpperWidth,
alignmentDepth = alignmentDepth,
alignmentUpperWidth = alignmentUpperWidth,
alignmentLowerWidth = alignmentLowerWidth,
alignmentSideClearance = alignmentSideClearance,
alignmentDepthClearance = alignmentDepthClearance,
magnetBorder = magnetBorder
);
}
// taper
intersection()
{
HalfConePipe (
diameter = innerEndDiameter,
length = fillet,
wallThickness1 = fillet - fudgeFactor,
wallThickness2 = 0,
zPosition= flangeThickness - fudgeFactor);
translate([0, 0, 0])
{
// incase the connector is less
cylinder(
d=innerEndDiameter*2,
h=length);
}
}
}
//Magnet cut out
for (i = [0: magnetCount-1]) {
rotate ([0, 0, i* 360 / magnetCount])
translate ([magnetPosition, 0, - fudgeFactor])
cylinder (d = magnetDiameter, h = magnetThickness + fudgeFactor);
}
//Flange inner
translate([0, 0, -fudgeFactor])
cylinder (
d1 = innerStartDiameter,
d2 = innerEndDiameter,
h = length + 2 * fudgeFactor);
if(alignmentRing == "recessed")
{
// Create recessed alignment ring
AlignmentRing(
centerDiameter = innerStartDiameter + alignmentBorder*2 + alignmentUpperWidth,
alignmentDepth = alignmentDepth,
alignmentUpperWidth = alignmentUpperWidth,
alignmentLowerWidth = alignmentLowerWidth,
alignmentSideClearance = 0,
alignmentDepthClearance = 0,
magnetBorder = magnetBorder);
}
}
}
module AlignmentRing(
centerDiameter,
alignmentDepth,
alignmentUpperWidth,
alignmentLowerWidth,
alignmentSideClearance,
alignmentDepthClearance,
magnetBorder
)
{
//rotate_extrude()
//translate([45, 0, 0])
//circle(r = 4);
ringHeight = 2*(alignmentDepth-alignmentDepthClearance);
ringMaxWidth = (alignmentUpperWidth - alignmentSideClearance);
ringMinWidth = (alignmentLowerWidth - alignmentSideClearance);
intersection()
{
union()
{
ConeRing (
centerDiameter = centerDiameter,
length = alignmentDepth,
wallThickness1 = ringMaxWidth,
wallThickness2 = ringMinWidth,
zPosition = 0);
//Add a StraightPipe between the two to block clipping without impacting the angle of the cones.
StraightPipe (
diameter = centerDiameter - ringMaxWidth + fudgeFactor,
length = fudgeFactor,
wallThickness = ringMaxWidth- fudgeFactor,
zPosition = -fudgeFactor/2);
ConeRing (
centerDiameter = centerDiameter,
length = alignmentDepth,
wallThickness1 = ringMinWidth,
wallThickness2= ringMaxWidth,
zPosition = -alignmentDepth);
}
translate([0, 0, -ringHeight/2])
{
cylinder(
d=centerDiameter + alignmentUpperWidth,
h=ringHeight);
}
}
}
module DysonConnector(
innerEndDiameter,
length,
wallThickness,
IncludeOrientationClip = true
){
heightStartShaft = 10;
heightCutout= 4.45;
heightCutoutTapper = 2.75;
//heightMainShaft = 28;
orientationClipHeight = 37-.5;
orientationClipCenter = 5.5;
orientationClipTaper = 2;
orientationClipLength = orientationClipCenter + orientationClipTaper*2;
heightMainShaft = orientationClipHeight - (heightStartShaft+heightCutout+heightCutoutTapper) + orientationClipLength;
height = heightStartShaft+heightCutout+heightCutoutTapper+heightMainShaft;
innerDiameter = 28.5;
outerDiameter = 34;
cutoutRadius = 30.7;// dysonInnerDiameter/2;
innerRadius = innerDiameter/2;
outerRadius = outerDiameter/2;
orentationRadius = 34.5/2;
union() {
difference() {
union() {
// Dyson connector
translate([0,0,0])
cylinder(r=outerRadius, h=heightStartShaft);
translate([0,0,heightStartShaft])
cylinder(r=outerRadius-1.5, h=heightCutout);
translate([0,0,heightStartShaft+heightCutout])
cylinder(r1=outerRadius-1.5, r2=outerRadius, h=heightCutoutTapper);
translate([0,0,heightStartShaft+heightCutout+heightCutoutTapper])
cylinder(r=outerRadius, h=heightMainShaft);
// orientation clip
if(IncludeOrientationClip == true){
translate([0,0,orientationClipHeight]) difference() {
union() {
cylinder(r1=outerRadius, r2=outerRadius+1.5, h=orientationClipTaper);
translate([0,0,orientationClipTaper])
cylinder(r=outerRadius+1.5, h=orientationClipCenter);
translate([0,0,orientationClipCenter + orientationClipTaper])
cylinder(r1=outerRadius+1.5, r2=outerRadius, h=orientationClipTaper);
}
for(i=[0,90,180,270])
{
rotate([0,0,i])
difference() {
translate([0,-34.5/2+4,-23/2+6.5]) rotate([90,0,0])
cylinder(r1=23/2, r2=23.5/2, h=7);
hull() {
translate([0,-34.5/2,1.5]) rotate([90,0,0])
cylinder(r1=1.5, r2=1.25, h=2);
translate([0,-34.5/2,8-1.5]) rotate([90,0,0])
cylinder(r1=1.5, r2=1.25, h=2);
}
}
}
}
}
}
//remove center
translate([0,0,-fudgeFactor])
cylinder(r=innerRadius, h=height+2);
}
echo("DysonConnector", innerRadius, innerDiameter, length, height);
Pipe (
diameter1 = innerDiameter,
diameter2 = innerEndDiameter,
length = length - height,
wallThickness1 = (outerDiameter - innerDiameter)/2,
wallThickness2 = wallThickness,
zPosition = height);
}
}
module Nozzle(
innerStartDiameter,
length,
wallThickness,
nozzleShape,
nozzleSquareWidth,
nozzleSquareDepth,
nozzleTipWallThickness,
nozzleRadius,
nozzleLength,
nozzlexOffset = 0,
nozzleyOffset = 0,
nozzleChamferPercentage = 0,
nozzleChamferAngle = 0
)
{
innerRadius = innerStartDiameter/2;
circlepositionx = nozzleShape == "square" ? nozzleSquareDepth/2 - nozzleRadius : 0;
circlepositiony = nozzleShape == "square" ? nozzleSquareWidth/2 - nozzleRadius : 0;
circlepositions = nozzleShape == "square" ?
[[ circlepositionx, circlepositiony ],
[ -circlepositionx, circlepositiony ],
[ circlepositionx, -circlepositiony ],
[ -circlepositionx, -circlepositiony ]] : [[ circlepositionx, circlepositiony ]] ;
nozzleWidth = (nozzleShape == "square" ? nozzleSquareDepth : nozzleRadius * 2) + wallThickness*2;
nozzleDepth = (nozzleShape == "square" ? nozzleSquareWidth : nozzleRadius * 2) + wallThickness*2;
nozzleWidthChamfer = nozzleWidth * nozzleChamferPercentage /100;
nozzleLengthChamfer = nozzleWidthChamfer * tan(nozzleChamferAngle);
tipWallThickness = nozzleTipWallThickness == 0 ? wallThickness : nozzleTipWallThickness;
widthChamfer = min(nozzleWidthChamfer, nozzleWidth);
lengthChamfer = min(nozzleLengthChamfer, nozzleLength);
echo("nozzle", innerRadius=innerRadius, circlepositionx=circlepositionx, circlepositiony=circlepositiony, nozzleWidth=nozzleWidth, nozzleDepth=nozzleDepth, nozzleWidthChamfer=nozzleWidthChamfer, nozzleLengthChamfer=nozzleLengthChamfer, widthChamfer=widthChamfer, lengthChamfer=lengthChamfer);
difference()
{
//Outer Shape
union()
{
// Nozzle base
hull()
{
cylinder(fudgeFactor*2, r=innerRadius+wallThickness);
translate([nozzleyOffset,nozzlexOffset,length + fudgeFactor])
hull() for (i= [ 0 : len(circlepositions) - 1 ])
translate([circlepositions[i][0], circlepositions[i][1], 0])
cylinder(fudgeFactor, r=nozzleRadius+wallThickness+fudgeFactor);
}
// Nozzle
translate([nozzleyOffset,nozzlexOffset,length + fudgeFactor])
hull() for (i= [ 0 : len(circlepositions) - 1 ])
{
translate([circlepositions[i][0], circlepositions[i][1], 0])
cylinder(fudgeFactor, r=nozzleRadius+wallThickness+fudgeFactor);
translate([circlepositions[i][0], circlepositions[i][1], nozzleLength])
cylinder(fudgeFactor, r=nozzleRadius+tipWallThickness+fudgeFactor);
}
}
//Inner shape
union()
{
// Nozzle base
hull()
{
translate([00,0,-fudgeFactor])
cylinder(fudgeFactor*2, r=innerRadius);
translate([nozzleyOffset,nozzlexOffset,length+fudgeFactor])
hull() for (i= [ 0 : len(circlepositions) - 1 ])
translate([circlepositions[i][0], circlepositions[i][1], 0])
cylinder(fudgeFactor*2, r=nozzleRadius+fudgeFactor);
}
// Nozzle
translate([nozzleyOffset,nozzlexOffset,length+fudgeFactor*2])
hull() for (i= [ 0 : len(circlepositions) - 1 ])
translate([circlepositions[i][0], circlepositions[i][1], 0])
cylinder(nozzleLength+fudgeFactor*2, r=nozzleRadius+fudgeFactor);
}
// Chamfer
if(widthChamfer > 0 && lengthChamfer > 0)
{
translate([0,0,nozzleLength+length+fudgeFactor*3] )
rotate([90,0,180])
linear_extrude(nozzleDepth+1, center=true)
polygon( points = [[nozzleWidth/2-widthChamfer,0],
[nozzleWidth/2+fudgeFactor*2,0],
[nozzleWidth/2+fudgeFactor*2,-lengthChamfer]] );
}
}
}
module HoseConnector(
innerStartDiameter,
innerEndDiameter,
connectorMeasurement,
length,
wallThickness,
stopLength,
stopWidth,
stopSymmetrical = 0,
barbsCount = 0,
barbsThickness = 0,
barbsSymmetrical = 0,
endCapDiameter = 0,
endCapThickness = 0,
)
{
_barbsThickness = barbsThickness == 0 ? wallThickness/2 : barbsThickness;
barbLength = length/(barbsCount*2+1);
union() {
difference ()
{
union() {
//outer cylinder
translate([0,0,0])
hull()
{
cylinder(fudgeFactor, d=innerStartDiameter+2*wallThickness);
translate([0,0,length-fudgeFactor])
cylinder(fudgeFactor, d=innerEndDiameter+2*wallThickness);
}
//barbs
if(barbsCount > 0)
{
for (i = [0: barbsCount-1]) {
hull()
{
translate([0,0,length/(barbsCount*2+1)*(i*2+1)])
Stopper(
diameter = innerStartDiameter+wallThickness,
totalLength = barbLength,
taper1 = barbsSymmetrical == 0 ? 1 : 0.4,
taper2 = barbsSymmetrical == 0 ? 0 : 0.4,
wallThickness = wallThickness/2,
stopThickness = _barbsThickness);
}}
}
}
//Inner cylinder to remove
translate([0,0,0-fudgeFactor])
hull()
{
cylinder(fudgeFactor, d=innerStartDiameter);
translate([0,0,length+2*fudgeFactor])
cylinder(fudgeFactor, d=innerEndDiameter);
}
}
// Create the end cap
if(endCapThickness > 0)
{
difference ()
{
cylinder(endCapThickness, d=innerEndDiameter + wallThickness/2);
translate([0,0,-fudgeFactor])
cylinder(endCapThickness + fudgeFactor * 2, d=endCapDiameter);
}
}
// Create the hose stop
if(stopWidth > 0)
{
Stopper(
diameter = innerEndDiameter,
outer = connectorMeasurement == "outer",
totalLength = stopLength,
taper1 = stopSymmetrical == 0 ? 0.5 : 0.4,
taper2 = stopSymmetrical == 0? 0 : 0.4,
wallThickness = wallThickness,
stopThickness = stopWidth,
zPosition = length);
}
}
}
//TODO This seems slow, esp when used for barbs
module Stopper(
diameter,
outer,
totalLength,
taper1,
taper2,
wallThickness,
stopThickness,
zPosition = 0
)
{
intersection()
{
flat = totalLength * (1 - taper1 - taper2);
StraightPipe (
diameter = outer ? diameter : diameter-stopThickness*2,
length = totalLength,
wallThickness = wallThickness + stopThickness,
zPosition = zPosition);
_diameter = outer ? diameter : diameter + wallThickness*2;
//Bottom taper
if(taper1 > 0)
{
taperLength1 = totalLength * taper1;
zoffset1 = wallThickness*taperLength1/stopThickness;
length1= (zoffset1 + totalLength);
width1 = length1 * stopThickness / taperLength1;
diameterstart1 = _diameter;
diameterend1 = outer ? _diameter :_diameter - width1*2;
Pipe (
diameter1 = diameterstart1,
diameter2 = diameterend1,
length = length1,
wallThickness1 = 0,
wallThickness2 = width1,
zPosition = zPosition-zoffset1);
}
//Top taper
if(taper2 > 0)
{
taperLength2 = totalLength * taper2;
zoffset2 = wallThickness * taperLength2 / stopThickness;
length2 = (zoffset2 + totalLength);
width2 = length2 * stopThickness / taperLength2;
diameterstart2 = outer ? _diameter :_diameter - width2*2;
diameterend2 = _diameter;
Pipe (
diameter1 = diameterstart2,
diameter2 = diameterend2,
length = length2,
wallThickness1 = width2,
wallThickness2 = 0,
zPosition = zPosition);
}
}
}
module HoseAdapter(
drawAlignmentRing = "no",
alignmentDepth = 2,
alignmentUpperWidth = 3,
alignmentLowerWidth = 0.5,
alignmentSideClearance = 0.25,
alignmentDepthClearance = .75,
connector1WallThickness = 2,
connector1Style= "hose",
connector1Measurement= "inner",
connector1Diameter = 0,
connector1Length = 0,
connector1Taper = 0,
connector1EndCapDiameter = 0,
connector1EndCapThickness = 0,
connector1StopThickness = 0,
connector1StopLength = 0,
connector1StopSymmetrical = 0,
connector1BarbsCount = 0,
connector1BarbsThickness = 0,
connector1BarbsSymmetrical = 0,
connector1MagnetCount = 0,
connector1MagnetDiameter = 0,
connector1MagnetThickness = 0,
connector1MagnetBorder = 0,
connector1MagnetFlangeThickness = 0,
connector1Ring= "no",
connector1FlangeWidth = 0,
connector1FlangeThickness = 0,
connector1FlangeScrewPosition = 0,
connector1FlangeScrewBorder = 0,
connector1FlangeScrewCount = 0,
connector1FlangeScrewDiameter = 0,
transitionStyle = "tapered",
transitionLength = 0,
transitionBendRadius = 0,
transitionAngle = 0,
transitionXOffset = 0,
transitionYOffset = 0,
transitionBaseType = "none",
transitionBaseThickness =0 ,
transitionBaseWidth =0 ,
transitionBaseLength = 0,
transitionBaseAngle = 0,
transitionEnd2Count = 1,
transitionHullLength = 0,
transitionHullyOffset = 0,
connector2WallThickness = 2,
connector2Style = "hose",
connector2Measurement = "inner",
connector2Diameter = 0,
connector2Length = 0,
connector2Taper = 0,
connector2EndCapDiameter = 0,
connector2EndCapThickness = 0,
connector2StopThickness = 0,
connector2StopLength = 0,
connector2StopSymmetrical = 0,
connector2BarbsCount = 0,
connector2BarbsThickness = 0,