New mountaineering module

contributors.json

@@ -35,6 +35,10 @@
         "name": "Energyxxer",
         "links": ["https://youtube.com/user/Energyxxer"]
     },
+    {
+        "name":"foodiebonus",
+        "links":[]
+    },
     {
         "name": "Fyid",
         "links": ["https://twitter.com/FyidRants"]

gm4_mountaineering/beet.yaml

@@ -0,0 +1,28 @@
+id: gm4_mountaineering
+name: Mountaineering
+version: 1.0.X
+
+data_pack:
+  load: .
+
+pipeline:
+  - gm4.plugins.extend.module
+  - gm4.plugins.include.lib_custom_crafters
+
+meta:
+  gm4:
+    versioning:
+      required:
+        - lib_custom_crafters: 3.0.0
+      schedule_loops:
+        - main
+        - fast_main
+    website:
+      description: A mezze of mountaineering means! Glide down slopes and scale cliffs.
+      recommended: []
+      notes: []
+    video: null
+    wiki: null
+    credits:
+      Creator:
+        - foodiebonus

gm4_mountaineering/data/gm4/advancements/root.json

@@ -0,0 +1,24 @@
+{
+  "display": {
+    "icon": {
+      "item": "command_block",
+      "nbt": "{CustomModelData:3420001}"
+    },
+    "title": {
+      "translate": "advancement.gm4.root.title",
+      "fallback": "Gamemode 4"
+    },
+    "description": {
+      "translate": "advancement.gm4.root.description",
+      "fallback": "Semi-funny blurb about GM4",
+      "color": "gray"
+    },
+    "background": "textures/block/light_blue_concrete_powder.png",
+    "announce_to_chat": false
+  },
+  "criteria": {
+    "automatic": {
+      "trigger": "minecraft:tick"
+    }
+  }
+}

gm4_mountaineering/data/gm4/advancements/ski.json

@@ -0,0 +1,33 @@
+{
+  "display": {
+    "icon": {
+      "item": "iron_boots",
+      "nbt": "{CustomModelData:3420001}"
+    },
+    "title": {
+      "translate": "advancement.gm4.mountaineering.title",
+      "fallback": "Piste de Résistance"
+    },
+    "description": {
+      "translate": "advancement.gm4.mountaineering.description",
+      "fallback": "Get yourself a pair of skis",
+      "color": "gray"
+    }
+  },
+  "parent": "gm4:custom_crafters",
+  "criteria": {
+    "mountaineering": {
+      "trigger": "minecraft:inventory_changed",
+      "conditions": {
+        "items": [
+          {
+            "items": [
+              "minecraft:iron_boots"
+            ],
+            "nbt": "{gm4_mountaineering:{item:\"skis\"}}"
+          }
+        ]
+      }
+    }
+  }
+}

gm4_mountaineering/data/gm4/advancements/ski_fast.json

@@ -0,0 +1,23 @@
+{
+    "display": {
+      "icon": {
+        "item": "diamond_boots",
+        "nbt": "{CustomModelData:3420001}"
+      },
+      "title": {
+        "translate": "advancement.gm4.mountaineering.title",
+        "fallback": "Ski ya Later!"
+      },
+      "description": {
+        "translate": "advancement.gm4.mountaineering.description",
+        "fallback": "Reach the highest speed boost while skiing",
+        "color": "gray"
+      }
+    },
+    "parent": "gm4:ski",
+    "criteria": {
+        "requirement": {
+          "trigger": "minecraft:impossible"
+        }
+      }
+  }

gm4_mountaineering/data/gm4_custom_crafters/tags/functions/check_recipes.json

@@ -0,0 +1,6 @@
+{
+    "values": [
+      "gm4_mountaineering:check_recipes"
+    ]
+  }
+

gm4_mountaineering/data/gm4_mountaineering/functions/check_recipes.mcfunction

@@ -0,0 +1,5 @@
+# Checks for recipes then runs the relevant function to create mountaineering gear
+
+execute if score $crafted gm4_crafting matches 0 store success score $crafted gm4_crafting if score $slot_count gm4_crafting matches 7 if score $stack_size gm4_crafting matches ..1 if data storage gm4_custom_crafters:temp/crafter {Items:[{Slot:0b,id:"minecraft:iron_ingot"},{Slot:2b,id:"minecraft:iron_ingot"},{Slot:3b,id:"minecraft:iron_ingot"},{Slot:4b,id:"minecraft:iron_boots"},{Slot:5b,id:"minecraft:iron_ingot"},{Slot:6b,id:"minecraft:iron_ingot"},{Slot:8b,id:"minecraft:iron_ingot"}]} unless data storage gm4_custom_crafters:temp/crafter Items[3].tag.gm4_mountaineering run function gm4_mountaineering:new_skis
+execute if score $crafted gm4_crafting matches 0 store success score $crafted gm4_crafting if score $slot_count gm4_crafting matches 3 if score $stack_size gm4_crafting matches ..64 if data storage gm4_custom_crafters:temp/crafter {Items:[{Slot:0b,id:"minecraft:tripwire_hook"},{Slot:3b,id:"minecraft:stick"},{Slot:6b,id:"minecraft:stick"}]} run loot replace block ~ ~ ~ container.0 loot gm4_mountaineering:crafting/poles
+execute if score $crafted gm4_crafting matches 0 store success score $crafted gm4_crafting if score $slot_count gm4_crafting matches 4 if score $stack_size gm4_crafting matches ..1 if data storage gm4_custom_crafters:temp/crafter {Items:[{Slot:1b,id:"minecraft:chainmail_boots"},{Slot:3b,id:"minecraft:iron_nugget"},{Slot:4b,id:"minecraft:iron_nugget"},{Slot:5b,id:"minecraft:iron_nugget"}]} unless data storage gm4_custom_crafters:temp/crafter Items[0].tag.gm4_mountaineering run function gm4_mountaineering:new_crampons

gm4_mountaineering/data/gm4_mountaineering/functions/climbing_effects/add_climb_effects.mcfunction

@@ -0,0 +1,20 @@
+# add the climbing tag, and spawn shulkers (which die after a brief time) to allow the player to climb a vertical wall
+# @s = player wearing crampons, with using_crampons tag, and facing a climbable block
+# at @s
+# run from player_fast_main
+
+# provide jump boost
+effect give @s jump_boost 1 1 true 
+
+# summon shulker in front and below player, but 1000 blocks up, facing towards them
+execute if entity @s[y_rotation=135..-135] positioned ~ ~-1.5 ~-1 align xyz unless entity @e[type=shulker, tag=gm4_mountaineering_climb_assist, dx=0.5, dz=0.5, dy=1] unless block ~0.5 ~1 ~0.5 minecraft:air run summon minecraft:shulker ~0.5 ~1000 ~0.5 {Color:7,AttachFace:2,Invulnerable:1b,NoAI:1b,NoGravity:1b,PersistenceRequired:1b,Silent:1b,Tags:[gm4_mountaineering_climb_assist, gm4_mountaineering_new_shulker, gm4_mountaineering_peek_unset],DeathLootTable:"minecraft:empty",ActiveEffects:[{Id:14,Duration:100000,ShowParticles:0b}]}
+execute if entity @s[y_rotation=-135..-45] positioned ~1 ~-1.5 ~ align xyz unless entity @e[type=shulker, tag=gm4_mountaineering_climb_assist, dx=0.5, dz=0.5, dy=1] unless block ~0.5 ~1 ~0.5 minecraft:air run summon minecraft:shulker ~0.5 ~1000 ~0.5 {Color:7,AttachFace:5,Invulnerable:1b,NoAI:1b,NoGravity:1b,PersistenceRequired:1b,Silent:1b,Tags:[gm4_mountaineering_climb_assist, gm4_mountaineering_new_shulker, gm4_mountaineering_peek_unset],DeathLootTable:"minecraft:empty",ActiveEffects:[{Id:14,Duration:100000,ShowParticles:0b}]}
+execute if entity @s[y_rotation=-45..45] positioned ~ ~-1.5 ~1 align xyz unless entity @e[type=shulker, tag=gm4_mountaineering_climb_assist, dx=0.5, dz=0.5, dy=1] unless block ~0.5 ~1 ~0.5 minecraft:air run summon minecraft:shulker ~0.5 ~1000 ~0.5 {Color:7,AttachFace:3,Invulnerable:1b,NoAI:1b,NoGravity:1b,PersistenceRequired:1b,Silent:1b,Tags:[gm4_mountaineering_climb_assist, gm4_mountaineering_new_shulker, gm4_mountaineering_peek_unset],DeathLootTable:"minecraft:empty",ActiveEffects:[{Id:14,Duration:100000,ShowParticles:0b}]}
+execute if entity @s[y_rotation=45..135] positioned ~-1 ~-1.5 ~ align xyz unless entity @e[type=shulker, tag=gm4_mountaineering_climb_assist, dx=0.5, dz=0.5, dy=1] unless block ~0.5 ~1 ~0.5 minecraft:air run summon minecraft:shulker ~0.5 ~1000 ~0.5 {Color:7,AttachFace:4,Invulnerable:1b,NoAI:1b,NoGravity:1b,PersistenceRequired:1b,Silent:1b,Tags:[gm4_mountaineering_climb_assist, gm4_mountaineering_new_shulker, gm4_mountaineering_peek_unset],DeathLootTable:"minecraft:empty",ActiveEffects:[{Id:14,Duration:100000,ShowParticles:0b}]}
+
+# teleport shulker down 999 blocks to bring them into position (999 to put the shulker one block below feet)
+execute positioned ~ ~1000 ~ as @e[type=shulker, tag=gm4_mountaineering_climb_assist, tag=gm4_mountaineering_new_shulker] at @s run teleport @s ~ ~-999 ~
+tag @e[type=shulker] remove gm4_mountaineering_new_shulker
+
+# schedule a function to set the peek of the shulker (can't do it in the same tick as teleporting)
+schedule function gm4_mountaineering:climbing_effects/reset_shulker_peek 1t

gm4_mountaineering/data/gm4_mountaineering/functions/climbing_effects/damage_shulkers.mcfunction

@@ -0,0 +1,8 @@
+# increase the score of each climbing shulker, and kill after reaching 6
+# @s = shulker with tag gm4_mountaineering_climb_assist
+# at @s
+# run from main
+
+scoreboard players add @s gm4_mountaineering_climbing_shulker_countdown 1
+teleport @s[scores={gm4_mountaineering_climbing_shulker_countdown=6..}] ~ -10000 ~
+kill @s[scores={gm4_mountaineering_climbing_shulker_countdown=6..}]

gm4_mountaineering/data/gm4_mountaineering/functions/climbing_effects/reset_shulker_peek.mcfunction

@@ -0,0 +1,7 @@
+# reset the peek values of new shulkers and remove the relevant tag
+# @s = player wearing crampons, with using_crampons tag, and facing a climbable block
+# at @s
+# run from add_climb_effects
+
+execute as @e[type=shulker, tag=gm4_mountaineering_climb_assist, tag=gm4_mountaineering_peek_unset] run data merge entity @s {Peek:10}
+tag @e[type=shulker] remove gm4_mountaineering_peek_unset

gm4_mountaineering/data/gm4_mountaineering/functions/fast_main.mcfunction

@@ -0,0 +1,5 @@
+# Running on a faster clock to enable smoother climbing and for poles fall damage reduction to work
+
+execute as @a[gamemode=!spectator] at @s run function gm4_mountaineering:player_fast_main
+
+schedule function gm4_mountaineering:fast_main 4t

gm4_mountaineering/data/gm4_mountaineering/functions/get_velocity.mcfunction

@@ -0,0 +1,26 @@
+# Update the player's velocity scores
+# @s = player wearing skis
+# at @s
+# run from ski_effects/skis_equipped and pole_effects/poles_equipped
+
+# Get current y-position, store as y1
+execute store result score @s gm4_mountaineering_y1 run data get entity @s Pos[1]
+
+# Velocity is current position y1 minus previous position y2
+scoreboard players operation @s gm4_mountaineering_vy = @s gm4_mountaineering_y1
+scoreboard players operation @s gm4_mountaineering_vy -= @s gm4_mountaineering_y2
+
+# Update y2 for use on next run of this function
+scoreboard players operation @s gm4_mountaineering_y2 = @s gm4_mountaineering_y1
+
+# Use the same method to get x velocity
+execute store result score @s gm4_mountaineering_x1 run data get entity @s Pos[0]
+scoreboard players operation @s gm4_mountaineering_vx = @s gm4_mountaineering_x1
+scoreboard players operation @s gm4_mountaineering_vx -= @s gm4_mountaineering_x2
+scoreboard players operation @s gm4_mountaineering_x2 = @s gm4_mountaineering_x1
+
+# Use the same method to get z velocity
+execute store result score @s gm4_mountaineering_z1 run data get entity @s Pos[2]
+scoreboard players operation @s gm4_mountaineering_vz = @s gm4_mountaineering_z1
+scoreboard players operation @s gm4_mountaineering_vz -= @s gm4_mountaineering_z2
+scoreboard players operation @s gm4_mountaineering_z2 = @s gm4_mountaineering_z1

gm4_mountaineering/data/gm4_mountaineering/functions/init.mcfunction

@@ -0,0 +1,21 @@
+execute unless score mountaineering gm4_modules matches 1 run data modify storage gm4:log queue append value {type:"install",module:"Mountaineering"}
+scoreboard players set mountaineering gm4_modules 1
+
+scoreboard objectives add gm4_mountaineering_y1 dummy
+scoreboard objectives add gm4_mountaineering_y2 dummy
+scoreboard objectives add gm4_mountaineering_vy dummy
+scoreboard objectives add gm4_mountaineering_x1 dummy
+scoreboard objectives add gm4_mountaineering_x2 dummy
+scoreboard objectives add gm4_mountaineering_vx dummy
+scoreboard objectives add gm4_mountaineering_z1 dummy
+scoreboard objectives add gm4_mountaineering_z2 dummy
+scoreboard objectives add gm4_mountaineering_vz dummy
+scoreboard objectives add gm4_mountaineering_ski_downhill dummy
+scoreboard objectives add gm4_mountaineering_ski_steep_downhill dummy
+scoreboard objectives add gm4_mountaineering_poles_jump_boost dummy
+scoreboard objectives add gm4_mountaineering_jump_counter minecraft.custom:minecraft.jump
+scoreboard objectives add gm4_mountaineering_climbing_shulker_countdown dummy
+scoreboard objectives add gm4_mountaineering_init_climbing_effects dummy
+
+schedule function gm4_mountaineering:main 1t
+schedule function gm4_mountaineering:fast_main 1t

gm4_mountaineering/data/gm4_mountaineering/functions/main.mcfunction

@@ -0,0 +1,15 @@
+execute as @a[gamemode=!spectator] at @s run function gm4_mountaineering:player_main
+
+# Initiate crampons when they are first equipped with a tag
+tag @a[tag=!gm4_mountaineering_using_crampons,predicate=gm4_mountaineering:wearing_crampons] add gm4_mountaineering_using_crampons
+
+# Clear crampon tag when crampons are removed
+tag @a[predicate=!gm4_mountaineering:wearing_crampons,tag=gm4_mountaineering_using_crampons] remove gm4_mountaineering_using_crampons
+
+# Reset the jump counter for use in the poles jump boost cooldown
+scoreboard players reset @a gm4_mountaineering_jump_counter
+
+# Apply damage to any climbing shulkers
+execute as @e[type=minecraft:shulker,tag=gm4_mountaineering_climb_assist] at @s run function gm4_mountaineering:climbing_effects/damage_shulkers
+
+schedule function gm4_mountaineering:main 16t

gm4_mountaineering/data/gm4_mountaineering/functions/new_crampons.mcfunction

@@ -0,0 +1,12 @@
+# Creates new crampons upon correct recipe detection
+# @s = custom crafter with correct recipe
+# run from check_recipes
+
+# Preserve existing item data for provided chainmail boots
+data modify storage gm4_mountaineering:temp crampons_item set from storage gm4_custom_crafters:temp/crafter Items[0]
+
+# Create crampons in custom crafter
+loot replace block ~ ~ ~ container.0 loot gm4_mountaineering:crafting/crampons
+
+# Remove temp-stored chainmail boots from stored data
+data remove storage gm4_mountaineering:temp crampons_item

gm4_mountaineering/data/gm4_mountaineering/functions/new_skis.mcfunction

@@ -0,0 +1,12 @@
+# Creates new skis upon correct recipe detection
+# @s = custom crafter with correct recipe
+# run from check_recipes
+
+# Preserve existing item data for provided iron boots
+data modify storage gm4_mountaineering:temp ski_item set from storage gm4_custom_crafters:temp/crafter Items[0]
+
+# Create skis in custom crafter
+loot replace block ~ ~ ~ container.0 loot gm4_mountaineering:crafting/skis
+
+# Remove temp-stored iron boots from stored data
+data remove storage gm4_mountaineering:temp ski_item

gm4_mountaineering/data/gm4_mountaineering/functions/player_fast_main.mcfunction

@@ -0,0 +1,13 @@
+# Submain function to limit `as @a` calls in fast_main
+# @s = player not in spectator
+# at @s
+# run from fast_main
+
+# Adds vertical climbing abilities when wearing crampons and not holding anything
+scoreboard players set @s gm4_mountaineering_init_climbing_effects 0
+execute if entity @s[gamemode=!spectator,tag=gm4_mountaineering_using_crampons,predicate=gm4_mountaineering:hands_empty] anchored eyes if block ^ ^ ^1 #gm4_mountaineering:climbable_blocks run scoreboard players set @s gm4_mountaineering_init_climbing_effects 1
+execute if entity @s[gamemode=!spectator,tag=gm4_mountaineering_using_crampons,predicate=gm4_mountaineering:hands_empty,scores={gm4_mountaineering_init_climbing_effects=0}] anchored eyes if block ^ ^-1 ^1 #gm4_mountaineering:climbable_blocks run scoreboard players set @s gm4_mountaineering_init_climbing_effects 1
+execute if entity @s[scores={gm4_mountaineering_init_climbing_effects=1}] run function gm4_mountaineering:climbing_effects/add_climb_effects
+
+# Give resistance before landing to reduce fall damage when holding poles in both hands
+execute if entity @s[gamemode=!spectator,predicate=gm4_mountaineering:holding_poles] if block ~ ~-2 ~ minecraft:air run effect give @s resistance 1 1 true

gm4_mountaineering/data/gm4_mountaineering/functions/player_main.mcfunction

@@ -0,0 +1,13 @@
+# Submain function to limit `as @a` calls in main
+# @s = player not in spectator
+# at @s
+# run from main
+
+# Run ski-related functions
+execute if entity @s[predicate=gm4_mountaineering:wearing_skis] run function gm4_mountaineering:ski_effects/skis_equipped
+
+# Clear ski-related functions when skis are removed
+execute if entity @s[predicate=!gm4_mountaineering:wearing_skis,tag=gm4_mountaineering_using_skis] run function gm4_mountaineering:ski_effects/skis_removed
+
+# Adds jump boost effects when holding poles
+execute if entity @s[predicate=gm4_mountaineering:holding_poles] run function gm4_mountaineering:pole_effects/poles_equipped

gm4_mountaineering/data/gm4_mountaineering/functions/pole_effects/poles_equipped.mcfunction

@@ -0,0 +1,18 @@
+# Give pole-related effects - jump boost on a cooldown and reduced fall damage
+# @s = player holding poles
+# at @s
+# run from player_main
+
+# Records the player's velocities in scoreboards if it wasn't already done (as would be the case if wearing skis)
+execute unless entity @s[predicate=gm4_mountaineering:wearing_skis] run function gm4_mountaineering:get_velocity
+
+# Add jump boost effect (1 with skis, 2 without skis, 3 if having an upwards velocity)
+effect give @s[scores={gm4_mountaineering_poles_jump_boost=..0,gm4_mountaineering_vy=2..}] jump_boost 1 2 true
+effect give @s[predicate=!gm4_mountaineering:wearing_skis,scores={gm4_mountaineering_poles_jump_boost=..0,gm4_mountaineering_vy=..0}] jump_boost 1 1 true
+effect give @s[predicate=gm4_mountaineering:wearing_skis,scores={gm4_mountaineering_poles_jump_boost=..0,gm4_mountaineering_vy=..0}] jump_boost 1 0 true
+
+# Reduce jump cooldown
+scoreboard players remove @s[scores={gm4_mountaineering_poles_jump_boost=1..}] gm4_mountaineering_poles_jump_boost 1
+
+# If jump, reset cooldown and jump counter
+scoreboard players set @s[scores={gm4_mountaineering_jump_counter=1..}] gm4_mountaineering_poles_jump_boost 3

gm4_mountaineering/data/gm4_mountaineering/functions/ski_effects/check_snowy_block.mcfunction

@@ -0,0 +1,16 @@
+# clear existing tags, check if the player is on a snowy block and wearing skis, add the skiing tag back if yes, and add ski_off_snow tag if not on snowy block
+# @s = player wearing skis
+# at @s
+# run from skis_equipped
+
+# Remove skiing tags and slowness effects unless the player is in the air
+execute if entity @s[tag=gm4_mountaineering_ski_slowness] unless block ~ ~-0.1 ~ minecraft:air run function gm4_mountaineering:ski_effects/ski_off_snow_slowness/remove_off_snow_slowness
+execute unless block ~ ~-0.1 ~ minecraft:air run tag @s remove gm4_mountaineering_skiing
+
+# Add skiing tag if on snow layer or any other snowy block (contained within the predicate) with skis
+execute if block ~ ~ ~ minecraft:snow run tag @s add gm4_mountaineering_skiing
+tag @s[predicate=gm4_mountaineering:on_snowy_block] add gm4_mountaineering_skiing
+
+# Add slowness if wearing skis on a non-snowy block
+execute if entity @s[tag=!gm4_mountaineering_ski_slowness] unless block ~ ~ ~ minecraft:snow unless predicate gm4_mountaineering:on_snowy_block_or_air run function gm4_mountaineering:ski_effects/ski_off_snow_slowness/add_off_snow_slowness
+

gm4_mountaineering/data/gm4_mountaineering/functions/ski_effects/downhill_ski_speed/add_downhill_ski_speed.mcfunction

@@ -0,0 +1,8 @@
+# Add increased speed when player is on snowy block, wearing skis, and travelling downhill (>=2 blocks descended)
+# @s = player without skiing tag and having fallen >=2 blocks
+# at @s
+# run from skis_equipped
+
+tag @s add gm4_mountaineering_skiing_downhill
+scoreboard players set @s gm4_mountaineering_ski_downhill 10
+attribute @s minecraft:generic.movement_speed modifier add 42a046eb-1425-4efe-831b-f891d8ede18f "gm4_mountaineering_downhill_speed_boost" 0.175 multiply_base

gm4_mountaineering/data/gm4_mountaineering/functions/ski_effects/downhill_ski_speed/check_downhill_ski_speed.mcfunction

@@ -0,0 +1,16 @@
+# Checks that the player still travels downhill (>=1 blocks)
+# @s = player with skiing tag and having initially fallen >=2 blocks
+# at @s
+# run from skis_equipped
+
+# remove a second of speed if the player has not fallen >=1 block, and an additional second if travelling uphill 
+scoreboard players remove @s[scores={gm4_mountaineering_ski_downhill=1..,gm4_mountaineering_vy=0..}] gm4_mountaineering_ski_downhill 1
+scoreboard players remove @s[scores={gm4_mountaineering_ski_downhill=1..,gm4_mountaineering_vy=1..}] gm4_mountaineering_ski_downhill 1
+scoreboard players set @s[tag=gm4_mountaineering_skiing,scores={gm4_mountaineering_vy=..-1}] gm4_mountaineering_ski_downhill 10
+
+# set scoreboard to 0 if player is not moving
+scoreboard players set @s[scores={gm4_mountaineering_vx=0,gm4_mountaineering_vy=0,gm4_mountaineering_vz=0}] gm4_mountaineering_ski_downhill 0
+
+# Remove speed if no longer travelling downhill or removed skis
+execute if entity @s[scores={gm4_mountaineering_ski_downhill=..0}] run function gm4_mountaineering:ski_effects/downhill_ski_speed/remove_downhill_ski_speed
+execute if entity @s[tag=!gm4_mountaineering_skiing] run function gm4_mountaineering:ski_effects/downhill_ski_speed/remove_downhill_ski_speed

gm4_mountaineering/data/gm4_mountaineering/functions/ski_effects/downhill_ski_speed/remove_downhill_ski_speed.mcfunction

@@ -0,0 +1,8 @@
+# Remove increased speed when player is no longer on snowy block, wearing skis, and travelling downhill (>=2 blocks descended)
+# @s = player with skiing tag and downhill skiing tag but not having recently fallen >= 2 blocks
+# at @s
+# run from check_downhill_ski_speed
+
+scoreboard players set @s gm4_mountaineering_ski_downhill 0
+attribute @s minecraft:generic.movement_speed modifier remove 42a046eb-1425-4efe-831b-f891d8ede18f
+tag @s remove gm4_mountaineering_skiing_downhill

gm4_mountaineering/data/gm4_mountaineering/functions/ski_effects/flat_ski_speed/add_flat_ski_speed.mcfunction

@@ -0,0 +1,7 @@
+# Add some speed when player is on snowy block and wearing skis
+# @s = player with skiing tag, without speed skiing tag
+# at @s
+# run from skis_equipped
+
+attribute @s minecraft:generic.movement_speed modifier add f2781530-676b-401d-b2e3-12de37f9b82a "gm4_mountaineering_flat_speed" 0.3 multiply_base
+tag @s add gm4_mountaineering_ski_speed