From 4160c7807b31743063c5a2627e025f19b52cc150 Mon Sep 17 00:00:00 2001
From: theverygaming <theverygaming@users.noreply.github.com>
Date: Tue, 31 Dec 2024 05:23:00 +0100
Subject: [PATCH 1/3] maintainers: add theverygaming

---
 maintainers/maintainer-list.nix | 5 +++++
 1 file changed, 5 insertions(+)

diff --git a/maintainers/maintainer-list.nix b/maintainers/maintainer-list.nix
index 93db923c267ec..6fae754f0a9f3 100644
--- a/maintainers/maintainer-list.nix
+++ b/maintainers/maintainer-list.nix
@@ -22628,6 +22628,11 @@
     githubId = 1220572;
     name = "Christian Theune";
   };
+  theverygaming = {
+    name = "theverygaming";
+    github = "theverygaming";
+    githubId = 18639279;
+  };
   thiagokokada = {
     email = "thiagokokada@gmail.com";
     github = "thiagokokada";

From 50807e90bb5a67944aae0cca1b68922271c8210f Mon Sep 17 00:00:00 2001
From: theverygaming <theverygaming@users.noreply.github.com>
Date: Tue, 31 Dec 2024 05:28:19 +0100
Subject: [PATCH 2/3] nng: build with BUILD_SHARED_LIBS=ON

---
 pkgs/by-name/nn/nng/package.nix | 5 ++++-
 1 file changed, 4 insertions(+), 1 deletion(-)

diff --git a/pkgs/by-name/nn/nng/package.nix b/pkgs/by-name/nn/nng/package.nix
index a10611f3a89a9..bd46f8b4b610c 100644
--- a/pkgs/by-name/nn/nng/package.nix
+++ b/pkgs/by-name/nn/nng/package.nix
@@ -27,7 +27,10 @@ stdenv.mkDerivation rec {
   buildInputs = lib.optionals mbedtlsSupport [ mbedtls ];
 
   cmakeFlags =
-    [ "-G Ninja" ]
+    [
+      "-G Ninja"
+      "-DBUILD_SHARED_LIBS=ON"
+    ]
     ++ lib.optionals mbedtlsSupport [
       "-DMBEDTLS_ROOT_DIR=${mbedtls}"
       "-DNNG_ENABLE_TLS=ON"

From eaa37ee25338300882f81a53e42eb99177d440c5 Mon Sep 17 00:00:00 2001
From: theverygaming <theverygaming@users.noreply.github.com>
Date: Tue, 31 Dec 2024 05:28:40 +0100
Subject: [PATCH 3/3] satdump: init at 1.2.2

---
 pkgs/by-name/sa/satdump/package.nix | 109 ++++++++++++++++++++++++++++
 1 file changed, 109 insertions(+)
 create mode 100644 pkgs/by-name/sa/satdump/package.nix

diff --git a/pkgs/by-name/sa/satdump/package.nix b/pkgs/by-name/sa/satdump/package.nix
new file mode 100644
index 0000000000000..259cb1a4e730f
--- /dev/null
+++ b/pkgs/by-name/sa/satdump/package.nix
@@ -0,0 +1,109 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  gitUpdater,
+  cmake,
+  pkg-config,
+  # required dependencies
+  fftwFloat,
+  libpng,
+  libtiff,
+  jemalloc,
+  volk,
+  nng,
+  curl,
+  # Optional dependencies
+  withZIQRecordingCompression ? true,
+  zstd,
+  withGUI ? true,
+  glfw,
+  zenity,
+  withAudio ? true,
+  portaudio,
+  withOfficialProductSupport ? true,
+  hdf5,
+  withOpenCL ? true,
+  opencl-headers,
+  ocl-icd,
+  withSourceRtlsdr ? true,
+  rtl-sdr-librtlsdr,
+  withSourceHackRF ? true,
+  hackrf,
+  withSourceAirspy ? true,
+  airspy,
+  withSourceAirspyHF ? true,
+  airspyhf,
+  withSourceAD9361 ? true,
+  libad9361,
+  libiio,
+  withSourceBladeRF ? true,
+  libbladeRF,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "satdump";
+  version = "1.2.2";
+
+  src = fetchFromGitHub {
+    owner = "SatDump";
+    repo = "SatDump";
+    tag = finalAttrs.version;
+    hash = "sha256-+Sne+NMwnIAs3ff64fBHAIE4/iDExIC64sXtO0LJwI0=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+    pkg-config
+  ];
+
+  buildInputs =
+    [
+      fftwFloat
+      libpng
+      libtiff
+      jemalloc
+      volk
+      nng
+      curl
+    ]
+    ++ lib.optional withZIQRecordingCompression zstd
+    ++ lib.optionals withGUI [
+      glfw
+      zenity
+    ]
+    ++ lib.optional withAudio portaudio
+    ++ lib.optional withOfficialProductSupport hdf5
+    ++ lib.optionals withOpenCL [
+      opencl-headers
+      ocl-icd
+    ]
+    ++ lib.optional withSourceRtlsdr rtl-sdr-librtlsdr
+    ++ lib.optional withSourceHackRF hackrf
+    ++ lib.optional withSourceAirspy airspy
+    ++ lib.optional withSourceAirspyHF airspyhf
+    ++ lib.optionals withSourceAD9361 [
+      libad9361
+      libiio
+    ]
+    ++ lib.optional withSourceBladeRF libbladeRF;
+
+  postPatch = ''
+    substituteInPlace src-core/CMakeLists.txt \
+      --replace-fail '$'{CMAKE_INSTALL_PREFIX}/'$'{CMAKE_INSTALL_LIBDIR} '$'{CMAKE_INSTALL_FULL_LIBDIR}
+  '';
+
+  passthru.updateScript = gitUpdater { };
+
+  meta = {
+    description = "A generic satellite data processing software";
+    homepage = "https://www.satdump.org/";
+    changelog = "https://github.com/SatDump/SatDump/releases/tag/${finalAttrs.version}";
+    license = lib.licenses.gpl3Only;
+    platforms = lib.platforms.linux;
+    maintainers = with lib.maintainers; [
+      theverygaming
+    ];
+    mainProgram = "satdump";
+  };
+})