flake.nix

{
  description = "Template for Holochain app development";

  # Note that this flake is partly based on https://tauri.app/v1/guides/getting-started/prerequisites/#setting-up-linux
  # and partly on Holonix. Please check both when making updates!

  inputs = {
    nixpkgs.follows = "holochain/nixpkgs";
    versions.url = "github:holochain/holochain?dir=versions/0_2";

    holochain = {
      url = "github:holochain/holochain";
      inputs.versions.follows = "versions";
    };
  };

  outputs = inputs @ {...}:
    inputs.holochain.inputs.flake-parts.lib.mkFlake
    {
      inherit inputs;
    }
    {
      systems = builtins.attrNames inputs.holochain.devShells;
      perSystem = {
        self',
        inputs',
        config,
        pkgs,
        system,
        lib,
        ...
      }: let
        libraries = with pkgs; [
          webkitgtk
          gtk3
          cairo
          gdk-pixbuf
          glib
          dbus
          openssl_3
          librsvg
        ] ++ lib.optionals pkgs.stdenv.isLinux [
          bzip2
          pango
          libsoup
          libappindicator
        ];

        packages = with pkgs; [
          curl
          wget
          pkg-config
          dbus
          openssl_3
          glib
          gtk3
          libsoup
          webkitgtk
          librsvg
        ];
      in {
        devShells.default = pkgs.mkShell {
          inputsFrom = [inputs'.holochain.devShells.rustDev];
          buildInputs = packages;

          shellHook = inputs'.holochain.devShells.rustDev.shellHook +
            ''
              export LD_LIBRARY_PATH=${pkgs.lib.makeLibraryPath libraries}:$LD_LIBRARY_PATH
              export XDG_DATA_DIRS=${pkgs.gsettings-desktop-schemas}/share/gsettings-schemas/${pkgs.gsettings-desktop-schemas.name}:${pkgs.gtk3}/share/gsettings-schemas/${pkgs.gtk3.name}:$XDG_DATA_DIRS
            '';

          packages = with pkgs; [
            nodejs-18_x
            gtksourceview3
            libappindicator
            pango
            squashfsTools
            atk
            llvmPackages.libclang
            llvmPackages.libcxxClang
            clang
            zlib
          ] ++ packages;
        };
      };
    };
}