Orb of Ankou 1.21 features

gm4/modeldata_registry.json

@@ -118,7 +118,8 @@
       "gm4_orb_of_ankou:pneuma/feigning": 234,
       "gm4_orb_of_ankou:pneuma/shrieking": 235,
       "gm4_orb_of_ankou:pneuma/dashing": 236,
-      "gm4_orb_of_ankou:pneuma/sniffing": 237
+      "gm4_orb_of_ankou:pneuma/sniffing": 237,
+      "gm4_orb_of_ankou:pneuma/tranquilizing": 238
     },
     "blaze_powder": {
       "gm4_mysterious_midnights:guidebook_icon/nightmare_nights": 1
@@ -566,7 +567,8 @@
       "gm4_orb_of_ankou:pneuma/feigning": 234,
       "gm4_orb_of_ankou:pneuma/shrieking": 235,
       "gm4_orb_of_ankou:pneuma/dashing": 236,
-      "gm4_orb_of_ankou:pneuma/sniffing": 237
+      "gm4_orb_of_ankou:pneuma/sniffing": 237,
+      "gm4_orb_of_ankou:pneuma/tranquilizing": 238
     },
     "flint_and_steel": {
       "gm4_orb_of_ankou:gui/advancement/orb_of_ankou_soul_forge": 1,

gm4_orb_of_ankou/assets/model_data.yaml

@@ -43,6 +43,7 @@ model_data:
       - reference: pneuma/freezing
       - reference: pneuma/feigning
       - reference: pneuma/shrieking
+      - reference: pneuma/tranquilizing
   - item: swords
     reference: shamir/corripio
     template:

gm4_orb_of_ankou/assets/translations.csv

@@ -58,6 +58,7 @@ text.gm4.pneuma_sniffing,Sniffing
 text.gm4.pneuma_soaring,Soaring
 text.gm4.pneuma_striding,Striding
 text.gm4.pneuma_synergetic,Synergetic
+text.gm4.pneuma_tranquilizing,Tranquilizing
 text.gm4.pneuma_vanishing,Vanishing
 text.gm4.pneuma_venomous,Venomous
 text.gm4.pneuma_volatile,Volatile

gm4_orb_of_ankou/data/gm4_orb_of_ankou/function/init.mcfunction

@@ -24,12 +24,11 @@ scoreboard objectives add gm4_oa_sniff dummy
 scoreboard objectives add gm4_health health
 scoreboard objectives add gm4_oa_sneak minecraft.custom:minecraft.sneak_time
 scoreboard objectives add gm4_oa_swim minecraft.custom:minecraft.swim_one_cm
-scoreboard objectives add gm4_oa_bow minecraft.used:minecraft.bow
-
-# check if players are in the nether and tag them if they are
-tag @a remove gm4_oa_in_nether
-execute in minecraft:the_nether run tag @a[x=0] add gm4_oa_in_nether
+scoreboard objectives add gm4_oa_bow_hawkeye minecraft.used:minecraft.bow
+scoreboard objectives add gm4_oa_bow_freezing minecraft.used:minecraft.bow
+scoreboard objectives add gm4_oa_bow_tranquilizing minecraft.used:minecraft.bow
 
+# start module
 execute unless score orb_of_ankou gm4_modules matches 1 run data modify storage gm4:log queue append value {type:"install",module:"Orb of Ankou"}
 execute unless score orb_of_ankou gm4_earliest_version < orb_of_ankou gm4_modules run scoreboard players operation orb_of_ankou gm4_earliest_version = orb_of_ankou gm4_modules
 scoreboard players set orb_of_ankou gm4_modules 1

gm4_orb_of_ankou/data/gm4_orb_of_ankou/function/main.mcfunction

@@ -1,16 +1,6 @@
 ## SOUL FORGE ##
 
-# check if player is in the nether
-execute store result score nether_player gm4_oa_forge if entity @a[gamemode=!spectator,tag=gm4_oa_in_nether,limit=1]
-
-# mark soul altars as loaded if a player is nearby
-execute if score nether_player gm4_oa_forge matches 1.. store result score loaded_forge gm4_oa_forge at @e[type=armor_stand,tag=gm4_soul_forge] if entity @a[gamemode=!spectator,distance=..8,limit=1]
-
-# destroy soul forge
-execute as @e[type=armor_stand,tag=gm4_soul_forge] at @s unless block ~ ~ ~ soul_fire run function gm4_orb_of_ankou:soul_forge/destroy
-
-# soul forge visuals
-execute as @e[type=armor_stand,tag=gm4_soul_forge] at @s if predicate gm4_orb_of_ankou:has_multiblock run function gm4_orb_of_ankou:soul_forge/process
+execute in the_nether run function gm4_orb_of_ankou:nether_main
 
 
 ## PNEUMA STUFF ##

gm4_orb_of_ankou/data/gm4_orb_of_ankou/function/nether_main.mcfunction

@@ -0,0 +1,18 @@
+# runs main functions in the nether
+# @s = none
+# located at world spawn, in the nether
+# run from main
+
+# check if player is in the nether
+execute store result score nether_player gm4_oa_forge if entity @a[gamemode=!spectator,x=0,limit=1]
+execute unless score nether_player gm4_oa_forge matches 1.. run return 0
+
+# mark soul altars as loaded if a player is nearby
+execute store result score loaded_forge gm4_oa_forge at @e[type=armor_stand,x=0,tag=gm4_soul_forge] if entity @a[gamemode=!spectator,distance=..8,limit=1]
+execute unless score loaded_forge gm4_oa_forge matches 1.. run return 0
+
+# destroy soul forge
+execute as @e[type=armor_stand,x=0,tag=gm4_soul_forge] at @s unless block ~ ~ ~ soul_fire run function gm4_orb_of_ankou:soul_forge/destroy
+
+# soul forge visuals
+execute as @e[type=armor_stand,x=0,tag=gm4_soul_forge] at @s if predicate gm4_orb_of_ankou:has_multiblock run function gm4_orb_of_ankou:soul_forge/process

gm4_orb_of_ankou/data/gm4_orb_of_ankou/function/nether_tick.mcfunction

@@ -0,0 +1,10 @@
+# runs tick functions in the nether
+# @s = none
+# located at world spawn, in the nether
+# run from tick
+
+# creation
+execute as @a[gamemode=!spectator,x=0,scores={gm4_oa_fns=1..}] at @s run function gm4_orb_of_ankou:soul_forge/used_flint_and_steel
+
+# check item before it burns
+execute if score loaded_forge gm4_oa_forge matches 1.. at @e[type=armor_stand,x=0,tag=gm4_soul_forge] if predicate gm4_orb_of_ankou:has_multiblock align xyz as @e[type=item,tag=!gm4_oa_checked_item,dx=0,dy=0,dz=0] run function gm4_orb_of_ankou:soul_forge/recipes/check_item

gm4_orb_of_ankou/data/gm4_orb_of_ankou/function/pneumas/temp_tick/freezing.mcfunction

@@ -0,0 +1,11 @@
+# @s = none
+# run from update_tags/check_pneuma
+
+execute unless entity @a[tag=gm4_pneuma_freezing,limit=1] run return 0
+execute unless entity @a[gamemode=!spectator,tag=gm4_pneuma_freezing,scores={gm4_oa_bow_freezing=1..},limit=1] run return run schedule function gm4_orb_of_ankou:pneumas/temp_tick/freezing 1t
+execute as @a[gamemode=!spectator,tag=gm4_pneuma_freezing,scores={gm4_oa_bow_freezing=1..}] at @s anchored eyes positioned ^ ^ ^2 run tag @e[type=arrow,distance=..2.5,limit=1] add gm4_oa_arrow
+data merge entity @e[type=arrow,tag=gm4_oa_arrow,limit=1] {item: {components: {"minecraft:potion_contents": {custom_effects: [{duration: 600, show_icon: 1b, id: "minecraft:slowness"}]}}}}
+tag @e[type=arrow] remove gm4_oa_arrow
+
+scoreboard players reset @a gm4_oa_bow_freezing
+schedule function gm4_orb_of_ankou:pneumas/temp_tick/freezing 1t

gm4_orb_of_ankou/data/gm4_orb_of_ankou/function/pneumas/temp_tick/hawkeye.mcfunction

@@ -1,9 +1,12 @@
 # @s = none
 # run from update_tags/check_pneuma
 
-execute as @a[gamemode=!spectator,tag=gm4_pneuma_hawkeye,scores={gm4_oa_bow=1..}] at @s anchored eyes positioned ^ ^ ^2 run tag @e[type=arrow,distance=..2.5,limit=1] add gm4_oa_arrow
+execute unless entity @a[tag=gm4_pneuma_hawkeye,limit=1] run return 0
+execute unless entity @a[gamemode=!spectator,tag=gm4_pneuma_hawkeye,scores={gm4_oa_bow_hawkeye=1..},limit=1] run return run schedule function gm4_orb_of_ankou:pneumas/temp_tick/hawkeye 1t
+execute as @a[gamemode=!spectator,tag=gm4_pneuma_hawkeye,scores={gm4_oa_bow_hawkeye=1..}] at @s anchored eyes positioned ^ ^ ^2 run tag @e[type=arrow,distance=..2.5,limit=1] add gm4_oa_arrow
 execute as @e[type=arrow,tag=gm4_oa_arrow,limit=1] store result entity @s damage byte 2 run data get entity @s damage
 data merge entity @e[type=arrow,tag=gm4_oa_arrow,limit=1] {PierceLevel:1b}
 tag @e[type=arrow] remove gm4_oa_arrow
 
-execute if entity @a[tag=gm4_pneuma_hawkeye,limit=1] run schedule function gm4_orb_of_ankou:pneumas/temp_tick/hawkeye 1t
+scoreboard players reset @a gm4_oa_bow_hawkeye
+schedule function gm4_orb_of_ankou:pneumas/temp_tick/hawkeye 1t

gm4_orb_of_ankou/data/gm4_orb_of_ankou/function/pneumas/temp_tick/tranquilizing.mcfunction

@@ -0,0 +1,11 @@
+# @s = none
+# run from update_tags/check_pneuma
+
+execute unless entity @a[tag=gm4_pneuma_tranquilizing,limit=1] run return 0
+execute unless entity @a[gamemode=!spectator,tag=gm4_pneuma_tranquilizing,scores={gm4_oa_bow_tranquilizing=1..},limit=1] run return run schedule function gm4_orb_of_ankou:pneumas/temp_tick/tranquilizing 1t
+execute as @a[gamemode=!spectator,tag=gm4_pneuma_tranquilizing,scores={gm4_oa_bow_tranquilizing=1..}] at @s anchored eyes positioned ^ ^ ^2 run tag @e[type=arrow,distance=..2.5,limit=1] add gm4_oa_arrow
+data merge entity @e[type=arrow,tag=gm4_oa_arrow,limit=1] {item: {components: {"minecraft:potion_contents": {custom_effects: [{duration: 100, show_icon: 1b, id: "minecraft:poison"}]}}}}
+tag @e[type=arrow] remove gm4_oa_arrow
+
+scoreboard players reset @a gm4_oa_bow_tranquilizing
+schedule function gm4_orb_of_ankou:pneumas/temp_tick/tranquilizing 1t

gm4_orb_of_ankou/data/gm4_orb_of_ankou/function/tick.mcfunction

@@ -1,12 +1,6 @@
 ## SOUL FORGE ##
 
-#creation
-execute if score nether_player gm4_oa_forge matches 1.. as @a[gamemode=!spectator,tag=gm4_oa_in_nether,scores={gm4_oa_fns=1..}] at @s run function gm4_orb_of_ankou:soul_forge/used_flint_and_steel
-scoreboard players reset @a gm4_oa_fns
-
-#check item before it burns
-execute if score loaded_forge gm4_oa_forge matches 1.. at @e[type=armor_stand,tag=gm4_soul_forge] if predicate gm4_orb_of_ankou:has_multiblock align xyz as @e[type=item,tag=!gm4_oa_checked_item,dx=0,dy=0,dz=0] run function gm4_orb_of_ankou:soul_forge/recipes/check_item
-
+execute if score nether_player gm4_oa_forge matches 1.. in the_nether run function gm4_orb_of_ankou:nether_tick
 
 ## PNEUMA STUFF ##
 
@@ -15,7 +9,7 @@ execute as @a[gamemode=!spectator,tag=gm4_has_pneuma,scores={gm4_oa_sneak=0},tag
 execute as @a[gamemode=!spectator,tag=gm4_has_pneuma,scores={gm4_oa_sneak=1..}] run function gm4_orb_of_ankou:pneumas/sneak/check
 scoreboard players set @a gm4_oa_sneak 0
 
-# use bow
-scoreboard players reset @a gm4_oa_bow
+# reset use tool scoreboards
+scoreboard players reset @a gm4_oa_fns
 
 schedule function gm4_orb_of_ankou:tick 1t

gm4_orb_of_ankou/data/gm4_orb_of_ankou/function/update_tags/check_pneuma.mcfunction

@@ -16,6 +16,7 @@ tag @s[predicate=gm4_orb_of_ankou:pneuma_equipped/draining] add gm4_pneuma_drain
 tag @s[predicate=gm4_orb_of_ankou:pneuma_equipped/expeditious] add gm4_pneuma_expeditious
 tag @s[predicate=gm4_orb_of_ankou:pneuma_equipped/feathery] add gm4_pneuma_feathery
 tag @s[predicate=gm4_orb_of_ankou:pneuma_equipped/feigning] add gm4_pneuma_feigning
+tag @s[predicate=gm4_orb_of_ankou:pneuma_equipped/freezing] add gm4_pneuma_freezing
 tag @s[predicate=gm4_orb_of_ankou:pneuma_equipped/gazing] add gm4_pneuma_gazing
 tag @s[predicate=gm4_orb_of_ankou:pneuma_equipped/gliding] add gm4_pneuma_gliding
 tag @s[predicate=gm4_orb_of_ankou:pneuma_equipped/hawkeye] add gm4_pneuma_hawkeye
@@ -31,6 +32,7 @@ tag @s[predicate=gm4_orb_of_ankou:pneuma_equipped/sniffing] add gm4_pneuma_sniff
 tag @s[predicate=gm4_orb_of_ankou:pneuma_equipped/soaring] add gm4_pneuma_soaring
 tag @s[predicate=gm4_orb_of_ankou:pneuma_equipped/striding] add gm4_pneuma_striding
 tag @s[predicate=gm4_orb_of_ankou:pneuma_equipped/synergetic] add gm4_pneuma_synergetic
+tag @s[predicate=gm4_orb_of_ankou:pneuma_equipped/tranquilizing] add gm4_pneuma_tranquilizing
 tag @s[predicate=gm4_orb_of_ankou:pneuma_equipped/vanishing] add gm4_pneuma_vanishing
 tag @s[predicate=gm4_orb_of_ankou:pneuma_equipped/volatile] add gm4_pneuma_volatile
 tag @s[predicate=gm4_orb_of_ankou:pneuma_equipped/withering] add gm4_pneuma_withering
@@ -43,7 +45,13 @@ tag @s[tag=gm4_pneuma_draining] add gm4_sneak_pneuma
 tag @s[tag=gm4_pneuma_shrieking] add gm4_sneak_pneuma
 tag @s[tag=gm4_pneuma_dashing] add gm4_sneak_pneuma
 
+scoreboard players reset @s gm4_oa_bow_hawkeye
+scoreboard players reset @s gm4_oa_bow_freezing
+scoreboard players reset @s gm4_oa_bow_tranquilizing
+
 # run tick functions
 execute if entity @a[gamemode=!spectator,tag=gm4_pneuma_agile,limit=1] run schedule function gm4_orb_of_ankou:pneumas/temp_tick/agile 1t
 execute if entity @a[gamemode=!spectator,tag=gm4_pneuma_hawkeye,limit=1] run schedule function gm4_orb_of_ankou:pneumas/temp_tick/hawkeye 1t
+execute if entity @a[gamemode=!spectator,tag=gm4_pneuma_freezing,limit=1] run schedule function gm4_orb_of_ankou:pneumas/temp_tick/freezing 1t
+execute if entity @a[gamemode=!spectator,tag=gm4_pneuma_tranquilizing,limit=1] run schedule function gm4_orb_of_ankou:pneumas/temp_tick/tranquilizing 1t
 execute if entity @a[gamemode=!spectator,tag=gm4_pneuma_striding,limit=1] run schedule function gm4_orb_of_ankou:pneumas/temp_tick/striding 1t

gm4_orb_of_ankou/data/gm4_orb_of_ankou/function/update_tags/remove_tags.mcfunction

@@ -14,6 +14,7 @@ tag @s remove gm4_pneuma_draining
 tag @s remove gm4_pneuma_expeditious
 tag @s remove gm4_pneuma_feathery
 tag @s remove gm4_pneuma_feigning
+tag @s remove gm4_pneuma_freezing
 tag @s remove gm4_pneuma_gazing
 tag @s remove gm4_pneuma_gliding
 tag @s remove gm4_pneuma_hawkeye
@@ -29,6 +30,7 @@ tag @s remove gm4_pneuma_sniffing
 tag @s remove gm4_pneuma_soaring
 tag @s remove gm4_pneuma_striding
 tag @s remove gm4_pneuma_synergetic
+tag @s remove gm4_pneuma_tranquilizing
 tag @s remove gm4_pneuma_vanishing
 tag @s remove gm4_pneuma_volatile
 tag @s remove gm4_pneuma_withering

gm4_orb_of_ankou/data/gm4_orb_of_ankou/loot_table/items/soul_essence/tranquilizing.json

@@ -0,0 +1,55 @@
+{
+  "type": "minecraft:generic",
+  "pools": [
+    {
+      "rolls": 1,
+      "entries": [
+        {
+          "type": "minecraft:item",
+          "name": "minecraft:black_dye",
+          "functions": [
+            {
+              "function": "minecraft:set_lore",
+              "mode": "append",
+              "lore": [
+                {
+                  "translate": "text.gm4.pneuma_tranquilizing",
+                  "fallback": "Tranquilizing",
+                  "italic": false,
+                  "color": "blue"
+                }
+              ]
+            },
+            {
+              "function": "minecraft:set_name",
+              "name": {
+                "translate": "item.gm4.soul_essence",
+                "fallback": "Soul Essence",
+                "italic": false,
+                "color": "white"
+              }
+            },
+            {
+              "function": "minecraft:set_components",
+              "components": {
+                "minecraft:enchantment_glint_override": true,
+                "minecraft:custom_model_data": "pneuma/tranquilizing",
+                "minecraft:custom_data": {
+                  "gm4_orb_of_ankou": {
+                    "item": "soul_essence",
+                    "stored_pneuma": {
+                      "id": "tranquilizing"
+                    },
+                    "stored_color": [
+                      5465649
+                    ]
+                  }
+                }
+              }
+            }
+          ]
+        }
+      ]
+    }
+  ]
+}