PMASIAUJ - Section 3.5, Exercise 1 question

[mindcrime]

Hi all, Exercise 1 of Section 3.5 in "Programming Multiagent Systems in Agentspeak Using Jason" asks the reader to change the has(owner,beer) plan trigger to only activate when the source is the owner. That's easy enough, and now my goal looks like:

+!has(owner,beer)[source(owner)] : available(beer,fridge) & not too_much(beer) // if there is beer available and the owner is not over the daily limit
    <- .print( "Owner has requested a beer!");

And as expected, the system now fails after the delivery of beer by the supermarket, as there is no longer a matching plan for the has(owner,beer)[source(self)] goal.

[Env] executing: move_towards(fridge)
[Env] l = fridge
[robot] At fridge
[supermarket] Sending 'delivered' message to robot agent
[robot] No fail event was generated for +!has(owner,beer)[source(self)]
[robot] 
intention 11: 
    +delivered(beer,5,2)[source(supermarket)] <- ... !has(owner,beer) / {Qtd=5, OrderId=2}
[robot] Found a goal for which there is no applicable plan: +!has(owner,beer)[source(self)]

I assume this is intended and the goal of the exercise didn't include "fix this so that it works again." But my obsessive nature leads me to want to fix it. Two options I see: duplicate the has(owner,beer) trigger with both forms [source(self)] and [source(owner)]. Or after the beer delivery, send() a message to the owner, saying "ask me for beer again", and once the owner receives that message, have the owner simply send another beer request to the robot.

So my question is: is either of these approaches particularly more idiomatic for Jason, or to be preferred for any other reason? The first approach is arguably "simpler" but requires duplicate code. The second seems more elegant in a way, but is slightly more complex to my way of thinking. OR is there maybe another approach that I'm missing altogether?

[mindcrime]

I tried the second approach mentioned above and it works fine:

robot.asl

// we got a delivery from the supermarket agent
@a2
+delivered(beer, Qtd, OrderId)[source(supermarket)] : true
    <- +available(beer,fridge);
       // !has(owner,beer).
       .send(owner, achieve, ask_beer ).

owner.asl

+!ask_beer : true <- !get(beer). 

My intuition tells me to prefer this, but I'd love to hear what the experts think. :-)

[jomifred]

Hi, I think your solution is reasonable considering the overall application: the owner has to decide about its beers :-). So it seems ok for the robot to delegate this decision to the owner. In your code the owner always accepts the suggestion of the robot, but it could be different.

However, considering just AgentSpeak and your question, we can program the plan for has(owner,beer) using the or operator for two sources:

+!has(owner,beer)[source(A)] : A == owner | A == self .......

or

trust(owner).
trust(self).

+!has(owner,beer)[source(A)] : trust(A)[source(self)]  .......

Notice that I wrote trust(A)[source(self)] instead of trust(A). Otherwise, some malicious agent could just .send(robot, tell, trust(MyName).