-
Notifications
You must be signed in to change notification settings - Fork 0
/
eedi2.cuh
1066 lines (866 loc) · 37.5 KB
/
eedi2.cuh
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
/*
* EEDI2CUDA: EEDI2 filter using CUDA
*
* Copyright (C) 2005-2006 Kevin Stone
* Copyright (C) 2014-2019 HolyWu
* Copyright (C) 2021 Misaki Kasumi
*
* This program is free software; you can redistribute it and/or modify it under the terms of the GNU General Public License as published by
* the Free Software Foundation; either version 2 of the License, or (at your option) any later version.
*
* This program is distributed in the hope that it will be useful, but WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License for more details.
*
* You should have received a copy of the GNU General Public License along with this program; if not, write to the Free Software Foundation,
* Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
*/
#pragma once
#include <limits>
#include <type_traits>
#include "common.h"
struct EEDI2Param : public VideoInfo {
unsigned d_pitch, field;
unsigned nt4, nt7, nt8, nt13, nt19;
unsigned mthresh, lthresh, vthresh;
unsigned estr, dstr, maxd;
};
#define KERNEL __global__ __launch_bounds__(64)
#define setup_kernel \
setup_xy; \
int width = d.width, height = d.height; \
auto pitch = d.d_pitch; \
__builtin_assume(width > 0); \
__builtin_assume(height > 0); \
__builtin_assume(x >= 0); \
__builtin_assume(y >= 0); \
constexpr T shift = sizeof(T) * 8 - 8, peak = std::numeric_limits<T>::max(), ten = 10 << shift, twleve = 12 << shift, \
eight = 8 << shift, twenty = 20 << shift, three = 3 << shift, nine = 9 << shift; \
constexpr T shift2 = shift + 2, neutral = peak / 2; \
constexpr int intmax = std::numeric_limits<int>::max()
__device__ int limlut[33]{6, 6, 7, 7, 8, 8, 9, 9, 9, 10, 10, 11, 11, 12, 12, 12, 12,
12, 12, 12, 12, 12, 12, 12, 12, 12, 12, 12, 12, 12, 12, -1, -1};
#define setup_kernel2x \
setup_kernel; \
height *= 2; \
y = d.field ? 2 * y + 1 : 2 * y
#define bounds_check3(value, lower, upper) \
if ((value) < (lower) || (value) >= (upper)) \
return
namespace bose {
template <typename T, size_t I, size_t J> __device__ __forceinline__ void P(T *arr) {
T &a = arr[I - 1], &b = arr[J - 1];
const T c = a;
a = a < b ? a : b;
b = c < b ? b : c;
}
template <typename T, size_t I, size_t X, size_t J, size_t Y> __device__ __forceinline__ void Pbracket(T *arr) {
constexpr size_t A = X / 2, B = (X & 1) ? (Y / 2) : ((Y + 1) / 2);
if constexpr (X == 1 && Y == 1)
P<T, I, J>(arr);
else if constexpr (X == 1 && Y == 2) {
P<T, I, J + 1>(arr);
P<T, I, J>(arr);
} else if constexpr (X == 2 && Y == 1) {
P<T, I, J>(arr);
P<T, I + 1, J>(arr);
} else {
Pbracket<T, I, A, J, B>(arr);
Pbracket<T, I + A, X - A, J + B, Y - B>(arr);
Pbracket<T, I + A, X - A, J, B>(arr);
}
}
template <typename T, size_t I, size_t M> __device__ __forceinline__ void Pstar(T *arr) {
constexpr size_t A = M / 2;
if constexpr (M > 1) {
Pstar<T, I, A>(arr);
Pstar<T, I + A, M - A>(arr);
Pbracket<T, I, A, I + A, M - A>(arr);
}
}
} // namespace bose
template <typename T, size_t N> __device__ __forceinline__ void boseSortArray(T (&arr)[N]) { bose::Pstar<T, 1, N>(arr); }
template <typename T> __device__ __forceinline__ T mmax(T last) { return last; }
template <typename T, typename... Args> __device__ __forceinline__ T mmax(T first, Args... remaining) {
auto candidate = mmax(remaining...);
static_assert(std::is_same<decltype(candidate), T>::value, "arguments must have the same type");
return first < candidate ? candidate : first;
}
template <typename T> __device__ __forceinline__ T mmin(T last) { return last; }
template <typename T, typename... Args> __device__ __forceinline__ T mmin(T first, Args... remaining) {
auto candidate = mmin(remaining...);
static_assert(std::is_same<decltype(candidate), T>::value, "arguments must have the same type");
return first < candidate ? first : candidate;
}
template <typename T> __device__ T round_div(T a, T b) {
// XXX: only for same sign
return (a + (b / 2)) / b;
}
template <typename T> KERNEL void buildEdgeMask(const EEDI2Param d, const T *src, T *dst) {
setup_kernel;
auto srcp = line(src);
auto srcpp = lineOff(src, -1);
auto srcpn = lineOff(src, 1);
auto &out = point(dst);
out = 0;
bounds_check3(x, 1, width - 1);
bounds_check3(y, 1, height - 1);
if ((abs(srcpp[x] - srcp[x]) < ten && abs(srcp[x] - srcpn[x]) < ten && abs(srcpp[x] - srcpn[x]) < ten) ||
(abs(srcpp[x - 1] - srcp[x - 1]) < ten && abs(srcp[x - 1] - srcpn[x - 1]) < ten && abs(srcpp[x - 1] - srcpn[x - 1]) < ten &&
abs(srcpp[x + 1] - srcp[x + 1]) < ten && abs(srcp[x + 1] - srcpn[x + 1]) < ten && abs(srcpp[x + 1] - srcpn[x + 1]) < ten))
return;
const unsigned sum =
(srcpp[x - 1] + srcpp[x] + srcpp[x + 1] + srcp[x - 1] + srcp[x] + srcp[x + 1] + srcpn[x - 1] + srcpn[x] + srcpn[x + 1]) >> shift;
const unsigned sumsq = (srcpp[x - 1] >> shift) * (srcpp[x - 1] >> shift) + (srcpp[x] >> shift) * (srcpp[x] >> shift) +
(srcpp[x + 1] >> shift) * (srcpp[x + 1] >> shift) + (srcp[x - 1] >> shift) * (srcp[x - 1] >> shift) +
(srcp[x] >> shift) * (srcp[x] >> shift) + (srcp[x + 1] >> shift) * (srcp[x + 1] >> shift) +
(srcpn[x - 1] >> shift) * (srcpn[x - 1] >> shift) + (srcpn[x] >> shift) * (srcpn[x] >> shift) +
(srcpn[x + 1] >> shift) * (srcpn[x + 1] >> shift);
if (9 * sumsq - sum * sum < d.vthresh)
return;
const unsigned Ix = abs(srcp[x + 1] - srcp[x - 1]) >> shift;
const unsigned Iy = mmax(abs(srcpp[x] - srcpn[x]), abs(srcpp[x] - srcp[x]), abs(srcp[x] - srcpn[x])) >> shift;
if (Ix * Ix + Iy * Iy >= d.mthresh)
out = peak;
const unsigned Ixx = abs(srcp[x - 1] - 2 * srcp[x] + srcp[x + 1]) >> shift;
const unsigned Iyy = abs(srcpp[x] - 2 * srcp[x] + srcpn[x]) >> shift;
if (Ixx + Iyy >= d.lthresh)
out = peak;
}
template <typename T> KERNEL void erode(const EEDI2Param d, const T *msk, T *dst) {
setup_kernel;
auto mskp = line(msk);
auto mskpp = lineOff(msk, -1);
auto mskpn = lineOff(msk, 1);
auto &out = point(dst);
out = 0;
bounds_check3(x, 1, width - 1);
bounds_check3(y, 1, height - 1);
unsigned count = 0;
count += mskpp[x - 1] == peak;
count += mskpp[x] == peak;
count += mskpp[x + 1] == peak;
count += mskp[x - 1] == peak;
count += mskp[x + 1] == peak;
count += mskpn[x - 1] == peak;
count += mskpn[x] == peak;
count += mskpn[x + 1] == peak;
out = mskp[x] == peak && count < d.estr ? 0 : mskp[x];
}
template <typename T> KERNEL void dilate(const EEDI2Param d, const T *msk, T *dst) {
setup_kernel;
auto mskp = line(msk);
auto mskpp = lineOff(msk, -1);
auto mskpn = lineOff(msk, 1);
auto &out = point(dst);
out = 0;
bounds_check3(x, 1, width - 1);
bounds_check3(y, 1, height - 1);
unsigned count = 0;
count += mskpp[x - 1] == peak;
count += mskpp[x] == peak;
count += mskpp[x + 1] == peak;
count += mskp[x - 1] == peak;
count += mskp[x + 1] == peak;
count += mskpn[x - 1] == peak;
count += mskpn[x] == peak;
count += mskpn[x + 1] == peak;
out = mskp[x] == 0 && count >= d.dstr ? peak : mskp[x];
}
template <typename T> KERNEL void removeSmallHorzGaps(const EEDI2Param d, const T *msk, T *dst) {
setup_kernel;
auto mskp = line(msk);
auto &out = point(dst);
auto orig = mskp[x];
out = orig;
bounds_check3(x, 3, width - 3);
bounds_check3(y, 1, height - 1);
auto a = mskp[x - 3] | mskp[x - 2] | mskp[x - 1] | mskp[x + 1] | mskp[x + 2] | mskp[x + 3] ? orig : 0;
auto b =
(mskp[x + 1] & (mskp[x - 1] | mskp[x - 2] | mskp[x - 3])) | (mskp[x + 2] & (mskp[x - 1] | mskp[x - 2])) | (mskp[x + 3] & mskp[x - 1])
? peak
: orig;
out = mskp[x] ? a : b;
}
template <typename T> KERNEL void calcDirections(const EEDI2Param d, const T *src, const T *msk, T *dst) {
setup_kernel;
auto srcp = line(src);
auto mskp = line(msk);
auto src2p = lineOff(src, -2);
auto srcpp = lineOff(src, -1);
auto srcpn = lineOff(src, 1);
auto src2n = lineOff(src, 2);
auto mskpp = lineOff(msk, -1);
auto mskpn = lineOff(msk, 1);
auto &out = point(dst);
out = peak;
constexpr int block_w = 64;
constexpr int off_w = block_w / 2;
constexpr int buf_w = block_w * 2;
__shared__ int s2p[buf_w], s1p[buf_w], s[buf_w], s1n[buf_w], s2n[buf_w];
__shared__ int m1p[buf_w], m1n[buf_w];
// XXX: we are safe because they won't be the first or last plane in pool
s2p[x % block_w] = src2p[x - off_w];
s2p[x % block_w + block_w] = src2p[x + off_w];
s1p[x % block_w] = srcpp[x - off_w];
s1p[x % block_w + block_w] = srcpp[x + off_w];
s[x % block_w] = srcp[x - off_w];
s[x % block_w + block_w] = srcp[x + off_w];
s1n[x % block_w] = srcpn[x - off_w];
s1n[x % block_w + block_w] = srcpn[x + off_w];
s2n[x % block_w] = src2n[x - off_w];
s2n[x % block_w + block_w] = src2n[x + off_w];
m1p[x % block_w] = mskpp[x - off_w];
m1p[x % block_w + block_w] = mskpp[x + off_w];
m1n[x % block_w] = mskpn[x - off_w];
m1n[x % block_w + block_w] = mskpn[x + off_w];
__syncthreads();
auto X = x % block_w + off_w;
bounds_check3(x, 1, width - 1);
bounds_check3(y, 1, height - 1);
const int maxd = d.maxd >> d.subSampling;
if (mskp[x] != peak || (mskp[x - 1] != peak && mskp[x + 1] != peak))
return;
const int uStartBound = -x + 1;
const int uStopBound = width - 2 - x;
const unsigned min0 = abs(s[X] - s1n[X]) + abs(s[X] - s1p[X]);
unsigned minA = mmin(d.nt19, min0 * 9);
unsigned minB = mmin(d.nt13, min0 * 6);
unsigned minC = minA;
unsigned minD = minB;
unsigned minE = minB;
int dirA = -5000, dirB = -5000, dirC = -5000, dirD = -5000, dirE = -5000;
for (int u = -maxd; u <= maxd; u++) {
if (u < uStartBound || u > uStopBound)
continue;
if ((y == 1 || m1p[X - 1 + u] == peak || m1p[X + u] == peak || m1p[X + 1 + u] == peak) &&
(y == height - 2 || m1n[X - 1 - u] == peak || m1n[X - u] == peak || m1n[X + 1 - u] == peak)) {
const unsigned diffsn = abs(s[X - 1] - s1n[X - 1 - u]) + abs(s[X] - s1n[X - u]) + abs(s[X + 1] - s1n[X + 1 - u]);
const unsigned diffsp = abs(s[X - 1] - s1p[X - 1 + u]) + abs(s[X] - s1p[X + u]) + abs(s[X + 1] - s1p[X + 1 + u]);
const unsigned diffps = abs(s1p[X - 1] - s[X - 1 - u]) + abs(s1p[X] - s[X - u]) + abs(s1p[X + 1] - s[X + 1 - u]);
const unsigned diffns = abs(s1n[X - 1] - s[X - 1 + u]) + abs(s1n[X] - s[X + u]) + abs(s1n[X + 1] - s[X + 1 + u]);
const unsigned diff = diffsn + diffsp + diffps + diffns;
unsigned diffD = diffsp + diffns;
unsigned diffE = diffsn + diffps;
if (diff < minB) {
dirB = u;
minB = diff;
}
if (y > 1) {
const unsigned diff2pp = abs(s2p[X - 1] - s1p[X - 1 - u]) + abs(s2p[X] - s1p[X - u]) + abs(s2p[X + 1] - s1p[X + 1 - u]);
const unsigned diffp2p = abs(s1p[X - 1] - s2p[X - 1 + u]) + abs(s1p[X] - s2p[X + u]) + abs(s1p[X + 1] - s2p[X + 1 + u]);
const unsigned diffA = diff + diff2pp + diffp2p;
diffD += diffp2p;
diffE += diff2pp;
if (diffA < minA) {
dirA = u;
minA = diffA;
}
}
if (y < height - 2) {
const unsigned diff2nn = abs(s2n[X - 1] - s1n[X - 1 + u]) + abs(s2n[X] - s1n[X + u]) + abs(s2n[X + 1] - s1n[X + 1 + u]);
const unsigned diffn2n = abs(s1n[X - 1] - s2n[X - 1 - u]) + abs(s1n[X] - s2n[X - u]) + abs(s1n[X + 1] - s2n[X + 1 - u]);
const unsigned diffC = diff + diff2nn + diffn2n;
diffD += diff2nn;
diffE += diffn2n;
if (diffC < minC) {
dirC = u;
minC = diffC;
}
}
if (diffD < minD) {
dirD = u;
minD = diffD;
}
if (diffE < minE) {
dirE = u;
minE = diffE;
}
}
}
auto okA = dirA != -5000, okB = dirB != -5000, okC = dirC != -5000, okD = dirD != -5000, okE = dirE != -5000;
unsigned k = okA + okB + okC + okD + okE;
int order[] = {
okA ? dirA : intmax, okB ? dirB : intmax, okC ? dirC : intmax, okD ? dirD : intmax, okE ? dirE : intmax,
};
if (k > 1) {
boseSortArray(order);
const int mid = (k & 1) ? order[k / 2] : (order[(k - 1) / 2] + order[k / 2] + 1) / 2;
const int lim = mmax(limlut[abs(mid)] / 4, 2);
int sum = 0;
int count = 0;
for (unsigned i = 0; i < 5; i++) {
auto cond = order[i] != intmax && abs(order[i] - mid) <= lim;
sum += cond * order[i];
count += cond;
}
out = (count > 1) ? neutral + ((sum / count) << shift2) : neutral;
} else {
out = neutral;
}
}
template <typename T> KERNEL void filterDirMap(const EEDI2Param d, const T *msk, const T *dmsk, T *dst) {
setup_kernel;
auto mskp = line(msk);
auto dmskp = line(dmsk);
auto dmskpp = lineOff(dmsk, -1);
auto dmskpn = lineOff(dmsk, 1);
auto &out = point(dst);
out = dmskp[x];
bounds_check3(x, 1, width - 1);
bounds_check3(y, 1, height - 1);
if (mskp[x] != peak)
return;
int val0 = dmskpp[x - 1], val1 = dmskpp[x], val2 = dmskpp[x + 1], val3 = dmskp[x - 1], val4 = dmskp[x], val5 = dmskp[x + 1],
val6 = dmskpn[x - 1], val7 = dmskpn[x], val8 = dmskpn[x + 1];
auto cond0 = val0 != peak, cond1 = val1 != peak, cond2 = val2 != peak, cond3 = val3 != peak, cond4 = val4 != peak, cond5 = val5 != peak,
cond6 = val6 != peak, cond7 = val7 != peak, cond8 = val8 != peak;
int order[] = {
cond0 ? val0 : intmax, cond1 ? val1 : intmax, cond2 ? val2 : intmax, cond3 ? val3 : intmax, cond4 ? val4 : intmax,
cond5 ? val5 : intmax, cond6 ? val6 : intmax, cond7 ? val7 : intmax, cond8 ? val8 : intmax,
};
unsigned u = cond0 + cond1 + cond2 + cond3 + cond4 + cond5 + cond6 + cond7 + cond8;
if (u < 4) {
out = peak;
return;
}
boseSortArray(order);
const int mid = (u & 1) ? order[u / 2] : (order[(u - 1) / 2] + order[u / 2] + 1) / 2;
const int lim = limlut[abs(mid - neutral) >> shift2] << shift;
int sum = 0;
int count = 0;
for (unsigned i = 0; i < 9; i++) {
auto cond = order[i] != intmax && abs(order[i] - mid) <= lim;
sum += cond * order[i];
count += cond;
}
if (count < 4 || (count < 5 && dmskp[x] == peak)) {
out = peak;
return;
}
out = round_div(sum + mid, count + 1);
}
template <typename T> KERNEL void expandDirMap(const EEDI2Param d, const T *msk, const T *dmsk, T *dst) {
setup_kernel;
auto mskp = line(msk);
auto dmskp = line(dmsk);
auto dmskpp = lineOff(dmsk, -1);
auto dmskpn = lineOff(dmsk, 1);
auto &out = point(dst);
out = dmskp[x];
bounds_check3(x, 1, width - 1);
bounds_check3(y, 1, height - 1);
if (dmskp[x] != peak || mskp[x] != peak)
return;
int val0 = dmskpp[x - 1], val1 = dmskpp[x], val2 = dmskpp[x + 1], val3 = dmskp[x - 1], val5 = dmskp[x + 1], val6 = dmskpn[x - 1],
val7 = dmskpn[x], val8 = dmskpn[x + 1];
auto cond0 = val0 != peak, cond1 = val1 != peak, cond2 = val2 != peak, cond3 = val3 != peak, cond5 = val5 != peak, cond6 = val6 != peak,
cond7 = val7 != peak, cond8 = val8 != peak;
int order[] = {
cond0 ? val0 : intmax, cond1 ? val1 : intmax, cond2 ? val2 : intmax, cond3 ? val3 : intmax,
cond5 ? val5 : intmax, cond6 ? val6 : intmax, cond7 ? val7 : intmax, cond8 ? val8 : intmax,
};
unsigned u = cond0 + cond1 + cond2 + cond3 + cond5 + cond6 + cond7 + cond8;
if (u < 5)
return;
boseSortArray(order);
const int mid = (u & 1) ? order[u / 2] : (order[(u - 1) / 2] + order[u / 2] + 1) / 2;
const int lim = limlut[abs(mid - neutral) >> shift2] << shift;
int sum = 0;
int count = 0;
for (unsigned i = 0; i < 8; i++) {
auto cond = order[i] != intmax && abs(order[i] - mid) <= lim;
sum += cond * order[i];
count += cond;
}
if (count < 5)
return;
out = round_div(sum + mid, count + 1);
}
template <typename T> KERNEL void filterMap(const EEDI2Param d, const T *msk, const T *dmsk, T *dst) {
setup_kernel;
auto mskp = line(msk);
auto dmskp = line(dmsk);
auto dmskpp = lineOff(dmsk, -1);
auto dmskpn = lineOff(dmsk, 1);
auto &out = point(dst);
out = dmskp[x];
bounds_check3(x, 1, width - 1);
bounds_check3(y, 1, height - 1);
if (dmskp[x] == peak || mskp[x] != peak)
return;
int dir = (dmskp[x] - neutral) / 4;
const int lim = mmax(abs(dir) * 2, twleve + 0);
dir >>= shift;
bool ict = false, icb = false;
auto cond = dir < 0;
auto l = cond ? mmax(-x, dir) : 0;
auto r = cond ? 0 : mmin(width - x - 1, dir);
for (int j = l; j <= r; j++) {
if ((abs(dmskpp[x + j] - dmskp[x]) > lim && dmskpp[x + j] != peak) || (dmskp[x + j] == peak && dmskpp[x + j] == peak) ||
(abs(dmskp[x + j] - dmskp[x]) > lim && dmskp[x + j] != peak)) {
ict = true;
break;
}
}
if (ict) {
auto l = cond ? 0 : mmax(-x, -dir);
auto r = cond ? mmin(width - x - 1, -dir) : 0;
for (int j = l; j <= r; j++) {
if ((abs(dmskpn[x + j] - dmskp[x]) > lim && dmskpn[x + j] != peak) || (dmskpn[x + j] == peak && dmskp[x + j] == peak) ||
(abs(dmskp[x + j] - dmskp[x]) > lim && dmskp[x + j] != peak)) {
icb = true;
break;
}
}
if (icb)
out = peak;
}
}
template <typename T> KERNEL void markDirections2X(const EEDI2Param d, const T *msk, const T *dmsk, T *dst) {
setup_kernel2x;
auto mskp = lineOff(msk, -1);
auto dmskp = lineOff(dmsk, -1);
auto mskpn = lineOff(msk, 1);
auto dmskpn = lineOff(dmsk, 1);
auto &out = point(dst);
bounds_check3(x, 1, width - 1);
bounds_check3(y, 1, height - 1);
if (mskp[x] != peak && mskpn[x] != peak)
return;
int val0 = dmskp[x - 1], val1 = dmskp[x], val2 = dmskp[x + 1], val6 = dmskpn[x - 1], val7 = dmskpn[x], val8 = dmskpn[x + 1];
auto cond0 = val0 != peak, cond1 = val1 != peak, cond2 = val2 != peak, cond6 = val6 != peak, cond7 = val7 != peak, cond8 = val8 != peak;
int order[] = {
cond0 ? val0 : intmax, cond1 ? val1 : intmax, cond2 ? val2 : intmax,
cond6 ? val6 : intmax, cond7 ? val7 : intmax, cond8 ? val8 : intmax,
};
unsigned v = cond0 + cond1 + cond2 + cond6 + cond7 + cond8;
if (v < 3)
return;
boseSortArray(order);
const int mid = (v & 1) ? order[v / 2] : (order[(v - 1) / 2] + order[v / 2] + 1) / 2;
const int lim = limlut[abs(mid - neutral) >> shift2] << shift;
int sum = 0;
int count = 0;
unsigned u = 0;
u += (abs(dmskp[x - 1] - dmskpn[x - 1]) <= lim || dmskp[x - 1] == peak || dmskpn[x - 1] == peak);
u += (abs(dmskp[x] - dmskpn[x]) <= lim || dmskp[x] == peak || dmskpn[x] == peak);
u += (abs(dmskp[x + 1] - dmskpn[x - 1]) <= lim || dmskp[x + 1] == peak || dmskpn[x + 1] == peak);
if (u < 2)
return;
for (unsigned i = 0; i < 6; i++) {
auto cond = order[i] != intmax && abs(order[i] - mid) <= lim;
sum += cond * order[i];
count += cond;
}
if (count < v - 2 || count < 2)
return;
out = round_div(sum + mid, count + 1);
}
template <typename T> KERNEL void filterDirMap2X(const EEDI2Param d, const T *msk, const T *dmsk, T *dst) {
setup_kernel2x;
auto mskp = lineOff(msk, -1);
auto dmskp = line(dmsk);
auto mskpn = lineOff(msk, 1);
auto dmskpn = lineOff(dmsk, 2);
auto dmskpp = lineOff(dmsk, -2);
auto &out = point(dst);
out = dmskp[x];
bounds_check3(x, 1, width - 1);
bounds_check3(y, 1, height - 1);
if (mskp[x] != peak && mskpn[x] != peak)
return;
// XXX: we are safe because dmsk won't be the first or last plane in pool
int val0 = dmskpp[x - 1], val1 = dmskpp[x], val2 = dmskpp[x + 1], val3 = dmskp[x - 1], val4 = dmskp[x], val5 = dmskp[x + 1],
val6 = dmskpn[x - 1], val7 = dmskpn[x], val8 = dmskpn[x + 1];
auto cond0 = val0 != peak && y > 1, cond1 = val1 != peak && y > 1, cond2 = val2 != peak && y > 1, cond3 = val3 != peak,
cond4 = val4 != peak, cond5 = val5 != peak, cond6 = val6 != peak && y < height - 2, cond7 = val7 != peak && y < height - 2,
cond8 = val8 != peak && y < height - 2;
int order[] = {
cond0 ? val0 : intmax, cond1 ? val1 : intmax, cond2 ? val2 : intmax, cond3 ? val3 : intmax, cond4 ? val4 : intmax,
cond5 ? val5 : intmax, cond6 ? val6 : intmax, cond7 ? val7 : intmax, cond8 ? val8 : intmax,
};
unsigned u = cond0 + cond1 + cond2 + cond3 + cond4 + cond5 + cond6 + cond7 + cond8;
if (u < 4) {
out = peak;
return;
}
boseSortArray(order);
const int mid = (u & 1) ? order[u / 2] : (order[(u - 1) / 2] + order[u / 2] + 1) / 2;
const int lim = limlut[abs(mid - neutral) >> shift2] << shift;
int sum = 0;
int count = 0;
for (unsigned i = 0; i < 9; i++) {
auto cond = order[i] != intmax && abs(order[i] - mid) <= lim;
sum += cond * order[i];
count += cond;
}
if (count < 4 || (count < 5 && dmskp[x] == peak)) {
out = peak;
return;
}
out = round_div(sum + mid, count + 1);
}
template <typename T> KERNEL void expandDirMap2X(const EEDI2Param d, const T *msk, const T *dmsk, T *dst) {
setup_kernel2x;
auto mskp = lineOff(msk, -1);
auto dmskp = line(dmsk);
auto mskpn = lineOff(msk, 1);
auto dmskpn = lineOff(dmsk, 2);
auto dmskpp = lineOff(dmsk, -2);
auto &out = point(dst);
out = dmskp[x];
bounds_check3(x, 1, width - 1);
bounds_check3(y, 1, height - 1);
if (dmskp[x] != peak || (mskp[x] != peak && mskpn[x] != peak))
return;
// XXX: we are safe because dmsk won't be the first or last plane in pool
int val0 = dmskpp[x - 1], val1 = dmskpp[x], val2 = dmskpp[x + 1], val3 = dmskp[x - 1], val5 = dmskp[x + 1], val6 = dmskpn[x - 1],
val7 = dmskpn[x], val8 = dmskpn[x + 1];
auto cond0 = val0 != peak && y > 1, cond1 = val1 != peak && y > 1, cond2 = val2 != peak && y > 1, cond3 = val3 != peak,
cond5 = val5 != peak, cond6 = val6 != peak && y < height - 2, cond7 = val7 != peak && y < height - 2,
cond8 = val8 != peak && y < height - 2;
int order[] = {
cond0 ? val0 : intmax, cond1 ? val1 : intmax, cond2 ? val2 : intmax, cond3 ? val3 : intmax,
cond5 ? val5 : intmax, cond6 ? val6 : intmax, cond7 ? val7 : intmax, cond8 ? val8 : intmax,
};
unsigned u = cond0 + cond1 + cond2 + cond3 + cond5 + cond6 + cond7 + cond8;
if (u < 5)
return;
boseSortArray(order);
const int mid = (u & 1) ? order[u / 2] : (order[(u - 1) / 2] + order[u / 2] + 1) / 2;
const int lim = limlut[abs(mid - neutral) >> shift2] << shift;
int sum = 0;
int count = 0;
for (unsigned i = 0; i < 8; i++) {
auto cond = order[i] != intmax && abs(order[i] - mid) <= lim;
sum += cond * order[i];
count += cond;
}
if (count < 5)
return;
out = round_div(sum + mid, count + 1);
}
template <typename T> KERNEL void fillGaps2X(const EEDI2Param d, const T *msk, const T *dmsk, T *tmp) {
setup_kernel2x;
constexpr int fiveHundred = 500 << shift;
auto mskp = lineOff(msk, -1);
auto dmskp = line(dmsk);
auto mskpn = lineOff(msk, 1);
auto mskpp = lineOff(msk, -3);
auto mskpnn = lineOff(msk, 3);
auto dmskpn = lineOff(dmsk, 2);
auto dmskpp = lineOff(dmsk, -2);
auto &out_tmp = point(tmp);
out_tmp = 0;
bounds_check3(x, 1, width - 1);
bounds_check3(y, 1, height - 1);
if (dmskp[x] != peak || (mskp[x] != peak && mskpn[x] != peak))
return;
unsigned u = x - 1, v = x + 1;
int back = fiveHundred, forward = -fiveHundred;
while (u && x - u < 16) {
if (dmskp[u] != peak) {
back = dmskp[u];
break;
}
if (mskp[u] != peak && mskpn[u] != peak)
break;
u--;
}
while (v < width && v - x < 16) {
if (dmskp[v] != peak) {
forward = dmskp[v];
break;
}
if (mskp[v] != peak && mskpn[v] != peak)
break;
v++;
}
bool tc = true, bc = true;
int mint = fiveHundred, maxt = -twenty;
int minb = fiveHundred, maxb = -twenty;
for (unsigned j = u; j <= v && tc; j++) {
tc = !(y <= 2 || dmskpp[j] == peak || (mskpp[j] != peak && mskp[j] != peak));
mint = tc ? mmin(mint, dmskpp[j] + 0) : twenty;
maxt = tc ? mmax(maxt, dmskpp[j] + 0) : twenty;
}
for (unsigned j = u; j <= v && bc; j++) {
bc = !(y >= height - 3 || dmskpn[j] == peak || (mskpn[j] != peak && mskpnn[j] != peak));
minb = bc ? mmin(minb, dmskpn[j] + 0) : twenty;
maxb = bc ? mmax(maxb, dmskpn[j] + 0) : twenty;
}
if (maxt == -twenty)
maxt = mint = twenty;
if (maxb == -twenty)
maxb = minb = twenty;
const int thresh = mmax(mmax(abs(forward - neutral), abs(back - neutral)) / 4, eight + 0, abs(mint - maxt), abs(minb - maxb));
const unsigned lim = mmin(mmax(abs(forward - neutral), abs(back - neutral)) >> shift2, 6);
if (abs(forward - back) <= thresh && (v - u - 1 <= lim || tc || bc)) {
out_tmp = (x - u) | (v - x) << 8u;
}
}
template <typename T> KERNEL void fillGaps2XStep2(const EEDI2Param d, const T *msk, const T *dmsk, const T *tmp, T *dst) {
setup_kernel2x;
auto mskp = lineOff(msk, -1);
auto dmskp = line(dmsk);
auto mskpn = lineOff(msk, 1);
auto tmpp = line(tmp);
auto &out = point(dst);
out = dmskp[x];
bounds_check3(x, 1, width - 1);
bounds_check3(y, 1, height - 1);
unsigned uv = 0, pos;
for (unsigned i = max(x - 16, 1); i < x; ++i) {
bool cond = i + (tmpp[i] >> 8) > x;
uv = cond ? tmpp[i] : uv;
pos = cond ? i : pos;
}
uv = tmpp[x] ? tmpp[x] : uv;
pos = tmpp[x] ? x : pos;
for (unsigned i = x + 1; i - x < 16 && i < width - 1; ++i) {
bool cond = i - (tmpp[i] & 255u) < x;
uv = cond ? tmpp[i] : uv;
pos = cond ? i : pos;
}
if (!uv)
return;
int u = pos - (uv & 255);
int v = pos + (uv >> 8);
int back = dmskp[u];
int forward = dmskp[v];
out = back + round_div((forward - back) * (x - 1 - u), (v - u));
}
template <typename T> KERNEL void interpolateLattice(const EEDI2Param d, const T *omsk, const T *dmsk, T *dst, T *dmsk_2) {
setup_kernel2x;
auto omskp = lineOff(omsk, -1);
auto omskn = lineOff(omsk, 1);
auto dmskp = line(dmsk);
auto dstp = lineOff(dst, -1);
auto dstpn = line(dst);
auto dstpnn = lineOff(dst, 1);
auto &out = point(dst);
auto &mout = point(dmsk_2);
bounds_check3(x, 0, width);
bounds_check3(y, 1, height - 1);
int dir = dmskp[x];
const int lim = limlut[abs(dir - neutral) >> shift2] << shift;
if (dir == peak || (abs(dmskp[x] - dmskp[x - 1]) > lim && abs(dmskp[x] - dmskp[x + 1]) > lim)) {
out = (dstp[x] + dstpnn[x] + 1) / 2;
if (dir != peak)
mout = neutral;
return;
}
if (lim < nine) {
const unsigned sum = (dstp[x - 1] + dstp[x] + dstp[x + 1] + dstpnn[x - 1] + dstpnn[x] + dstpnn[x + 1]) >> shift;
const unsigned sumsq = (dstp[x - 1] >> shift) * (dstp[x - 1] >> shift) + (dstp[x] >> shift) * (dstp[x] >> shift) +
(dstp[x + 1] >> shift) * (dstp[x + 1] >> shift) + (dstpnn[x - 1] >> shift) * (dstpnn[x - 1] >> shift) +
(dstpnn[x] >> shift) * (dstpnn[x] >> shift) + (dstpnn[x + 1] >> shift) * (dstpnn[x + 1] >> shift);
if (6 * sumsq - sum * sum < 576) {
out = (dstp[x] + dstpnn[x] + 1) / 2;
mout = peak;
return;
}
}
if (x > 1 && x < width - 2 &&
((dstp[x] < mmax(dstp[x - 2], dstp[x - 1]) - three && dstp[x] < mmax(dstp[x + 2], dstp[x + 1]) - three &&
dstpnn[x] < mmax(dstpnn[x - 2], dstpnn[x - 1]) - three && dstpnn[x] < mmax(dstpnn[x + 2], dstpnn[x + 1]) - three) ||
(dstp[x] > mmin(dstp[x - 2], dstp[x - 1]) + three && dstp[x] > mmin(dstp[x + 2], dstp[x + 1]) + three &&
dstpnn[x] > mmin(dstpnn[x - 2], dstpnn[x - 1]) + three && dstpnn[x] > mmin(dstpnn[x + 2], dstpnn[x + 1]) + three))) {
out = (dstp[x] + dstpnn[x] + 1) / 2;
mout = neutral;
return;
}
dir = (dir - neutral + (1 << (shift2 - 1))) >> shift2;
const int uStart = (dir - 2 < 0) ? mmax(-x + 1, dir - 2, -width + 2 + x) : mmin(x - 1, dir - 2, width - 2 - x);
const int uStop = (dir + 2 < 0) ? mmax(-x + 1, dir + 2, -width + 2 + x) : mmin(x - 1, dir + 2, width - 2 - x);
unsigned min = d.nt8;
unsigned val = (dstp[x] + dstpnn[x] + 1) / 2;
for (int u = uStart; u <= uStop; u++) {
const unsigned diff = abs(dstp[x - 1] - dstpnn[x - u - 1]) + abs(dstp[x] - dstpnn[x - u]) + abs(dstp[x + 1] - dstpnn[x - u + 1]) +
abs(dstpnn[x - 1] - dstp[x + u - 1]) + abs(dstpnn[x] - dstp[x + u]) + abs(dstpnn[x + 1] - dstp[x + u + 1]);
if (diff < min &&
((omskp[x - 1 + u] != peak && abs(omskp[x - 1 + u] - dmskp[x]) <= lim) ||
(omskp[x + u] != peak && abs(omskp[x + u] - dmskp[x]) <= lim) ||
(omskp[x + 1 + u] != peak && abs(omskp[x + 1 + u] - dmskp[x]) <= lim)) &&
((omskn[x - 1 - u] != peak && abs(omskn[x - 1 - u] - dmskp[x]) <= lim) ||
(omskn[x - u] != peak && abs(omskn[x - u] - dmskp[x]) <= lim) ||
(omskn[x + 1 - u] != peak && abs(omskn[x + 1 - u] - dmskp[x]) <= lim))) {
const unsigned diff2 = abs(dstp[x + u / 2 - 1] - dstpnn[x - u / 2 - 1]) + abs(dstp[x + u / 2] - dstpnn[x - u / 2]) +
abs(dstp[x + u / 2 + 1] - dstpnn[x - u / 2 + 1]);
if (diff2 < d.nt4 &&
(((abs(omskp[x + u / 2] - omskn[x - u / 2]) <= lim || abs(omskp[x + u / 2] - omskn[x - ((u + 1) / 2)]) <= lim) &&
omskp[x + u / 2] != peak) ||
((abs(omskp[x + ((u + 1) / 2)] - omskn[x - u / 2]) <= lim || abs(omskp[x + ((u + 1) / 2)] - omskn[x - ((u + 1) / 2)]) <= lim) &&
omskp[x + ((u + 1) / 2)] != peak))) {
if ((abs(dmskp[x] - omskp[x + u / 2]) <= lim || abs(dmskp[x] - omskp[x + ((u + 1) / 2)]) <= lim) &&
(abs(dmskp[x] - omskn[x - u / 2]) <= lim || abs(dmskp[x] - omskn[x - ((u + 1) / 2)]) <= lim)) {
val = (dstp[x + u / 2] + dstp[x + ((u + 1) / 2)] + dstpnn[x - u / 2] + dstpnn[x - ((u + 1) / 2)] + 2) / 4;
min = diff;
dir = u;
}
}
}
}
if (min != d.nt8) {
out = val;
mout = neutral + (dir << shift2);
} else {
const int dt = 4 >> d.subSampling;
const int uStart2 = mmax(-x + 1, -dt);
const int uStop2 = mmin(width - 2 - x, dt);
const unsigned minm = mmin(dstp[x], dstpnn[x]);
const unsigned maxm = mmax(dstp[x], dstpnn[x]);
min = d.nt7;
for (int u = uStart2; u <= uStop2; u++) {
const int p1 = dstp[x + u / 2] + dstp[x + ((u + 1) / 2)];
const int p2 = dstpnn[x - u / 2] + dstpnn[x - ((u + 1) / 2)];
const unsigned diff = abs(dstp[x - 1] - dstpnn[x - u - 1]) + abs(dstp[x] - dstpnn[x - u]) + abs(dstp[x + 1] - dstpnn[x - u + 1]) +
abs(dstpnn[x - 1] - dstp[x + u - 1]) + abs(dstpnn[x] - dstp[x + u]) + abs(dstpnn[x + 1] - dstp[x + u + 1]) +
abs(p1 - p2);
if (diff < min) {
const unsigned valt = (p1 + p2 + 2) / 4;
if (valt >= minm && valt <= maxm) {
val = valt;
min = diff;
dir = u;
}
}
}
out = val;
mout = (min == d.nt7) ? neutral : neutral + (dir << shift2);
}
}
template <typename T> KERNEL void postProcess(const EEDI2Param d, const T *nmsk, const T *omsk, T *dst) {
setup_kernel2x;
auto nmskp = line(nmsk);
auto omskp = line(omsk);
auto &out = point(dst);
auto dstpp = lineOff(dst, -1);
auto dstpn = lineOff(dst, 1);
bounds_check3(x, 0, width);
bounds_check3(y, 1, height - 1);
const int lim = limlut[abs(nmskp[x] - neutral) >> shift2] << shift;
if (abs(nmskp[x] - omskp[x]) > lim && omskp[x] != peak && omskp[x] != neutral)
out = (dstpp[x] + dstpn[x] + 1) / 2;
}
template <typename T> class EEDI2Pass final : public Pass<T> {
EEDI2Param d;
T *dst, *msk, *src, *tmp;
T *dst2, *dst2M, *tmp2, *tmp2_2, *tmp2_3, *msk2;
unsigned map, pp, fieldS;
unsigned d_pitch;
public:
EEDI2Pass(const EEDI2Pass &other) : Pass<T>(other), d(other.d), map(other.map), pp(other.pp), fieldS(other.fieldS) { initCuda(); }
EEDI2Pass(VideoInfo vi, VideoInfo vi2, const EEDI2Param &d, unsigned map, unsigned pp, unsigned fieldS)
: Pass<T>(vi, vi2), d(d), map(map), pp(pp), fieldS(fieldS) {
initCuda();
}
[[nodiscard]] Pass<T> *dup() const override { return new EEDI2Pass(*this); }
~EEDI2Pass() override {
try_cuda(cudaFree(dst));
try_cuda(cudaFree(dst2));
}
private:
void initCuda() {
constexpr size_t numMem = 4;
constexpr size_t numMem2x = 6;
T **mem = &dst;
size_t pitch;
auto width = this->vi.width;
auto height = this->vi.height;
auto height2x = height * 2;
try_cuda(cudaMallocPitch(&mem[0], &pitch, width * sizeof(T), height * numMem));
narrow_cast_to(d_pitch, pitch);
for (size_t i = 1; i < numMem; ++i)
mem[i] = reinterpret_cast<T *>(reinterpret_cast<char *>(mem[i - 1]) + d_pitch * height);
if (map == 0 || map == 3) {
try_cuda(cudaMalloc(&dst2, d_pitch * height * numMem2x * 2));
mem = &dst2;
for (size_t i = 1; i < numMem2x; ++i)
mem[i] = reinterpret_cast<T *>(reinterpret_cast<char *>(mem[i - 1]) + d_pitch * height2x);
} else {
dst2 = nullptr;
}
}
public:
T *getSrcDevPtr() override { return src; }
unsigned getSrcPitch() override { return d_pitch; }
const T *getDstDevPtr() const override {
switch (map) {
case 0:
return dst2;
case 1:
return msk;
case 3:
return tmp2;
default:
return dst;
}
}
unsigned getDstPitch() override { return d_pitch; }
void process(int n, int plane, cudaStream_t stream) override {
auto field = fieldS;
if (field > 1)
field = (n & 1) ? (field == 2 ? 1 : 0) : (field == 2 ? 0 : 1);
auto subSampling = plane ? this->vi.subSampling : 0u;
auto width = this->vi.width >> subSampling;
auto height = this->vi.height >> subSampling;
auto height2x = height * 2;
auto width_bytes = width * sizeof(T);
auto d_pitch = this->d_pitch >> subSampling;