Parametric Polymorphism / Generics

[loisch]

I'm coming from Haskell where I have a type constructor FinDefSet that takes a type a as a parameter and defines two alternatives AllBut [a] and Only [a]

data FinDefSet a = AllBut [a] | Only [a]

value :: FinDefSet Int
value = Only [1,2,3]

notAllowed :: FinDefSet       -- can't use type constructor without parameter!
notAllowed = Only [] 

I'd like to define the same structure in CUE:

#FinDefSet: {
	_#Type: _
	AllBut: [..._#Type]
} | {
	_#Type: _
	Only: [..._#Type]
}

value: #FinDefSet & { _#Type: int }
value: Only: [1,2,3]

notAllowed: #FinDefSet  
notAllowed: Only: []           // I don't want this to be valid!

but I haven't found a way to define that _#Type must be unified with some "concrete" type. Is there a way to do that?

[myitcv]

I think you achieve what you want by making the _#Type "parameter" required:

! exec cue export x.cue
cmp stderr stderr.golden

exec cue export y.cue
cmp stdout stdout.golden

-- x.cue --
#FinDefSet: {
	_#Type!: _
	AllBut: [..._#Type]
} | {
	_#Type!: _
	Only: [..._#Type]
}

value: #FinDefSet & {_#Type: int}
value: Only: [1, 2, 3]

notAllowed: #FinDefSet
notAllowed: Only: []

-- y.cue --
#FinDefSet: {
	_#Type!: _
	AllBut: [..._#Type]
} | {
	_#Type!: _
	Only: [..._#Type]
}

value: #FinDefSet & {_#Type: int}
value: Only: [1, 2, 3]

notAllowed: #FinDefSet & {_#Type: string}
notAllowed: Only: []

-- stderr.golden --
notAllowed._#Type: field is required but not present:
    ./x.cue:5:2
    ./x.cue:12:13
-- stdout.golden --
{
    "value": {
        "Only": [
            1,
            2,
            3
        ]
    },
    "notAllowed": {
        "Only": []
    }
}

Whether you want to allow empty lists is separate, but easily fixed from this point.